1PERLRE(1) Perl Programmers Reference Guide PERLRE(1)
2
6 perlre - Perl regular expressions
7
9 This page describes the syntax of regular expressions in Perl.
10 If you haven't used regular expressions before, a tutorial introduction
12 is available in perlretut. If you know just a little about them, a
13 quick-start introduction is available in perlrequick.
14 Except for "The Basics" section, this page assumes you are familiar
16 with regular expression basics, like what is a "pattern", what does it
17 look like, and how it is basically used. For a reference on how they
18 are used, plus various examples of the same, see discussions of "m//",
19 "s///", "qr//" and "??" in "Regexp Quote-Like Operators" in perlop.
20 New in v5.22, "use re 'strict'" applies stricter rules than otherwise
22 when compiling regular expression patterns. It can find things that,
23 while legal, may not be what you intended.
24 The Basics
26 Regular expressions are strings with the very particular syntax and
27 meaning described in this document and auxiliary documents referred to
28 by this one. The strings are called "patterns". Patterns are used to
29 determine if some other string, called the "target", has (or doesn't
30 have) the characteristics specified by the pattern. We call this
31 "matching" the target string against the pattern. Usually the match is
32 done by having the target be the first operand, and the pattern be the
33 second operand, of one of the two binary operators "=~" and "!~",
34 listed in "Binding Operators" in perlop; and the pattern will have been
35 converted from an ordinary string by one of the operators in "Regexp
36 Quote-Like Operators" in perlop, like so:
37 $foo =~ m/abc/
39 This evaluates to true if and only if the string in the variable $foo
41 contains somewhere in it, the sequence of characters "a", "b", then
42 "c". (The "=~ m", or match operator, is described in
43 "m/PATTERN/msixpodualngc" in perlop.)
44 Patterns that aren't already stored in some variable must be
46 delimitted, at both ends, by delimitter characters. These are often,
47 as in the example above, forward slashes, and the typical way a pattern
48 is written in documentation is with those slashes. In most cases, the
49 delimitter is the same character, fore and aft, but there are a few
50 cases where a character looks like it has a mirror-image mate, where
51 the opening version is the beginning delimiter, and the closing one is
52 the ending delimiter, like
53 $foo =~ m<abc>
55 Most times, the pattern is evaluated in double-quotish context, but it
57 is possible to choose delimiters to force single-quotish, like
58 $foo =~ m'abc'
60 If the pattern contains its delimiter within it, that delimiter must be
62 escaped. Prefixing it with a backslash (e.g., "/foo\/bar/") serves
63 this purpose.
64 Any single character in a pattern matches that same character in the
66 target string, unless the character is a metacharacter with a special
67 meaning described in this document. A sequence of non-metacharacters
68 matches the same sequence in the target string, as we saw above with
69 "m/abc/".
70 Only a few characters (all of them being ASCII punctuation characters)
72 are metacharacters. The most commonly used one is a dot ".", which
73 normally matches almost any character (including a dot itself).
74 You can cause characters that normally function as metacharacters to be
76 interpreted literally by prefixing them with a "\", just like the
77 pattern's delimiter must be escaped if it also occurs within the
78 pattern. Thus, "\." matches just a literal dot, "." instead of its
79 normal meaning. This means that the backslash is also a metacharacter,
80 so "\\" matches a single "\". And a sequence that contains an escaped
81 metacharacter matches the same sequence (but without the escape) in the
82 target string. So, the pattern "/blur\\fl/" would match any target
83 string that contains the sequence "blur\fl".
84 The metacharacter "|" is used to match one thing or another. Thus
86 $foo =~ m/this|that/
88 is TRUE if and only if $foo contains either the sequence "this" or the
90 sequence "that". Like all metacharacters, prefixing the "|" with a
91 backslash makes it match the plain punctuation character; in its case,
92 the VERTICAL LINE.
93 $foo =~ m/this\|that/
95 is TRUE if and only if $foo contains the sequence "this|that".
97 You aren't limited to just a single "|".
99 $foo =~ m/fee|fie|foe|fum/
101 is TRUE if and only if $foo contains any of those 4 sequences from the
103 children's story "Jack and the Beanstalk".
104 As you can see, the "|" binds less tightly than a sequence of ordinary
106 characters. We can override this by using the grouping metacharacters,
107 the parentheses "(" and ")".
108 $foo =~ m/th(is|at) thing/
110 is TRUE if and only if $foo contains either the sequence "this thing"
112 or the sequence "that thing". The portions of the string that match
113 the portions of the pattern enclosed in parentheses are normally made
114 available separately for use later in the pattern, substitution, or
115 program. This is called "capturing", and it can get complicated. See
116 "Capture groups".
117 The first alternative includes everything from the last pattern
119 delimiter ("(", "(?:" (described later), etc. or the beginning of the
120 pattern) up to the first "|", and the last alternative contains
121 everything from the last "|" to the next closing pattern delimiter.
122 That's why it's common practice to include alternatives in parentheses:
123 to minimize confusion about where they start and end.
124 Alternatives are tried from left to right, so the first alternative
126 found for which the entire expression matches, is the one that is
127 chosen. This means that alternatives are not necessarily greedy. For
128 example: when matching "foo|foot" against "barefoot", only the "foo"
129 part will match, as that is the first alternative tried, and it
130 successfully matches the target string. (This might not seem important,
131 but it is important when you are capturing matched text using
132 parentheses.)
133 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning. These are called
137 "escape sequences", and all such are described in perlrebackslash. A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141 One such sequence is "\b", which matches a boundary of some sort.
143 "\b{wb}" and a few others give specialized types of boundaries. (They
144 are all described in detail starting at "\b{}, \b, \B{}, \B" in
145 perlrebackslash.) Note that these don't match characters, but the
146 zero-width spaces between characters. They are an example of a zero-
147 width assertion. Consider again,
148 $foo =~ m/fee|fie|foe|fum/
150 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in $foo. By
153 judicious use of "\b" (or better (because it is designed to handle
154 natural language) "\b{wb}"), we can make sure that only the Giant's
155 words are matched:
156 $foo =~ m/\b(fee|fie|foe|fum)\b/
158 $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159 The final example shows that the characters "{" and "}" are
161 metacharacters.
162 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally. These are described
165 in detail in "Character Escapes" in perlrebackslash, but the next three
166 paragraphs briefly describe some of them.
167 Various control characters can be written in C language style: "\n"
169 matches a newline, "\t" a tab, "\r" a carriage return, "\f" a form
170 feed, etc.
171 More generally, "\nnn", where nnn is a string of three octal digits,
173 matches the character whose native code point is nnn. You can easily
174 run into trouble if you don't have exactly three digits. So always use
175 three, or since Perl 5.14, you can use "\o{...}" to specify any number
176 of octal digits.
177 Similarly, "\xnn", where nn are hexadecimal digits, matches the
179 character whose native ordinal is nn. Again, not using exactly two
180 digits is a recipe for disaster, but you can use "\x{...}" to specify
181 any number of hex digits.
182 Besides being a metacharacter, the "." is an example of a "character
184 class", something that can match any single character of a given set of
185 them. In its case, the set is just about all possible characters.
186 Perl predefines several character classes besides the "."; there is a
187 separate reference page about just these, perlrecharclass.
188 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set. You do this by enclosing the list within "[]" bracket
192 characters. These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped. (Dropping it
194 usually doesn't cause confusion.) This means that the "[" character is
195 another metacharacter. It doesn't match anything just by itself; it is
196 used only to tell Perl that what follows it is a bracketed character
197 class. If you want to match a literal left square bracket, you must
198 escape it, like "\[". The matching "]" is also a metacharacter; again
199 it doesn't match anything by itself, but just marks the end of your
200 custom class to Perl. It is an example of a "sometimes metacharacter".
201 It isn't a metacharacter if there is no corresponding "[", and matches
202 its literal self:
203 print "]" =~ /]/; # prints 1
205 The list of characters within the character class gives the set of
207 characters matched by the class. "[abc]" matches a single "a" or "b"
208 or "c". But if the first character after the "[" is "^", the class
209 instead matches any character not in the list. Within a list, the "-"
210 character specifies a range of characters, so that "a-z" represents all
211 characters between "a" and "z", inclusive. If you want either "-" or
212 "]" itself to be a member of a class, put it at the start of the list
213 (possibly after a "^"), or escape it with a backslash. "-" is also
214 taken literally when it is at the end of the list, just before the
215 closing "]". (The following all specify the same class of three
216 characters: "[-az]", "[az-]", and "[a\-z]". All are different from
217 "[a-z]", which specifies a class containing twenty-six characters, even
218 on EBCDIC-based character sets.)
219 There is lots more to bracketed character classes; full details are in
221 "Bracketed Character Classes" in perlrecharclass.
222 Metacharacters
224 "The Basics" introduced some of the metacharacters. This section gives
226 them all. Most of them have the same meaning as in the egrep command.
227 Only the "\" is always a metacharacter. The others are metacharacters
229 just sometimes. The following tables lists all of them, summarizes
230 their use, and gives the contexts where they are metacharacters.
231 Outside those contexts or if prefixed by a "\", they match their
232 corresponding punctuation character. In some cases, their meaning
233 varies depending on various pattern modifiers that alter the default
234 behaviors. See "Modifiers".
235 PURPOSE WHERE
237 \ Escape the next character Always, except when
238 escaped by another \
239 ^ Match the beginning of the string Not in []
240 (or line, if /m is used)
241 ^ Complement the [] class At the beginning of []
242 . Match any single character except newline Not in []
243 (under /s, includes newline)
244 $ Match the end of the string Not in [], but can
245 (or before newline at the end of the mean interpolate a
246 string; or before any newline if /m is scalar
247 used)
248 | Alternation Not in []
249 () Grouping Not in []
250 [ Start Bracketed Character class Not in []
251 ] End Bracketed Character class Only in [], and
252 not first
253 * Matches the preceding element 0 or more Not in []
254 times
255 + Matches the preceding element 1 or more Not in []
256 times
257 ? Matches the preceding element 0 or 1 Not in []
258 times
259 { Starts a sequence that gives number(s) Not in []
260 of times the preceding element can be
261 matched
262 { when following certain escape sequences
263 starts a modifier to the meaning of the
264 sequence
265 } End sequence started by {
266 - Indicates a range Only in [] interior
267 # Beginning of comment, extends to line end Only with /x modifier
268 Notice that most of the metacharacters lose their special meaning when
270 they occur in a bracketed character class, except "^" has a different
271 meaning when it is at the beginning of such a class. And "-" and "]"
272 are metacharacters only at restricted positions within bracketed
273 character classes; while "}" is a metacharacter only when closing a
274 special construct started by "{".
275 In double-quotish context, as is usually the case, you need to be
277 careful about "$" and the non-metacharacter "@". Those could
278 interpolate variables, which may or may not be what you intended.
279 These rules were designed for compactness of expression, rather than
281 legibility and maintainability. The "/x and /xx" pattern modifiers
282 allow you to insert white space to improve readability. And use of
283 "re 'strict'" adds extra checking to catch some typos that might
284 silently compile into something unintended.
285 By default, the "^" character is guaranteed to match only the beginning
287 of the string, the "$" character only the end (or before the newline at
288 the end), and Perl does certain optimizations with the assumption that
289 the string contains only one line. Embedded newlines will not be
290 matched by "^" or "$". You may, however, wish to treat a string as a
291 multi-line buffer, such that the "^" will match after any newline
292 within the string (except if the newline is the last character in the
293 string), and "$" will match before any newline. At the cost of a
294 little more overhead, you can do this by using the ""/m"" modifier on
295 the pattern match operator. (Older programs did this by setting $*,
296 but this option was removed in perl 5.10.)
297 To simplify multi-line substitutions, the "." character never matches a
299 newline unless you use the "/s" modifier, which in effect tells Perl to
300 pretend the string is a single line--even if it isn't.
301 Modifiers
303 Overview
304 The default behavior for matching can be changed, using various
306 modifiers. Modifiers that relate to the interpretation of the pattern
307 are listed just below. Modifiers that alter the way a pattern is used
308 by Perl are detailed in "Regexp Quote-Like Operators" in perlop and
309 "Gory details of parsing quoted constructs" in perlop.
310 "m" Treat the string being matched against as multiple lines. That is,
312 change "^" and "$" from matching the start of the string's first
313 line and the end of its last line to matching the start and end of
314 each line within the string.
315 "s" Treat the string as single line. That is, change "." to match any
317 character whatsoever, even a newline, which normally it would not
318 match.
319 Used together, as "/ms", they let the "." match any character
321 whatsoever, while still allowing "^" and "$" to match,
322 respectively, just after and just before newlines within the
323 string.
324 "i" Do case-insensitive pattern matching. For example, "A" will match
326 "a" under "/i".
327 If locale matching rules are in effect, the case map is taken from
329 the current locale for code points less than 255, and from Unicode
330 rules for larger code points. However, matches that would cross
331 the Unicode rules/non-Unicode rules boundary (ords 255/256) will
332 not succeed, unless the locale is a UTF-8 one. See perllocale.
333 There are a number of Unicode characters that match a sequence of
335 multiple characters under "/i". For example, "LATIN SMALL LIGATURE
336 FI" should match the sequence "fi". Perl is not currently able to
337 do this when the multiple characters are in the pattern and are
338 split between groupings, or when one or more are quantified. Thus
339 "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i; # Matches
341 "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i; # Doesn't match!
342 "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i; # Doesn't match!
343 # The below doesn't match, and it isn't clear what $1 and $2 would
345 # be even if it did!!
346 "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i; # Doesn't match!
347 Perl doesn't match multiple characters in a bracketed character
349 class unless the character that maps to them is explicitly
350 mentioned, and it doesn't match them at all if the character class
351 is inverted, which otherwise could be highly confusing. See
352 "Bracketed Character Classes" in perlrecharclass, and "Negation" in
353 perlrecharclass.
354 "x" and "xx"
356 Extend your pattern's legibility by permitting whitespace and
357 comments. Details in "/x and /xx"
358 "p" Preserve the string matched such that "${^PREMATCH}", "${^MATCH}",
360 and "${^POSTMATCH}" are available for use after matching.
361 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
363 mechanism, "${^PREMATCH}", "${^MATCH}", and "${^POSTMATCH}" will be
364 available after the match regardless of the modifier.
365 "a", "d", "l", and "u"
367 These modifiers, all new in 5.14, affect which character-set rules
368 (Unicode, etc.) are used, as described below in "Character set
369 modifiers".
370 "n" Prevent the grouping metacharacters "()" from capturing. This
372 modifier, new in 5.22, will stop $1, $2, etc... from being filled
373 in.
374 "hello" =~ /(hi|hello)/; # $1 is "hello"
376 "hello" =~ /(hi|hello)/n; # $1 is undef
377 This is equivalent to putting "?:" at the beginning of every
379 capturing group:
380 "hello" =~ /(?:hi|hello)/; # $1 is undef
382 "/n" can be negated on a per-group basis. Alternatively, named
384 captures may still be used.
385 "hello" =~ /(?-n:(hi|hello))/n; # $1 is "hello"
387 "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
388 # "hello"
389 Other Modifiers
391 There are a number of flags that can be found at the end of regular
392 expression constructs that are not generic regular expression
393 flags, but apply to the operation being performed, like matching or
394 substitution ("m//" or "s///" respectively).
395 Flags described further in "Using regular expressions in Perl" in
397 perlretut are:
398 c - keep the current position during repeated matching
400 g - globally match the pattern repeatedly in the string
401 Substitution-specific modifiers described in
403 "s/PATTERN/REPLACEMENT/msixpodualngcer" in perlop are:
404 e - evaluate the right-hand side as an expression
406 ee - evaluate the right side as a string then eval the result
407 o - pretend to optimize your code, but actually introduce bugs
408 r - perform non-destructive substitution and return the new value
409 Regular expression modifiers are usually written in documentation as
411 e.g., "the "/x" modifier", even though the delimiter in question might
412 not really be a slash. The modifiers "/imnsxadlup" may also be
413 embedded within the regular expression itself using the "(?...)"
414 construct, see "Extended Patterns" below.
415 Details on some modifiers
417 Some of the modifiers require more explanation than given in the
419 "Overview" above.
420 "/x" and "/xx"
422 A single "/x" tells the regular expression parser to ignore most
424 whitespace that is neither backslashed nor within a bracketed character
425 class. You can use this to break up your regular expression into more
426 readable parts. Also, the "#" character is treated as a metacharacter
427 introducing a comment that runs up to the pattern's closing delimiter,
428 or to the end of the current line if the pattern extends onto the next
429 line. Hence, this is very much like an ordinary Perl code comment.
430 (You can include the closing delimiter within the comment only if you
431 precede it with a backslash, so be careful!)
432 Use of "/x" means that if you want real whitespace or "#" characters in
434 the pattern (outside a bracketed character class, which is unaffected
435 by "/x"), then you'll either have to escape them (using backslashes or
436 "\Q...\E") or encode them using octal, hex, or "\N{}" escapes. It is
437 ineffective to try to continue a comment onto the next line by escaping
438 the "\n" with a backslash or "\Q".
439 You can use "(?#text)" to create a comment that ends earlier than the
441 end of the current line, but "text" also can't contain the closing
442 delimiter unless escaped with a backslash.
443 A common pitfall is to forget that "#" characters begin a comment under
445 "/x" and are not matched literally. Just keep that in mind when trying
446 to puzzle out why a particular "/x" pattern isn't working as expected.
447 Starting in Perl v5.26, if the modifier has a second "x" within it, it
449 does everything that a single "/x" does, but additionally non-
450 backslashed SPACE and TAB characters within bracketed character classes
451 are also generally ignored, and hence can be added to make the classes
452 more readable.
453 / [d-e g-i 3-7]/xx
455 /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
456 may be easier to grasp than the squashed equivalents
458 /[d-eg-i3-7]/
460 /[!@"#$%^&*()=?<>']/
461 Taken together, these features go a long way towards making Perl's
463 regular expressions more readable. Here's an example:
464 # Delete (most) C comments.
466 $program =~ s {
467 /\* # Match the opening delimiter.
468 .*? # Match a minimal number of characters.
469 \*/ # Match the closing delimiter.
470 } []gsx;
471 Note that anything inside a "\Q...\E" stays unaffected by "/x". And
473 note that "/x" doesn't affect space interpretation within a single
474 multi-character construct. For example in "\x{...}", regardless of the
475 "/x" modifier, there can be no spaces. Same for a quantifier such as
476 "{3}" or "{5,}". Similarly, "(?:...)" can't have a space between the
477 "(", "?", and ":". Within any delimiters for such a construct, allowed
478 spaces are not affected by "/x", and depend on the construct. For
479 example, "\x{...}" can't have spaces because hexadecimal numbers don't
480 have spaces in them. But, Unicode properties can have spaces, so in
481 "\p{...}" there can be spaces that follow the Unicode rules, for which
482 see "Properties accessible through \p{} and \P{}" in perluniprops.
483 The set of characters that are deemed whitespace are those that Unicode
485 calls "Pattern White Space", namely:
486 U+0009 CHARACTER TABULATION
488 U+000A LINE FEED
489 U+000B LINE TABULATION
490 U+000C FORM FEED
491 U+000D CARRIAGE RETURN
492 U+0020 SPACE
493 U+0085 NEXT LINE
494 U+200E LEFT-TO-RIGHT MARK
495 U+200F RIGHT-TO-LEFT MARK
496 U+2028 LINE SEPARATOR
497 U+2029 PARAGRAPH SEPARATOR
498 Character set modifiers
500 "/d", "/u", "/a", and "/l", available starting in 5.14, are called the
502 character set modifiers; they affect the character set rules used for
503 the regular expression.
504 The "/d", "/u", and "/l" modifiers are not likely to be of much use to
506 you, and so you need not worry about them very much. They exist for
507 Perl's internal use, so that complex regular expression data structures
508 can be automatically serialized and later exactly reconstituted,
509 including all their nuances. But, since Perl can't keep a secret, and
510 there may be rare instances where they are useful, they are documented
511 here.
512 The "/a" modifier, on the other hand, may be useful. Its purpose is to
514 allow code that is to work mostly on ASCII data to not have to concern
515 itself with Unicode.
516 Briefly, "/l" sets the character set to that of whatever Locale is in
518 effect at the time of the execution of the pattern match.
519 "/u" sets the character set to Unicode.
521 "/a" also sets the character set to Unicode, BUT adds several
523 restrictions for ASCII-safe matching.
524 "/d" is the old, problematic, pre-5.14 Default character set behavior.
526 Its only use is to force that old behavior.
527 At any given time, exactly one of these modifiers is in effect. Their
529 existence allows Perl to keep the originally compiled behavior of a
530 regular expression, regardless of what rules are in effect when it is
531 actually executed. And if it is interpolated into a larger regex, the
532 original's rules continue to apply to it, and only it.
533 The "/l" and "/u" modifiers are automatically selected for regular
535 expressions compiled within the scope of various pragmas, and we
536 recommend that in general, you use those pragmas instead of specifying
537 these modifiers explicitly. For one thing, the modifiers affect only
538 pattern matching, and do not extend to even any replacement done,
539 whereas using the pragmas gives consistent results for all appropriate
540 operations within their scopes. For example,
541 s/foo/\Ubar/il
543 will match "foo" using the locale's rules for case-insensitive
545 matching, but the "/l" does not affect how the "\U" operates. Most
546 likely you want both of them to use locale rules. To do this, instead
547 compile the regular expression within the scope of "use locale". This
548 both implicitly adds the "/l", and applies locale rules to the "\U".
549 The lesson is to "use locale", and not "/l" explicitly.
550 Similarly, it would be better to use "use feature 'unicode_strings'"
552 instead of,
553 s/foo/\Lbar/iu
555 to get Unicode rules, as the "\L" in the former (but not necessarily
557 the latter) would also use Unicode rules.
558 More detail on each of the modifiers follows. Most likely you don't
560 need to know this detail for "/l", "/u", and "/d", and can skip ahead
561 to /a.
562 /l
564 means to use the current locale's rules (see perllocale) when pattern
566 matching. For example, "\w" will match the "word" characters of that
567 locale, and "/i" case-insensitive matching will match according to the
568 locale's case folding rules. The locale used will be the one in effect
569 at the time of execution of the pattern match. This may not be the
570 same as the compilation-time locale, and can differ from one match to
571 another if there is an intervening call of the setlocale() function.
572 Prior to v5.20, Perl did not support multi-byte locales. Starting
574 then, UTF-8 locales are supported. No other multi byte locales are
575 ever likely to be supported. However, in all locales, one can have
576 code points above 255 and these will always be treated as Unicode no
577 matter what locale is in effect.
578 Under Unicode rules, there are a few case-insensitive matches that
580 cross the 255/256 boundary. Except for UTF-8 locales in Perls v5.20
581 and later, these are disallowed under "/l". For example, 0xFF (on
582 ASCII platforms) does not caselessly match the character at 0x178,
583 "LATIN CAPITAL LETTER Y WITH DIAERESIS", because 0xFF may not be "LATIN
584 SMALL LETTER Y WITH DIAERESIS" in the current locale, and Perl has no
585 way of knowing if that character even exists in the locale, much less
586 what code point it is.
587 In a UTF-8 locale in v5.20 and later, the only visible difference
589 between locale and non-locale in regular expressions should be tainting
590 (see perlsec).
591 This modifier may be specified to be the default by "use locale", but
593 see "Which character set modifier is in effect?".
594 /u
596 means to use Unicode rules when pattern matching. On ASCII platforms,
598 this means that the code points between 128 and 255 take on their
599 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
600 (Otherwise Perl considers their meanings to be undefined.) Thus, under
601 this modifier, the ASCII platform effectively becomes a Unicode
602 platform; and hence, for example, "\w" will match any of the more than
603 100_000 word characters in Unicode.
604 Unlike most locales, which are specific to a language and country pair,
606 Unicode classifies all the characters that are letters somewhere in the
607 world as "\w". For example, your locale might not think that "LATIN
608 SMALL LETTER ETH" is a letter (unless you happen to speak Icelandic),
609 but Unicode does. Similarly, all the characters that are decimal
610 digits somewhere in the world will match "\d"; this is hundreds, not
611 10, possible matches. And some of those digits look like some of the
612 10 ASCII digits, but mean a different number, so a human could easily
613 think a number is a different quantity than it really is. For example,
614 "BENGALI DIGIT FOUR" (U+09EA) looks very much like an "ASCII DIGIT
615 EIGHT" (U+0038). And, "\d+", may match strings of digits that are a
616 mixture from different writing systems, creating a security issue.
617 "num()" in Unicode::UCD can be used to sort this out. Or the "/a"
618 modifier can be used to force "\d" to match just the ASCII 0 through 9.
619 Also, under this modifier, case-insensitive matching works on the full
621 set of Unicode characters. The "KELVIN SIGN", for example matches the
622 letters "k" and "K"; and "LATIN SMALL LIGATURE FF" matches the sequence
623 "ff", which, if you're not prepared, might make it look like a
624 hexadecimal constant, presenting another potential security issue. See
625 <http://unicode.org/reports/tr36> for a detailed discussion of Unicode
626 security issues.
627 This modifier may be specified to be the default by "use feature
629 'unicode_strings", "use locale ':not_characters'", or "use 5.012" (or
630 higher), but see "Which character set modifier is in effect?".
631 /d
633 This modifier means to use the "Default" native rules of the platform
635 except when there is cause to use Unicode rules instead, as follows:
636 1. the target string is encoded in UTF-8; or
638 2. the pattern is encoded in UTF-8; or
640 3. the pattern explicitly mentions a code point that is above 255 (say
642 by "\x{100}"); or
643 4. the pattern uses a Unicode name ("\N{...}"); or
645 5. the pattern uses a Unicode property ("\p{...}" or "\P{...}"); or
647 6. the pattern uses a Unicode break ("\b{...}" or "\B{...}"); or
649 7. the pattern uses ""(?[ ])""
651 8. the pattern uses "(*script_run: ...)"
653 Another mnemonic for this modifier is "Depends", as the rules actually
655 used depend on various things, and as a result you can get unexpected
656 results. See "The "Unicode Bug"" in perlunicode. The Unicode Bug has
657 become rather infamous, leading to yet another (printable) name for
658 this modifier, "Dodgy".
659 Unless the pattern or string are encoded in UTF-8, only ASCII
661 characters can match positively.
662 Here are some examples of how that works on an ASCII platform:
664 $str = "\xDF"; # $str is not in UTF-8 format.
666 $str =~ /^\w/; # No match, as $str isn't in UTF-8 format.
667 $str .= "\x{0e0b}"; # Now $str is in UTF-8 format.
668 $str =~ /^\w/; # Match! $str is now in UTF-8 format.
669 chop $str;
670 $str =~ /^\w/; # Still a match! $str remains in UTF-8 format.
671 This modifier is automatically selected by default when none of the
673 others are, so yet another name for it is "Default".
674 Because of the unexpected behaviors associated with this modifier, you
676 probably should only explicitly use it to maintain weird backward
677 compatibilities.
678 /a (and /aa)
680 This modifier stands for ASCII-restrict (or ASCII-safe). This modifier
682 may be doubled-up to increase its effect.
683 When it appears singly, it causes the sequences "\d", "\s", "\w", and
685 the Posix character classes to match only in the ASCII range. They
686 thus revert to their pre-5.6, pre-Unicode meanings. Under "/a", "\d"
687 always means precisely the digits "0" to "9"; "\s" means the five
688 characters "[ \f\n\r\t]", and starting in Perl v5.18, the vertical tab;
689 "\w" means the 63 characters "[A-Za-z0-9_]"; and likewise, all the
690 Posix classes such as "[[:print:]]" match only the appropriate ASCII-
691 range characters.
692 This modifier is useful for people who only incidentally use Unicode,
694 and who do not wish to be burdened with its complexities and security
695 concerns.
696 With "/a", one can write "\d" with confidence that it will only match
698 ASCII characters, and should the need arise to match beyond ASCII, you
699 can instead use "\p{Digit}" (or "\p{Word}" for "\w"). There are
700 similar "\p{...}" constructs that can match beyond ASCII both white
701 space (see "Whitespace" in perlrecharclass), and Posix classes (see
702 "POSIX Character Classes" in perlrecharclass). Thus, this modifier
703 doesn't mean you can't use Unicode, it means that to get Unicode
704 matching you must explicitly use a construct ("\p{}", "\P{}") that
705 signals Unicode.
706 As you would expect, this modifier causes, for example, "\D" to mean
708 the same thing as "[^0-9]"; in fact, all non-ASCII characters match
709 "\D", "\S", and "\W". "\b" still means to match at the boundary
710 between "\w" and "\W", using the "/a" definitions of them (similarly
711 for "\B").
712 Otherwise, "/a" behaves like the "/u" modifier, in that case-
714 insensitive matching uses Unicode rules; for example, "k" will match
715 the Unicode "\N{KELVIN SIGN}" under "/i" matching, and code points in
716 the Latin1 range, above ASCII will have Unicode rules when it comes to
717 case-insensitive matching.
718 To forbid ASCII/non-ASCII matches (like "k" with "\N{KELVIN SIGN}"),
720 specify the "a" twice, for example "/aai" or "/aia". (The first
721 occurrence of "a" restricts the "\d", etc., and the second occurrence
722 adds the "/i" restrictions.) But, note that code points outside the
723 ASCII range will use Unicode rules for "/i" matching, so the modifier
724 doesn't really restrict things to just ASCII; it just forbids the
725 intermixing of ASCII and non-ASCII.
726 To summarize, this modifier provides protection for applications that
728 don't wish to be exposed to all of Unicode. Specifying it twice gives
729 added protection.
730 This modifier may be specified to be the default by "use re '/a'" or
732 "use re '/aa'". If you do so, you may actually have occasion to use
733 the "/u" modifier explicitly if there are a few regular expressions
734 where you do want full Unicode rules (but even here, it's best if
735 everything were under feature "unicode_strings", along with the "use re
736 '/aa'"). Also see "Which character set modifier is in effect?".
737 Which character set modifier is in effect?
739 Which of these modifiers is in effect at any given point in a regular
741 expression depends on a fairly complex set of interactions. These have
742 been designed so that in general you don't have to worry about it, but
743 this section gives the gory details. As explained below in "Extended
744 Patterns" it is possible to explicitly specify modifiers that apply
745 only to portions of a regular expression. The innermost always has
746 priority over any outer ones, and one applying to the whole expression
747 has priority over any of the default settings that are described in the
748 remainder of this section.
749 The "use re '/foo'" pragma can be used to set default modifiers
751 (including these) for regular expressions compiled within its scope.
752 This pragma has precedence over the other pragmas listed below that
753 also change the defaults.
754 Otherwise, "use locale" sets the default modifier to "/l"; and "use
756 feature 'unicode_strings", or "use 5.012" (or higher) set the default
757 to "/u" when not in the same scope as either "use locale" or "use
758 bytes". ("use locale ':not_characters'" also sets the default to "/u",
759 overriding any plain "use locale".) Unlike the mechanisms mentioned
760 above, these affect operations besides regular expressions pattern
761 matching, and so give more consistent results with other operators,
762 including using "\U", "\l", etc. in substitution replacements.
763 If none of the above apply, for backwards compatibility reasons, the
765 "/d" modifier is the one in effect by default. As this can lead to
766 unexpected results, it is best to specify which other rule set should
767 be used.
768 Character set modifier behavior prior to Perl 5.14
770 Prior to 5.14, there were no explicit modifiers, but "/l" was implied
772 for regexes compiled within the scope of "use locale", and "/d" was
773 implied otherwise. However, interpolating a regex into a larger regex
774 would ignore the original compilation in favor of whatever was in
775 effect at the time of the second compilation. There were a number of
776 inconsistencies (bugs) with the "/d" modifier, where Unicode rules
777 would be used when inappropriate, and vice versa. "\p{}" did not imply
778 Unicode rules, and neither did all occurrences of "\N{}", until 5.12.
779 Regular Expressions
781 Quantifiers
782 Quantifiers are used when a particular portion of a pattern needs to
784 match a certain number (or numbers) of times. If there isn't a
785 quantifier the number of times to match is exactly one. The following
786 standard quantifiers are recognized:
787 * Match 0 or more times
789 + Match 1 or more times
790 ? Match 1 or 0 times
791 {n} Match exactly n times
792 {n,} Match at least n times
793 {n,m} Match at least n but not more than m times
794 (If a non-escaped curly bracket occurs in a context other than one of
796 the quantifiers listed above, where it does not form part of a
797 backslashed sequence like "\x{...}", it is either a fatal syntax error,
798 or treated as a regular character, generally with a deprecation warning
799 raised. To escape it, you can precede it with a backslash ("\{") or
800 enclose it within square brackets ("[{]"). This change will allow for
801 future syntax extensions (like making the lower bound of a quantifier
802 optional), and better error checking of quantifiers).
803 The "*" quantifier is equivalent to "{0,}", the "+" quantifier to
805 "{1,}", and the "?" quantifier to "{0,1}". n and m are limited to non-
806 negative integral values less than a preset limit defined when perl is
807 built. This is usually 32766 on the most common platforms. The actual
808 limit can be seen in the error message generated by code such as this:
809 $_ **= $_ , / {$_} / for 2 .. 42;
811 By default, a quantified subpattern is "greedy", that is, it will match
813 as many times as possible (given a particular starting location) while
814 still allowing the rest of the pattern to match. If you want it to
815 match the minimum number of times possible, follow the quantifier with
816 a "?". Note that the meanings don't change, just the "greediness":
817 *? Match 0 or more times, not greedily
819 +? Match 1 or more times, not greedily
820 ?? Match 0 or 1 time, not greedily
821 {n}? Match exactly n times, not greedily (redundant)
822 {n,}? Match at least n times, not greedily
823 {n,m}? Match at least n but not more than m times, not greedily
824 Normally when a quantified subpattern does not allow the rest of the
826 overall pattern to match, Perl will backtrack. However, this behaviour
827 is sometimes undesirable. Thus Perl provides the "possessive"
828 quantifier form as well.
829 *+ Match 0 or more times and give nothing back
831 ++ Match 1 or more times and give nothing back
832 ?+ Match 0 or 1 time and give nothing back
833 {n}+ Match exactly n times and give nothing back (redundant)
834 {n,}+ Match at least n times and give nothing back
835 {n,m}+ Match at least n but not more than m times and give nothing back
836 For instance,
838 'aaaa' =~ /a++a/
840 will never match, as the "a++" will gobble up all the "a"'s in the
842 string and won't leave any for the remaining part of the pattern. This
843 feature can be extremely useful to give perl hints about where it
844 shouldn't backtrack. For instance, the typical "match a double-quoted
845 string" problem can be most efficiently performed when written as:
846 /"(?:[^"\\]++|\\.)*+"/
848 as we know that if the final quote does not match, backtracking will
850 not help. See the independent subexpression ""(?>pattern)"" for more
851 details; possessive quantifiers are just syntactic sugar for that
852 construct. For instance the above example could also be written as
853 follows:
854 /"(?>(?:(?>[^"\\]+)|\\.)*)"/
856 Note that the possessive quantifier modifier can not be be combined
858 with the non-greedy modifier. This is because it would make no sense.
859 Consider the follow equivalency table:
860 Illegal Legal
862 ------------ ------
863 X??+ X{0}
864 X+?+ X{1}
865 X{min,max}?+ X{min}
866 Escape sequences
868 Because patterns are processed as double-quoted strings, the following
870 also work:
871 \t tab (HT, TAB)
873 \n newline (LF, NL)
874 \r return (CR)
875 \f form feed (FF)
876 \a alarm (bell) (BEL)
877 \e escape (think troff) (ESC)
878 \cK control char (example: VT)
879 \x{}, \x00 character whose ordinal is the given hexadecimal number
880 \N{name} named Unicode character or character sequence
881 \N{U+263D} Unicode character (example: FIRST QUARTER MOON)
882 \o{}, \000 character whose ordinal is the given octal number
883 \l lowercase next char (think vi)
884 \u uppercase next char (think vi)
885 \L lowercase until \E (think vi)
886 \U uppercase until \E (think vi)
887 \Q quote (disable) pattern metacharacters until \E
888 \E end either case modification or quoted section, think vi
889 Details are in "Quote and Quote-like Operators" in perlop.
891 Character Classes and other Special Escapes
893 In addition, Perl defines the following:
895 Sequence Note Description
897 [...] [1] Match a character according to the rules of the
898 bracketed character class defined by the "...".
899 Example: [a-z] matches "a" or "b" or "c" ... or "z"
900 [[:...:]] [2] Match a character according to the rules of the POSIX
901 character class "..." within the outer bracketed
902 character class. Example: [[:upper:]] matches any
903 uppercase character.
904 (?[...]) [8] Extended bracketed character class
905 \w [3] Match a "word" character (alphanumeric plus "_", plus
906 other connector punctuation chars plus Unicode
907 marks)
908 \W [3] Match a non-"word" character
909 \s [3] Match a whitespace character
910 \S [3] Match a non-whitespace character
911 \d [3] Match a decimal digit character
912 \D [3] Match a non-digit character
913 \pP [3] Match P, named property. Use \p{Prop} for longer names
914 \PP [3] Match non-P
915 \X [4] Match Unicode "eXtended grapheme cluster"
916 \1 [5] Backreference to a specific capture group or buffer.
917 '1' may actually be any positive integer.
918 \g1 [5] Backreference to a specific or previous group,
919 \g{-1} [5] The number may be negative indicating a relative
920 previous group and may optionally be wrapped in
921 curly brackets for safer parsing.
922 \g{name} [5] Named backreference
923 \k<name> [5] Named backreference
924 \K [6] Keep the stuff left of the \K, don't include it in $&
925 \N [7] Any character but \n. Not affected by /s modifier
926 \v [3] Vertical whitespace
927 \V [3] Not vertical whitespace
928 \h [3] Horizontal whitespace
929 \H [3] Not horizontal whitespace
930 \R [4] Linebreak
931 [1] See "Bracketed Character Classes" in perlrecharclass for details.
933 [2] See "POSIX Character Classes" in perlrecharclass for details.
935 [3] See "Backslash sequences" in perlrecharclass for details.
937 [4] See "Misc" in perlrebackslash for details.
939 [5] See "Capture groups" below for details.
941 [6] See "Extended Patterns" below for details.
943 [7] Note that "\N" has two meanings. When of the form "\N{NAME}", it
945 matches the character or character sequence whose name is "NAME";
946 and similarly when of the form "\N{U+hex}", it matches the
947 character whose Unicode code point is hex. Otherwise it matches
948 any character but "\n".
949 [8] See "Extended Bracketed Character Classes" in perlrecharclass for
951 details.
952 Assertions
954 Besides "^" and "$", Perl defines the following zero-width assertions:
956 \b{} Match at Unicode boundary of specified type
958 \B{} Match where corresponding \b{} doesn't match
959 \b Match a \w\W or \W\w boundary
960 \B Match except at a \w\W or \W\w boundary
961 \A Match only at beginning of string
962 \Z Match only at end of string, or before newline at the end
963 \z Match only at end of string
964 \G Match only at pos() (e.g. at the end-of-match position
965 of prior m//g)
966 A Unicode boundary ("\b{}"), available starting in v5.22, is a spot
968 between two characters, or before the first character in the string, or
969 after the final character in the string where certain criteria defined
970 by Unicode are met. See "\b{}, \b, \B{}, \B" in perlrebackslash for
971 details.
972 A word boundary ("\b") is a spot between two characters that has a "\w"
974 on one side of it and a "\W" on the other side of it (in either order),
975 counting the imaginary characters off the beginning and end of the
976 string as matching a "\W". (Within character classes "\b" represents
977 backspace rather than a word boundary, just as it normally does in any
978 double-quoted string.) The "\A" and "\Z" are just like "^" and "$",
979 except that they won't match multiple times when the "/m" modifier is
980 used, while "^" and "$" will match at every internal line boundary. To
981 match the actual end of the string and not ignore an optional trailing
982 newline, use "\z".
983 The "\G" assertion can be used to chain global matches (using "m//g"),
985 as described in "Regexp Quote-Like Operators" in perlop. It is also
986 useful when writing "lex"-like scanners, when you have several patterns
987 that you want to match against consequent substrings of your string;
988 see the previous reference. The actual location where "\G" will match
989 can also be influenced by using "pos()" as an lvalue: see "pos" in
990 perlfunc. Note that the rule for zero-length matches (see "Repeated
991 Patterns Matching a Zero-length Substring") is modified somewhat, in
992 that contents to the left of "\G" are not counted when determining the
993 length of the match. Thus the following will not match forever:
994 my $string = 'ABC';
996 pos($string) = 1;
997 while ($string =~ /(.\G)/g) {
998 print $1;
999 }
1000 It will print 'A' and then terminate, as it considers the match to be
1002 zero-width, and thus will not match at the same position twice in a
1003 row.
1004 It is worth noting that "\G" improperly used can result in an infinite
1006 loop. Take care when using patterns that include "\G" in an
1007 alternation.
1008 Note also that "s///" will refuse to overwrite part of a substitution
1010 that has already been replaced; so for example this will stop after the
1011 first iteration, rather than iterating its way backwards through the
1012 string:
1013 $_ = "123456789";
1015 pos = 6;
1016 s/.(?=.\G)/X/g;
1017 print; # prints 1234X6789, not XXXXX6789
1018 Capture groups
1020 The grouping construct "( ... )" creates capture groups (also referred
1022 to as capture buffers). To refer to the current contents of a group
1023 later on, within the same pattern, use "\g1" (or "\g{1}") for the
1024 first, "\g2" (or "\g{2}") for the second, and so on. This is called a
1025 backreference.
1026 There is no limit to the number of captured substrings that you may
1035 use. Groups are numbered with the leftmost open parenthesis being
1036 number 1, etc. If a group did not match, the associated backreference
1037 won't match either. (This can happen if the group is optional, or in a
1038 different branch of an alternation.) You can omit the "g", and write
1039 "\1", etc, but there are some issues with this form, described below.
1040 You can also refer to capture groups relatively, by using a negative
1042 number, so that "\g-1" and "\g{-1}" both refer to the immediately
1043 preceding capture group, and "\g-2" and "\g{-2}" both refer to the
1044 group before it. For example:
1045 /
1047 (Y) # group 1
1048 ( # group 2
1049 (X) # group 3
1050 \g{-1} # backref to group 3
1051 \g{-3} # backref to group 1
1052 )
1053 /x
1054 would match the same as "/(Y) ( (X) \g3 \g1 )/x". This allows you to
1056 interpolate regexes into larger regexes and not have to worry about the
1057 capture groups being renumbered.
1058 You can dispense with numbers altogether and create named capture
1060 groups. The notation is "(?<name>...)" to declare and "\g{name}" to
1061 reference. (To be compatible with .Net regular expressions, "\g{name}"
1062 may also be written as "\k{name}", "\k<name>" or "\k'name'".) name
1063 must not begin with a number, nor contain hyphens. When different
1064 groups within the same pattern have the same name, any reference to
1065 that name assumes the leftmost defined group. Named groups count in
1066 absolute and relative numbering, and so can also be referred to by
1067 those numbers. (It's possible to do things with named capture groups
1068 that would otherwise require "(??{})".)
1069 Capture group contents are dynamically scoped and available to you
1071 outside the pattern until the end of the enclosing block or until the
1072 next successful match, whichever comes first. (See "Compound
1073 Statements" in perlsyn.) You can refer to them by absolute number
1074 (using "$1" instead of "\g1", etc); or by name via the "%+" hash, using
1075 "$+{name}".
1076 Braces are required in referring to named capture groups, but are
1078 optional for absolute or relative numbered ones. Braces are safer when
1079 creating a regex by concatenating smaller strings. For example if you
1080 have "qr/$a$b/", and $a contained "\g1", and $b contained "37", you
1081 would get "/\g137/" which is probably not what you intended.
1082 The "\g" and "\k" notations were introduced in Perl 5.10.0. Prior to
1084 that there were no named nor relative numbered capture groups.
1085 Absolute numbered groups were referred to using "\1", "\2", etc., and
1086 this notation is still accepted (and likely always will be). But it
1087 leads to some ambiguities if there are more than 9 capture groups, as
1088 "\10" could mean either the tenth capture group, or the character whose
1089 ordinal in octal is 010 (a backspace in ASCII). Perl resolves this
1090 ambiguity by interpreting "\10" as a backreference only if at least 10
1091 left parentheses have opened before it. Likewise "\11" is a
1092 backreference only if at least 11 left parentheses have opened before
1093 it. And so on. "\1" through "\9" are always interpreted as
1094 backreferences. There are several examples below that illustrate these
1095 perils. You can avoid the ambiguity by always using "\g{}" or "\g" if
1096 you mean capturing groups; and for octal constants always using "\o{}",
1097 or for "\077" and below, using 3 digits padded with leading zeros,
1098 since a leading zero implies an octal constant.
1099 The "\digit" notation also works in certain circumstances outside the
1101 pattern. See "Warning on \1 Instead of $1" below for details.
1102 Examples:
1104 s/^([^ ]*) *([^ ]*)/$2 $1/; # swap first two words
1106 /(.)\g1/ # find first doubled char
1108 and print "'$1' is the first doubled character\n";
1109 /(?<char>.)\k<char>/ # ... a different way
1111 and print "'$+{char}' is the first doubled character\n";
1112 /(?'char'.)\g1/ # ... mix and match
1114 and print "'$1' is the first doubled character\n";
1115 if (/Time: (..):(..):(..)/) { # parse out values
1117 $hours = $1;
1118 $minutes = $2;
1119 $seconds = $3;
1120 }
1121 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/ # \g10 is a backreference
1123 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/ # \10 is octal
1124 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/ # \10 is a backreference
1125 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1126 $a = '(.)\1'; # Creates problems when concatenated.
1128 $b = '(.)\g{1}'; # Avoids the problems.
1129 "aa" =~ /${a}/; # True
1130 "aa" =~ /${b}/; # True
1131 "aa0" =~ /${a}0/; # False!
1132 "aa0" =~ /${b}0/; # True
1133 "aa\x08" =~ /${a}0/; # True!
1134 "aa\x08" =~ /${b}0/; # False
1135 Several special variables also refer back to portions of the previous
1137 match. $+ returns whatever the last bracket match matched. $& returns
1138 the entire matched string. (At one point $0 did also, but now it
1139 returns the name of the program.) "$`" returns everything before the
1140 matched string. "$'" returns everything after the matched string. And
1141 $^N contains whatever was matched by the most-recently closed group
1142 (submatch). $^N can be used in extended patterns (see below), for
1143 example to assign a submatch to a variable.
1144 These special variables, like the "%+" hash and the numbered match
1146 variables ($1, $2, $3, etc.) are dynamically scoped until the end of
1147 the enclosing block or until the next successful match, whichever comes
1148 first. (See "Compound Statements" in perlsyn.)
1149 NOTE: Failed matches in Perl do not reset the match variables, which
1151 makes it easier to write code that tests for a series of more specific
1152 cases and remembers the best match.
1153 WARNING: If your code is to run on Perl 5.16 or earlier, beware that
1155 once Perl sees that you need one of $&, "$`", or "$'" anywhere in the
1156 program, it has to provide them for every pattern match. This may
1157 substantially slow your program.
1158 Perl uses the same mechanism to produce $1, $2, etc, so you also pay a
1160 price for each pattern that contains capturing parentheses. (To avoid
1161 this cost while retaining the grouping behaviour, use the extended
1162 regular expression "(?: ... )" instead.) But if you never use $&, "$`"
1163 or "$'", then patterns without capturing parentheses will not be
1164 penalized. So avoid $&, "$'", and "$`" if you can, but if you can't
1165 (and some algorithms really appreciate them), once you've used them
1166 once, use them at will, because you've already paid the price.
1167 Perl 5.16 introduced a slightly more efficient mechanism that notes
1169 separately whether each of "$`", $&, and "$'" have been seen, and thus
1170 may only need to copy part of the string. Perl 5.20 introduced a much
1171 more efficient copy-on-write mechanism which eliminates any slowdown.
1172 As another workaround for this problem, Perl 5.10.0 introduced
1174 "${^PREMATCH}", "${^MATCH}" and "${^POSTMATCH}", which are equivalent
1175 to "$`", $& and "$'", except that they are only guaranteed to be
1176 defined after a successful match that was executed with the "/p"
1177 (preserve) modifier. The use of these variables incurs no global
1178 performance penalty, unlike their punctuation character equivalents,
1179 however at the trade-off that you have to tell perl when you want to
1180 use them. As of Perl 5.20, these three variables are equivalent to
1181 "$`", $& and "$'", and "/p" is ignored.
1182 Quoting metacharacters
1184 Backslashed metacharacters in Perl are alphanumeric, such as "\b",
1185 "\w", "\n". Unlike some other regular expression languages, there are
1186 no backslashed symbols that aren't alphanumeric. So anything that
1187 looks like "\\", "\(", "\)", "\[", "\]", "\{", or "\}" is always
1188 interpreted as a literal character, not a metacharacter. This was once
1189 used in a common idiom to disable or quote the special meanings of
1190 regular expression metacharacters in a string that you want to use for
1191 a pattern. Simply quote all non-"word" characters:
1192 $pattern =~ s/(\W)/\\$1/g;
1194 (If "use locale" is set, then this depends on the current locale.)
1196 Today it is more common to use the "quotemeta()" function or the "\Q"
1197 metaquoting escape sequence to disable all metacharacters' special
1198 meanings like this:
1199 /$unquoted\Q$quoted\E$unquoted/
1201 Beware that if you put literal backslashes (those not inside
1203 interpolated variables) between "\Q" and "\E", double-quotish backslash
1204 interpolation may lead to confusing results. If you need to use
1205 literal backslashes within "\Q...\E", consult "Gory details of parsing
1206 quoted constructs" in perlop.
1207 "quotemeta()" and "\Q" are fully described in "quotemeta" in perlfunc.
1209 Extended Patterns
1211 Perl also defines a consistent extension syntax for features not found
1212 in standard tools like awk and lex. The syntax for most of these is a
1213 pair of parentheses with a question mark as the first thing within the
1214 parentheses. The character after the question mark indicates the
1215 extension.
1216 A question mark was chosen for this and for the minimal-matching
1218 construct because 1) question marks are rare in older regular
1219 expressions, and 2) whenever you see one, you should stop and
1220 "question" exactly what is going on. That's psychology....
1221 "(?#text)"
1223 A comment. The text is ignored. Note that Perl closes the comment
1224 as soon as it sees a ")", so there is no way to put a literal ")"
1225 in the comment. The pattern's closing delimiter must be escaped by
1226 a backslash if it appears in the comment.
1227 See "/x" for another way to have comments in patterns.
1229 Note that a comment can go just about anywhere, except in the
1231 middle of an escape sequence. Examples:
1232 qr/foo(?#comment)bar/' # Matches 'foobar'
1234 # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1236 qr/abc(?#comment between literal and its quantifier){1,3}d/
1237 # The pattern below generates a syntax error, because the '\p' must
1239 # be followed immediately by a '{'.
1240 qr/\p(?#comment between \p and its property name){Any}/
1241 # The pattern below generates a syntax error, because the initial
1243 # '\(' is a literal opening parenthesis, and so there is nothing
1244 # for the closing ')' to match
1245 qr/\(?#the backslash means this isn't a comment)p{Any}/
1246 # Comments can be used to fold long patterns into multiple lines
1248 qr/First part of a long regex(?#
1249 )remaining part/
1250 "(?adlupimnsx-imnsx)"
1252 "(?^alupimnsx)"
1253 One or more embedded pattern-match modifiers, to be turned on (or
1254 turned off if preceded by "-") for the remainder of the pattern or
1255 the remainder of the enclosing pattern group (if any).
1256 This is particularly useful for dynamically-generated patterns,
1258 such as those read in from a configuration file, taken from an
1259 argument, or specified in a table somewhere. Consider the case
1260 where some patterns want to be case-sensitive and some do not: The
1261 case-insensitive ones merely need to include "(?i)" at the front of
1262 the pattern. For example:
1263 $pattern = "foobar";
1265 if ( /$pattern/i ) { }
1266 # more flexible:
1268 $pattern = "(?i)foobar";
1270 if ( /$pattern/ ) { }
1271 These modifiers are restored at the end of the enclosing group. For
1273 example,
1274 ( (?i) blah ) \s+ \g1
1276 will match "blah" in any case, some spaces, and an exact (including
1278 the case!) repetition of the previous word, assuming the "/x"
1279 modifier, and no "/i" modifier outside this group.
1280 These modifiers do not carry over into named subpatterns called in
1282 the enclosing group. In other words, a pattern such as
1283 "((?i)(?&NAME))" does not change the case-sensitivity of the "NAME"
1284 pattern.
1285 A modifier is overridden by later occurrences of this construct in
1287 the same scope containing the same modifier, so that
1288 /((?im)foo(?-m)bar)/
1290 matches all of "foobar" case insensitively, but uses "/m" rules for
1292 only the "foo" portion. The "a" flag overrides "aa" as well;
1293 likewise "aa" overrides "a". The same goes for "x" and "xx".
1294 Hence, in
1295 /(?-x)foo/xx
1297 both "/x" and "/xx" are turned off during matching "foo". And in
1299 /(?x)foo/x
1301 "/x" but NOT "/xx" is turned on for matching "foo". (One might
1303 mistakenly think that since the inner "(?x)" is already in the
1304 scope of "/x", that the result would effectively be the sum of
1305 them, yielding "/xx". It doesn't work that way.) Similarly, doing
1306 something like "(?xx-x)foo" turns off all "x" behavior for matching
1307 "foo", it is not that you subtract 1 "x" from 2 to get 1 "x"
1308 remaining.
1309 Any of these modifiers can be set to apply globally to all regular
1311 expressions compiled within the scope of a "use re". See "'/flags'
1312 mode" in re.
1313 Starting in Perl 5.14, a "^" (caret or circumflex accent)
1315 immediately after the "?" is a shorthand equivalent to "d-imnsx".
1316 Flags (except "d") may follow the caret to override it. But a
1317 minus sign is not legal with it.
1318 Note that the "a", "d", "l", "p", and "u" modifiers are special in
1320 that they can only be enabled, not disabled, and the "a", "d", "l",
1321 and "u" modifiers are mutually exclusive: specifying one de-
1322 specifies the others, and a maximum of one (or two "a"'s) may
1323 appear in the construct. Thus, for example, "(?-p)" will warn when
1324 compiled under "use warnings"; "(?-d:...)" and "(?dl:...)" are
1325 fatal errors.
1326 Note also that the "p" modifier is special in that its presence
1328 anywhere in a pattern has a global effect.
1329 "(?:pattern)"
1331 "(?adluimnsx-imnsx:pattern)"
1332 "(?^aluimnsx:pattern)"
1333 This is for clustering, not capturing; it groups subexpressions
1334 like "()", but doesn't make backreferences as "()" does. So
1335 @fields = split(/\b(?:a|b|c)\b/)
1337 matches the same field delimiters as
1339 @fields = split(/\b(a|b|c)\b/)
1341 but doesn't spit out the delimiters themselves as extra fields
1343 (even though that's the behaviour of "split" in perlfunc when its
1344 pattern contains capturing groups). It's also cheaper not to
1345 capture characters if you don't need to.
1346 Any letters between "?" and ":" act as flags modifiers as with
1348 "(?adluimnsx-imnsx)". For example,
1349 /(?s-i:more.*than).*million/i
1351 is equivalent to the more verbose
1353 /(?:(?s-i)more.*than).*million/i
1355 Note that any "()" constructs enclosed within this one will still
1357 capture unless the "/n" modifier is in effect.
1358 Like the "(?adlupimnsx-imnsx)" construct, "aa" and "a" override
1360 each other, as do "xx" and "x". They are not additive. So, doing
1361 something like "(?xx-x:foo)" turns off all "x" behavior for
1362 matching "foo".
1363 Starting in Perl 5.14, a "^" (caret or circumflex accent)
1365 immediately after the "?" is a shorthand equivalent to "d-imnsx".
1366 Any positive flags (except "d") may follow the caret, so
1367 (?^x:foo)
1369 is equivalent to
1371 (?x-imns:foo)
1373 The caret tells Perl that this cluster doesn't inherit the flags of
1375 any surrounding pattern, but uses the system defaults ("d-imnsx"),
1376 modified by any flags specified.
1377 The caret allows for simpler stringification of compiled regular
1379 expressions. These look like
1380 (?^:pattern)
1382 with any non-default flags appearing between the caret and the
1384 colon. A test that looks at such stringification thus doesn't need
1385 to have the system default flags hard-coded in it, just the caret.
1386 If new flags are added to Perl, the meaning of the caret's
1387 expansion will change to include the default for those flags, so
1388 the test will still work, unchanged.
1389 Specifying a negative flag after the caret is an error, as the flag
1391 is redundant.
1392 Mnemonic for "(?^...)": A fresh beginning since the usual use of a
1394 caret is to match at the beginning.
1395 "(?|pattern)"
1397 This is the "branch reset" pattern, which has the special property
1398 that the capture groups are numbered from the same starting point
1399 in each alternation branch. It is available starting from perl
1400 5.10.0.
1401 Capture groups are numbered from left to right, but inside this
1403 construct the numbering is restarted for each branch.
1404 The numbering within each branch will be as normal, and any groups
1406 following this construct will be numbered as though the construct
1407 contained only one branch, that being the one with the most capture
1408 groups in it.
1409 This construct is useful when you want to capture one of a number
1411 of alternative matches.
1412 Consider the following pattern. The numbers underneath show in
1414 which group the captured content will be stored.
1415 # before ---------------branch-reset----------- after
1417 / ( a ) (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1418 # 1 2 2 3 2 3 4
1419 Be careful when using the branch reset pattern in combination with
1421 named captures. Named captures are implemented as being aliases to
1422 numbered groups holding the captures, and that interferes with the
1423 implementation of the branch reset pattern. If you are using named
1424 captures in a branch reset pattern, it's best to use the same
1425 names, in the same order, in each of the alternations:
1426 /(?| (?<a> x ) (?<b> y )
1428 | (?<a> z ) (?<b> w )) /x
1429 Not doing so may lead to surprises:
1431 "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1433 say $+{a}; # Prints '12'
1434 say $+{b}; # *Also* prints '12'.
1435 The problem here is that both the group named "a" and the group
1437 named "b" are aliases for the group belonging to $1.
1438 Lookaround Assertions
1440 Lookaround assertions are zero-width patterns which match a
1441 specific pattern without including it in $&. Positive assertions
1442 match when their subpattern matches, negative assertions match when
1443 their subpattern fails. Lookbehind matches text up to the current
1444 match position, lookahead matches text following the current match
1445 position.
1446 "(?=pattern)"
1448 "(*pla:pattern)"
1449 "(*positive_lookahead:pattern)"
1450 A zero-width positive lookahead assertion. For example,
1451 "/\w+(?=\t)/" matches a word followed by a tab, without
1452 including the tab in $&.
1453 The alphabetic forms are experimental; using them yields a
1455 warning in the "experimental::alpha_assertions" category.
1456 "(?!pattern)"
1458 "(*nla:pattern)"
1459 "(*negative_lookahead:pattern)"
1460 A zero-width negative lookahead assertion. For example
1461 "/foo(?!bar)/" matches any occurrence of "foo" that isn't
1462 followed by "bar". Note however that lookahead and lookbehind
1463 are NOT the same thing. You cannot use this for lookbehind.
1464 If you are looking for a "bar" that isn't preceded by a "foo",
1466 "/(?!foo)bar/" will not do what you want. That's because the
1467 "(?!foo)" is just saying that the next thing cannot be
1468 "foo"--and it's not, it's a "bar", so "foobar" will match. Use
1469 lookbehind instead (see below).
1470 The alphabetic forms are experimental; using them yields a
1472 warning in the "experimental::alpha_assertions" category.
1473 "(?<=pattern)"
1475 "\K"
1476 "(*plb:pattern)"
1477 "(*positive_lookbehind:pattern)"
1478 A zero-width positive lookbehind assertion. For example,
1479 "/(?<=\t)\w+/" matches a word that follows a tab, without
1480 including the tab in $&. Works only for fixed-width
1481 lookbehind.
1482 There is a special form of this construct, called "\K"
1484 (available since Perl 5.10.0), which causes the regex engine to
1485 "keep" everything it had matched prior to the "\K" and not
1486 include it in $&. This effectively provides variable-length
1487 lookbehind. The use of "\K" inside of another lookaround
1488 assertion is allowed, but the behaviour is currently not well
1489 defined.
1490 For various reasons "\K" may be significantly more efficient
1492 than the equivalent "(?<=...)" construct, and it is especially
1493 useful in situations where you want to efficiently remove
1494 something following something else in a string. For instance
1495 s/(foo)bar/$1/g;
1497 can be rewritten as the much more efficient
1499 s/foo\Kbar//g;
1501 The alphabetic forms (not including "\K" are experimental;
1503 using them yields a warning in the
1504 "experimental::alpha_assertions" category.
1505 "(?<!pattern)"
1507 "(*nlb:pattern)"
1508 "(*negative_lookbehind:pattern)"
1509 A zero-width negative lookbehind assertion. For example
1510 "/(?<!bar)foo/" matches any occurrence of "foo" that does not
1511 follow "bar". Works only for fixed-width lookbehind.
1512 The alphabetic forms are experimental; using them yields a
1514 warning in the "experimental::alpha_assertions" category.
1515 "(?<NAME>pattern)"
1517 "(?'NAME'pattern)"
1518 A named capture group. Identical in every respect to normal
1519 capturing parentheses "()" but for the additional fact that the
1520 group can be referred to by name in various regular expression
1521 constructs (like "\g{NAME}") and can be accessed by name after a
1522 successful match via "%+" or "%-". See perlvar for more details on
1523 the "%+" and "%-" hashes.
1524 If multiple distinct capture groups have the same name, then
1526 $+{NAME} will refer to the leftmost defined group in the match.
1527 The forms "(?'NAME'pattern)" and "(?<NAME>pattern)" are equivalent.
1529 NOTE: While the notation of this construct is the same as the
1531 similar function in .NET regexes, the behavior is not. In Perl the
1532 groups are numbered sequentially regardless of being named or not.
1533 Thus in the pattern
1534 /(x)(?<foo>y)(z)/
1536 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1538 the opposite which is what a .NET regex hacker might expect.
1539 Currently NAME is restricted to simple identifiers only. In other
1541 words, it must match "/^[_A-Za-z][_A-Za-z0-9]*\z/" or its Unicode
1542 extension (see utf8), though it isn't extended by the locale (see
1543 perllocale).
1544 NOTE: In order to make things easier for programmers with
1546 experience with the Python or PCRE regex engines, the pattern
1547 "(?P<NAME>pattern)" may be used instead of "(?<NAME>pattern)";
1548 however this form does not support the use of single quotes as a
1549 delimiter for the name.
1550 "\k<NAME>"
1552 "\k'NAME'"
1553 Named backreference. Similar to numeric backreferences, except that
1554 the group is designated by name and not number. If multiple groups
1555 have the same name then it refers to the leftmost defined group in
1556 the current match.
1557 It is an error to refer to a name not defined by a "(?<NAME>)"
1559 earlier in the pattern.
1560 Both forms are equivalent.
1562 NOTE: In order to make things easier for programmers with
1564 experience with the Python or PCRE regex engines, the pattern
1565 "(?P=NAME)" may be used instead of "\k<NAME>".
1566 "(?{ code })"
1568 WARNING: Using this feature safely requires that you understand its
1569 limitations. Code executed that has side effects may not perform
1570 identically from version to version due to the effect of future
1571 optimisations in the regex engine. For more information on this,
1572 see "Embedded Code Execution Frequency".
1573 This zero-width assertion executes any embedded Perl code. It
1575 always succeeds, and its return value is set as $^R.
1576 In literal patterns, the code is parsed at the same time as the
1578 surrounding code. While within the pattern, control is passed
1579 temporarily back to the perl parser, until the logically-balancing
1580 closing brace is encountered. This is similar to the way that an
1581 array index expression in a literal string is handled, for example
1582 "abc$array[ 1 + f('[') + g()]def"
1584 In particular, braces do not need to be balanced:
1586 s/abc(?{ f('{'); })/def/
1588 Even in a pattern that is interpolated and compiled at run-time,
1590 literal code blocks will be compiled once, at perl compile time;
1591 the following prints "ABCD":
1592 print "D";
1594 my $qr = qr/(?{ BEGIN { print "A" } })/;
1595 my $foo = "foo";
1596 /$foo$qr(?{ BEGIN { print "B" } })/;
1597 BEGIN { print "C" }
1598 In patterns where the text of the code is derived from run-time
1600 information rather than appearing literally in a source code
1601 /pattern/, the code is compiled at the same time that the pattern
1602 is compiled, and for reasons of security, "use re 'eval'" must be
1603 in scope. This is to stop user-supplied patterns containing code
1604 snippets from being executable.
1605 In situations where you need to enable this with "use re 'eval'",
1607 you should also have taint checking enabled. Better yet, use the
1608 carefully constrained evaluation within a Safe compartment. See
1609 perlsec for details about both these mechanisms.
1610 From the viewpoint of parsing, lexical variable scope and closures,
1612 /AAA(?{ BBB })CCC/
1614 behaves approximately like
1616 /AAA/ && do { BBB } && /CCC/
1618 Similarly,
1620 qr/AAA(?{ BBB })CCC/
1622 behaves approximately like
1624 sub { /AAA/ && do { BBB } && /CCC/ }
1626 In particular:
1628 { my $i = 1; $r = qr/(?{ print $i })/ }
1630 my $i = 2;
1631 /$r/; # prints "1"
1632 Inside a "(?{...})" block, $_ refers to the string the regular
1634 expression is matching against. You can also use "pos()" to know
1635 what is the current position of matching within this string.
1636 The code block introduces a new scope from the perspective of
1638 lexical variable declarations, but not from the perspective of
1639 "local" and similar localizing behaviours. So later code blocks
1640 within the same pattern will still see the values which were
1641 localized in earlier blocks. These accumulated localizations are
1642 undone either at the end of a successful match, or if the assertion
1643 is backtracked (compare "Backtracking"). For example,
1644 $_ = 'a' x 8;
1646 m<
1647 (?{ $cnt = 0 }) # Initialize $cnt.
1648 (
1649 a
1650 (?{
1651 local $cnt = $cnt + 1; # Update $cnt,
1652 # backtracking-safe.
1653 })
1654 )*
1655 aaaa
1656 (?{ $res = $cnt }) # On success copy to
1657 # non-localized location.
1658 >x;
1659 will initially increment $cnt up to 8; then during backtracking,
1661 its value will be unwound back to 4, which is the value assigned to
1662 $res. At the end of the regex execution, $cnt will be wound back
1663 to its initial value of 0.
1664 This assertion may be used as the condition in a
1666 (?(condition)yes-pattern|no-pattern)
1668 switch. If not used in this way, the result of evaluation of
1670 "code" is put into the special variable $^R. This happens
1671 immediately, so $^R can be used from other "(?{ code })" assertions
1672 inside the same regular expression.
1673 The assignment to $^R above is properly localized, so the old value
1675 of $^R is restored if the assertion is backtracked; compare
1676 "Backtracking".
1677 Note that the special variable $^N is particularly useful with
1679 code blocks to capture the results of submatches in variables
1680 without having to keep track of the number of nested parentheses.
1681 For example:
1682 $_ = "The brown fox jumps over the lazy dog";
1684 /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1685 print "color = $color, animal = $animal\n";
1686 "(??{ code })"
1688 WARNING: Using this feature safely requires that you understand its
1689 limitations. Code executed that has side effects may not perform
1690 identically from version to version due to the effect of future
1691 optimisations in the regex engine. For more information on this,
1692 see "Embedded Code Execution Frequency".
1693 This is a "postponed" regular subexpression. It behaves in exactly
1695 the same way as a "(?{ code })" code block as described above,
1696 except that its return value, rather than being assigned to $^R, is
1697 treated as a pattern, compiled if it's a string (or used as-is if
1698 its a qr// object), then matched as if it were inserted instead of
1699 this construct.
1700 During the matching of this sub-pattern, it has its own set of
1702 captures which are valid during the sub-match, but are discarded
1703 once control returns to the main pattern. For example, the
1704 following matches, with the inner pattern capturing "B" and
1705 matching "BB", while the outer pattern captures "A";
1706 my $inner = '(.)\1';
1708 "ABBA" =~ /^(.)(??{ $inner })\1/;
1709 print $1; # prints "A";
1710 Note that this means that there is no way for the inner pattern to
1712 refer to a capture group defined outside. (The code block itself
1713 can use $1, etc., to refer to the enclosing pattern's capture
1714 groups.) Thus, although
1715 ('a' x 100)=~/(??{'(.)' x 100})/
1717 will match, it will not set $1 on exit.
1719 The following pattern matches a parenthesized group:
1721 $re = qr{
1723 \(
1724 (?:
1725 (?> [^()]+ ) # Non-parens without backtracking
1726 |
1727 (??{ $re }) # Group with matching parens
1728 )*
1729 \)
1730 }x;
1731 See also "(?PARNO)" for a different, more efficient way to
1733 accomplish the same task.
1734 Executing a postponed regular expression too many times without
1736 consuming any input string will also result in a fatal error. The
1737 depth at which that happens is compiled into perl, so it can be
1738 changed with a custom build.
1739 "(?PARNO)" "(?-PARNO)" "(?+PARNO)" "(?R)" "(?0)"
1741 Recursive subpattern. Treat the contents of a given capture buffer
1742 in the current pattern as an independent subpattern and attempt to
1743 match it at the current position in the string. Information about
1744 capture state from the caller for things like backreferences is
1745 available to the subpattern, but capture buffers set by the
1746 subpattern are not visible to the caller.
1747 Similar to "(??{ code })" except that it does not involve executing
1749 any code or potentially compiling a returned pattern string;
1750 instead it treats the part of the current pattern contained within
1751 a specified capture group as an independent pattern that must match
1752 at the current position. Also different is the treatment of capture
1753 buffers, unlike "(??{ code })" recursive patterns have access to
1754 their caller's match state, so one can use backreferences safely.
1755 PARNO is a sequence of digits (not starting with 0) whose value
1757 reflects the paren-number of the capture group to recurse to.
1758 "(?R)" recurses to the beginning of the whole pattern. "(?0)" is an
1759 alternate syntax for "(?R)". If PARNO is preceded by a plus or
1760 minus sign then it is assumed to be relative, with negative numbers
1761 indicating preceding capture groups and positive ones following.
1762 Thus "(?-1)" refers to the most recently declared group, and
1763 "(?+1)" indicates the next group to be declared. Note that the
1764 counting for relative recursion differs from that of relative
1765 backreferences, in that with recursion unclosed groups are
1766 included.
1767 The following pattern matches a function "foo()" which may contain
1769 balanced parentheses as the argument.
1770 $re = qr{ ( # paren group 1 (full function)
1772 foo
1773 ( # paren group 2 (parens)
1774 \(
1775 ( # paren group 3 (contents of parens)
1776 (?:
1777 (?> [^()]+ ) # Non-parens without backtracking
1778 |
1779 (?2) # Recurse to start of paren group 2
1780 )*
1781 )
1782 \)
1783 )
1784 )
1785 }x;
1786 If the pattern was used as follows
1788 'foo(bar(baz)+baz(bop))'=~/$re/
1790 and print "\$1 = $1\n",
1791 "\$2 = $2\n",
1792 "\$3 = $3\n";
1793 the output produced should be the following:
1795 $1 = foo(bar(baz)+baz(bop))
1797 $2 = (bar(baz)+baz(bop))
1798 $3 = bar(baz)+baz(bop)
1799 If there is no corresponding capture group defined, then it is a
1801 fatal error. Recursing deeply without consuming any input string
1802 will also result in a fatal error. The depth at which that happens
1803 is compiled into perl, so it can be changed with a custom build.
1804 The following shows how using negative indexing can make it easier
1806 to embed recursive patterns inside of a "qr//" construct for later
1807 use:
1808 my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1810 if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1811 # do something here...
1812 }
1813 Note that this pattern does not behave the same way as the
1815 equivalent PCRE or Python construct of the same form. In Perl you
1816 can backtrack into a recursed group, in PCRE and Python the
1817 recursed into group is treated as atomic. Also, modifiers are
1818 resolved at compile time, so constructs like "(?i:(?1))" or
1819 "(?:(?i)(?1))" do not affect how the sub-pattern will be processed.
1820 "(?&NAME)"
1822 Recurse to a named subpattern. Identical to "(?PARNO)" except that
1823 the parenthesis to recurse to is determined by name. If multiple
1824 parentheses have the same name, then it recurses to the leftmost.
1825 It is an error to refer to a name that is not declared somewhere in
1827 the pattern.
1828 NOTE: In order to make things easier for programmers with
1830 experience with the Python or PCRE regex engines the pattern
1831 "(?P>NAME)" may be used instead of "(?&NAME)".
1832 "(?(condition)yes-pattern|no-pattern)"
1834 "(?(condition)yes-pattern)"
1835 Conditional expression. Matches "yes-pattern" if "condition" yields
1836 a true value, matches "no-pattern" otherwise. A missing pattern
1837 always matches.
1838 "(condition)" should be one of:
1840 an integer in parentheses
1842 (which is valid if the corresponding pair of parentheses
1843 matched);
1844 a lookahead/lookbehind/evaluate zero-width assertion;
1846 a name in angle brackets or single quotes
1847 (which is valid if a group with the given name matched);
1848 the special symbol "(R)"
1850 (true when evaluated inside of recursion or eval).
1851 Additionally the "R" may be followed by a number, (which will
1852 be true when evaluated when recursing inside of the appropriate
1853 group), or by &NAME, in which case it will be true only when
1854 evaluated during recursion in the named group.
1855 Here's a summary of the possible predicates:
1857 "(1)" "(2)" ...
1859 Checks if the numbered capturing group has matched something.
1860 Full syntax: "(?(1)then|else)"
1861 "(<NAME>)" "('NAME')"
1863 Checks if a group with the given name has matched something.
1864 Full syntax: "(?(<name>)then|else)"
1865 "(?=...)" "(?!...)" "(?<=...)" "(?<!...)"
1867 Checks whether the pattern matches (or does not match, for the
1868 "!" variants). Full syntax: "(?(?=lookahead)then|else)"
1869 "(?{ CODE })"
1871 Treats the return value of the code block as the condition.
1872 Full syntax: "(?(?{ code })then|else)"
1873 "(R)"
1875 Checks if the expression has been evaluated inside of
1876 recursion. Full syntax: "(?(R)then|else)"
1877 "(R1)" "(R2)" ...
1879 Checks if the expression has been evaluated while executing
1880 directly inside of the n-th capture group. This check is the
1881 regex equivalent of
1882 if ((caller(0))[3] eq 'subname') { ... }
1884 In other words, it does not check the full recursion stack.
1886 Full syntax: "(?(R1)then|else)"
1888 "(R&NAME)"
1890 Similar to "(R1)", this predicate checks to see if we're
1891 executing directly inside of the leftmost group with a given
1892 name (this is the same logic used by "(?&NAME)" to
1893 disambiguate). It does not check the full stack, but only the
1894 name of the innermost active recursion. Full syntax:
1895 "(?(R&name)then|else)"
1896 "(DEFINE)"
1898 In this case, the yes-pattern is never directly executed, and
1899 no no-pattern is allowed. Similar in spirit to "(?{0})" but
1900 more efficient. See below for details. Full syntax:
1901 "(?(DEFINE)definitions...)"
1902 For example:
1904 m{ ( \( )?
1906 [^()]+
1907 (?(1) \) )
1908 }x
1909 matches a chunk of non-parentheses, possibly included in
1911 parentheses themselves.
1912 A special form is the "(DEFINE)" predicate, which never executes
1914 its yes-pattern directly, and does not allow a no-pattern. This
1915 allows one to define subpatterns which will be executed only by the
1916 recursion mechanism. This way, you can define a set of regular
1917 expression rules that can be bundled into any pattern you choose.
1918 It is recommended that for this usage you put the DEFINE block at
1920 the end of the pattern, and that you name any subpatterns defined
1921 within it.
1922 Also, it's worth noting that patterns defined this way probably
1924 will not be as efficient, as the optimizer is not very clever about
1925 handling them.
1926 An example of how this might be used is as follows:
1928 /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1930 (?(DEFINE)
1931 (?<NAME_PAT>....)
1932 (?<ADDRESS_PAT>....)
1933 )/x
1934 Note that capture groups matched inside of recursion are not
1936 accessible after the recursion returns, so the extra layer of
1937 capturing groups is necessary. Thus $+{NAME_PAT} would not be
1938 defined even though $+{NAME} would be.
1939 Finally, keep in mind that subpatterns created inside a DEFINE
1941 block count towards the absolute and relative number of captures,
1942 so this:
1943 my @captures = "a" =~ /(.) # First capture
1945 (?(DEFINE)
1946 (?<EXAMPLE> 1 ) # Second capture
1947 )/x;
1948 say scalar @captures;
1949 Will output 2, not 1. This is particularly important if you intend
1951 to compile the definitions with the "qr//" operator, and later
1952 interpolate them in another pattern.
1953 "(?>pattern)"
1955 "(*atomic:pattern)"
1956 An "independent" subexpression, one which matches the substring
1957 that a standalone "pattern" would match if anchored at the given
1958 position, and it matches nothing other than this substring. This
1959 construct is useful for optimizations of what would otherwise be
1960 "eternal" matches, because it will not backtrack (see
1961 "Backtracking"). It may also be useful in places where the "grab
1962 all you can, and do not give anything back" semantic is desirable.
1963 For example: "^(?>a*)ab" will never match, since "(?>a*)" (anchored
1965 at the beginning of string, as above) will match all characters "a"
1966 at the beginning of string, leaving no "a" for "ab" to match. In
1967 contrast, "a*ab" will match the same as "a+b", since the match of
1968 the subgroup "a*" is influenced by the following group "ab" (see
1969 "Backtracking"). In particular, "a*" inside "a*ab" will match
1970 fewer characters than a standalone "a*", since this makes the tail
1971 match.
1972 "(?>pattern)" does not disable backtracking altogether once it has
1974 matched. It is still possible to backtrack past the construct, but
1975 not into it. So "((?>a*)|(?>b*))ar" will still match "bar".
1976 An effect similar to "(?>pattern)" may be achieved by writing
1978 "(?=(pattern))\g{-1}". This matches the same substring as a
1979 standalone "a+", and the following "\g{-1}" eats the matched
1980 string; it therefore makes a zero-length assertion into an analogue
1981 of "(?>...)". (The difference between these two constructs is that
1982 the second one uses a capturing group, thus shifting ordinals of
1983 backreferences in the rest of a regular expression.)
1984 Consider this pattern:
1986 m{ \(
1988 (
1989 [^()]+ # x+
1990 |
1991 \( [^()]* \)
1992 )+
1993 \)
1994 }x
1995 That will efficiently match a nonempty group with matching
1997 parentheses two levels deep or less. However, if there is no such
1998 group, it will take virtually forever on a long string. That's
1999 because there are so many different ways to split a long string
2000 into several substrings. This is what "(.+)+" is doing, and
2001 "(.+)+" is similar to a subpattern of the above pattern. Consider
2002 how the pattern above detects no-match on "((()aaaaaaaaaaaaaaaaaa"
2003 in several seconds, but that each extra letter doubles this time.
2004 This exponential performance will make it appear that your program
2005 has hung. However, a tiny change to this pattern
2006 m{ \(
2008 (
2009 (?> [^()]+ ) # change x+ above to (?> x+ )
2010 |
2011 \( [^()]* \)
2012 )+
2013 \)
2014 }x
2015 which uses "(?>...)" matches exactly when the one above does
2017 (verifying this yourself would be a productive exercise), but
2018 finishes in a fourth the time when used on a similar string with
2019 1000000 "a"s. Be aware, however, that, when this construct is
2020 followed by a quantifier, it currently triggers a warning message
2021 under the "use warnings" pragma or -w switch saying it "matches
2022 null string many times in regex".
2023 On simple groups, such as the pattern "(?> [^()]+ )", a comparable
2025 effect may be achieved by negative lookahead, as in "[^()]+ (?!
2026 [^()] )". This was only 4 times slower on a string with 1000000
2027 "a"s.
2028 The "grab all you can, and do not give anything back" semantic is
2030 desirable in many situations where on the first sight a simple
2031 "()*" looks like the correct solution. Suppose we parse text with
2032 comments being delimited by "#" followed by some optional
2033 (horizontal) whitespace. Contrary to its appearance, "#[ \t]*" is
2034 not the correct subexpression to match the comment delimiter,
2035 because it may "give up" some whitespace if the remainder of the
2036 pattern can be made to match that way. The correct answer is
2037 either one of these:
2038 (?>#[ \t]*)
2040 #[ \t]*(?![ \t])
2041 For example, to grab non-empty comments into $1, one should use
2043 either one of these:
2044 / (?> \# [ \t]* ) ( .+ ) /x;
2046 / \# [ \t]* ( [^ \t] .* ) /x;
2047 Which one you pick depends on which of these expressions better
2049 reflects the above specification of comments.
2050 In some literature this construct is called "atomic matching" or
2052 "possessive matching".
2053 Possessive quantifiers are equivalent to putting the item they are
2055 applied to inside of one of these constructs. The following
2056 equivalences apply:
2057 Quantifier Form Bracketing Form
2059 --------------- ---------------
2060 PAT*+ (?>PAT*)
2061 PAT++ (?>PAT+)
2062 PAT?+ (?>PAT?)
2063 PAT{min,max}+ (?>PAT{min,max})
2064 Nested "(?>...)" constructs are not no-ops, even if at first glance
2066 they might seem to be. This is because the nested "(?>...)" can
2067 restrict internal backtracking that otherwise might occur. For
2068 example,
2069 "abc" =~ /(?>a[bc]*c)/
2071 matches, but
2073 "abc" =~ /(?>a(?>[bc]*)c)/
2075 does not.
2077 The alphabetic form ("(*atomic:...)") is experimental; using it
2079 yields a warning in the "experimental::alpha_assertions" category.
2080 "(?[ ])"
2082 See "Extended Bracketed Character Classes" in perlrecharclass.
2083 Note that this feature is currently experimental; using it yields a
2085 warning in the "experimental::regex_sets" category.
2086 Backtracking
2088 NOTE: This section presents an abstract approximation of regular
2089 expression behavior. For a more rigorous (and complicated) view of the
2090 rules involved in selecting a match among possible alternatives, see
2091 "Combining RE Pieces".
2092 A fundamental feature of regular expression matching involves the
2094 notion called backtracking, which is currently used (when needed) by
2095 all regular non-possessive expression quantifiers, namely "*", "*?",
2096 "+", "+?", "{n,m}", and "{n,m}?". Backtracking is often optimized
2097 internally, but the general principle outlined here is valid.
2098 For a regular expression to match, the entire regular expression must
2100 match, not just part of it. So if the beginning of a pattern
2101 containing a quantifier succeeds in a way that causes later parts in
2102 the pattern to fail, the matching engine backs up and recalculates the
2103 beginning part--that's why it's called backtracking.
2104 Here is an example of backtracking: Let's say you want to find the
2106 word following "foo" in the string "Food is on the foo table.":
2107 $_ = "Food is on the foo table.";
2109 if ( /\b(foo)\s+(\w+)/i ) {
2110 print "$2 follows $1.\n";
2111 }
2112 When the match runs, the first part of the regular expression
2114 ("\b(foo)") finds a possible match right at the beginning of the
2115 string, and loads up $1 with "Foo". However, as soon as the matching
2116 engine sees that there's no whitespace following the "Foo" that it had
2117 saved in $1, it realizes its mistake and starts over again one
2118 character after where it had the tentative match. This time it goes
2119 all the way until the next occurrence of "foo". The complete regular
2120 expression matches this time, and you get the expected output of "table
2121 follows foo."
2122 Sometimes minimal matching can help a lot. Imagine you'd like to match
2124 everything between "foo" and "bar". Initially, you write something
2125 like this:
2126 $_ = "The food is under the bar in the barn.";
2128 if ( /foo(.*)bar/ ) {
2129 print "got <$1>\n";
2130 }
2131 Which perhaps unexpectedly yields:
2133 got <d is under the bar in the >
2135 That's because ".*" was greedy, so you get everything between the first
2137 "foo" and the last "bar". Here it's more effective to use minimal
2138 matching to make sure you get the text between a "foo" and the first
2139 "bar" thereafter.
2140 if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2142 got <d is under the >
2143 Here's another example. Let's say you'd like to match a number at the
2145 end of a string, and you also want to keep the preceding part of the
2146 match. So you write this:
2147 $_ = "I have 2 numbers: 53147";
2149 if ( /(.*)(\d*)/ ) { # Wrong!
2150 print "Beginning is <$1>, number is <$2>.\n";
2151 }
2152 That won't work at all, because ".*" was greedy and gobbled up the
2154 whole string. As "\d*" can match on an empty string the complete
2155 regular expression matched successfully.
2156 Beginning is <I have 2 numbers: 53147>, number is <>.
2158 Here are some variants, most of which don't work:
2160 $_ = "I have 2 numbers: 53147";
2162 @pats = qw{
2163 (.*)(\d*)
2164 (.*)(\d+)
2165 (.*?)(\d*)
2166 (.*?)(\d+)
2167 (.*)(\d+)$
2168 (.*?)(\d+)$
2169 (.*)\b(\d+)$
2170 (.*\D)(\d+)$
2171 };
2172 for $pat (@pats) {
2174 printf "%-12s ", $pat;
2175 if ( /$pat/ ) {
2176 print "<$1> <$2>\n";
2177 } else {
2178 print "FAIL\n";
2179 }
2180 }
2181 That will print out:
2183 (.*)(\d*) <I have 2 numbers: 53147> <>
2185 (.*)(\d+) <I have 2 numbers: 5314> <7>
2186 (.*?)(\d*) <> <>
2187 (.*?)(\d+) <I have > <2>
2188 (.*)(\d+)$ <I have 2 numbers: 5314> <7>
2189 (.*?)(\d+)$ <I have 2 numbers: > <53147>
2190 (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2191 (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2192 As you see, this can be a bit tricky. It's important to realize that a
2194 regular expression is merely a set of assertions that gives a
2195 definition of success. There may be 0, 1, or several different ways
2196 that the definition might succeed against a particular string. And if
2197 there are multiple ways it might succeed, you need to understand
2198 backtracking to know which variety of success you will achieve.
2199 When using lookahead assertions and negations, this can all get even
2201 trickier. Imagine you'd like to find a sequence of non-digits not
2202 followed by "123". You might try to write that as
2203 $_ = "ABC123";
2205 if ( /^\D*(?!123)/ ) { # Wrong!
2206 print "Yup, no 123 in $_\n";
2207 }
2208 But that isn't going to match; at least, not the way you're hoping. It
2210 claims that there is no 123 in the string. Here's a clearer picture of
2211 why that pattern matches, contrary to popular expectations:
2212 $x = 'ABC123';
2214 $y = 'ABC445';
2215 print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2217 print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2218 print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2220 print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2221 This prints
2223 2: got ABC
2225 3: got AB
2226 4: got ABC
2227 You might have expected test 3 to fail because it seems to a more
2229 general purpose version of test 1. The important difference between
2230 them is that test 3 contains a quantifier ("\D*") and so can use
2231 backtracking, whereas test 1 will not. What's happening is that you've
2232 asked "Is it true that at the start of $x, following 0 or more non-
2233 digits, you have something that's not 123?" If the pattern matcher had
2234 let "\D*" expand to "ABC", this would have caused the whole pattern to
2235 fail.
2236 The search engine will initially match "\D*" with "ABC". Then it will
2238 try to match "(?!123)" with "123", which fails. But because a
2239 quantifier ("\D*") has been used in the regular expression, the search
2240 engine can backtrack and retry the match differently in the hope of
2241 matching the complete regular expression.
2242 The pattern really, really wants to succeed, so it uses the standard
2244 pattern back-off-and-retry and lets "\D*" expand to just "AB" this
2245 time. Now there's indeed something following "AB" that is not "123".
2246 It's "C123", which suffices.
2247 We can deal with this by using both an assertion and a negation. We'll
2249 say that the first part in $1 must be followed both by a digit and by
2250 something that's not "123". Remember that the lookaheads are zero-
2251 width expressions--they only look, but don't consume any of the string
2252 in their match. So rewriting this way produces what you'd expect; that
2253 is, case 5 will fail, but case 6 succeeds:
2254 print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2256 print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2257 6: got ABC
2259 In other words, the two zero-width assertions next to each other work
2261 as though they're ANDed together, just as you'd use any built-in
2262 assertions: "/^$/" matches only if you're at the beginning of the line
2263 AND the end of the line simultaneously. The deeper underlying truth is
2264 that juxtaposition in regular expressions always means AND, except when
2265 you write an explicit OR using the vertical bar. "/ab/" means match
2266 "a" AND (then) match "b", although the attempted matches are made at
2267 different positions because "a" is not a zero-width assertion, but a
2268 one-width assertion.
2269 WARNING: Particularly complicated regular expressions can take
2271 exponential time to solve because of the immense number of possible
2272 ways they can use backtracking to try for a match. For example,
2273 without internal optimizations done by the regular expression engine,
2274 this will take a painfully long time to run:
2275 'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2277 And if you used "*"'s in the internal groups instead of limiting them
2279 to 0 through 5 matches, then it would take forever--or until you ran
2280 out of stack space. Moreover, these internal optimizations are not
2281 always applicable. For example, if you put "{0,5}" instead of "*" on
2282 the external group, no current optimization is applicable, and the
2283 match takes a long time to finish.
2284 A powerful tool for optimizing such beasts is what is known as an
2286 "independent group", which does not backtrack (see ""(?>pattern)"").
2287 Note also that zero-length lookahead/lookbehind assertions will not
2288 backtrack to make the tail match, since they are in "logical" context:
2289 only whether they match is considered relevant. For an example where
2290 side-effects of lookahead might have influenced the following match,
2291 see ""(?>pattern)"".
2292 Script Runs
2294 A script run is basically a sequence of characters, all from the same
2295 Unicode script (see "Scripts" in perlunicode), such as Latin or Greek.
2296 In most places a single word would never be written in multiple
2297 scripts, unless it is a spoofing attack. An infamous example, is
2298 paypal.com
2300 Those letters could all be Latin (as in the example just above), or
2302 they could be all Cyrillic (except for the dot), or they could be a
2303 mixture of the two. In the case of an internet address the ".com"
2304 would be in Latin, And any Cyrillic ones would cause it to be a
2305 mixture, not a script run. Someone clicking on such a link would not
2306 be directed to the real Paypal website, but an attacker would craft a
2307 look-alike one to attempt to gather sensitive information from the
2308 person.
2309 Starting in Perl 5.28, it is now easy to detect strings that aren't
2311 script runs. Simply enclose just about any pattern like either of
2312 these:
2313 (*script_run:pattern)
2315 (*sr:pattern)
2316 What happens is that after pattern succeeds in matching, it is
2318 subjected to the additional criterion that every character in it must
2319 be from the same script (see exceptions below). If this isn't true,
2320 backtracking occurs until something all in the same script is found
2321 that matches, or all possibilities are exhausted. This can cause a lot
2322 of backtracking, but generally, only malicious input will result in
2323 this, though the slow down could cause a denial of service attack. If
2324 your needs permit, it is best to make the pattern atomic. This is so
2325 likely to be what you want, that instead of writing this:
2326 (*script_run:(?>pattern))
2328 you can write either of these:
2330 (*atomic_script_run:pattern)
2332 (*asr:pattern)
2333 (See ""(?>pattern)"".)
2335 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2337 characters from their native scripts and base Chinese. Perl follows
2338 Unicode's UTS 39 (<http://unicode.org/reports/tr39/>) Unicode Security
2339 Mechanisms in allowing such mixtures.
2340 The rules used for matching decimal digits are slightly stricter. Many
2342 scripts have their own sets of digits equivalent to the Western 0
2343 through 9 ones. A few, such as Arabic, have more than one set. For a
2344 string to be considered a script run, all digits in it must come from
2345 the same set of ten, as determined by the first digit encountered. As
2346 an example,
2347 qr/(*script_run: \d+ \b )/x
2349 guarantees that the digits matched will all be from the same set of 10.
2351 You won't get a look-alike digit from a different script that has a
2352 different value than what it appears to be.
2353 Unicode has three pseudo scripts that are handled specially.
2355 "Unknown" is applied to code points whose meaning has yet to be
2357 determined. Perl currently will match as a script run, any single
2358 character string consisting of one of these code points. But any
2359 string longer than one code point containing one of these will not be
2360 considered a script run.
2361 "Inherited" is applied to characters that modify another, such as an
2363 accent of some type. These are considered to be in the script of the
2364 master character, and so never cause a script run to not match.
2365 The other one is "Common". This consists of mostly punctuation, emoji,
2367 and characters used in mathematics and music, the ASCII digits 0
2368 through 9, and full-width forms of these digits. These characters can
2369 appear intermixed in text in many of the world's scripts. These also
2370 don't cause a script run to not match. But like other scripts, all
2371 digits in a run must come from the same set of 10.
2372 This construct is non-capturing. You can add parentheses to pattern to
2374 capture, if desired. You will have to do this if you plan to use
2375 "(*ACCEPT) (*ACCEPT:arg)" and not have it bypass the script run
2376 checking.
2377 This feature is experimental, and the exact syntax and details of
2379 operation are subject to change; using it yields a warning in the
2380 "experimental::script_run" category.
2381 The "Script_Extensions" property is used as the basis for this feature.
2383 Special Backtracking Control Verbs
2385 These special patterns are generally of the form "(*VERB:ARG)". Unless
2386 otherwise stated the ARG argument is optional; in some cases, it is
2387 mandatory.
2388 Any pattern containing a special backtracking verb that allows an
2390 argument has the special behaviour that when executed it sets the
2391 current package's $REGERROR and $REGMARK variables. When doing so the
2392 following rules apply:
2393 On failure, the $REGERROR variable will be set to the ARG value of the
2395 verb pattern, if the verb was involved in the failure of the match. If
2396 the ARG part of the pattern was omitted, then $REGERROR will be set to
2397 the name of the last "(*MARK:NAME)" pattern executed, or to TRUE if
2398 there was none. Also, the $REGMARK variable will be set to FALSE.
2399 On a successful match, the $REGERROR variable will be set to FALSE, and
2401 the $REGMARK variable will be set to the name of the last
2402 "(*MARK:NAME)" pattern executed. See the explanation for the
2403 "(*MARK:NAME)" verb below for more details.
2404 NOTE: $REGERROR and $REGMARK are not magic variables like $1 and most
2406 other regex-related variables. They are not local to a scope, nor
2407 readonly, but instead are volatile package variables similar to
2408 $AUTOLOAD. They are set in the package containing the code that
2409 executed the regex (rather than the one that compiled it, where those
2410 differ). If necessary, you can use "local" to localize changes to
2411 these variables to a specific scope before executing a regex.
2412 If a pattern does not contain a special backtracking verb that allows
2414 an argument, then $REGERROR and $REGMARK are not touched at all.
2415 Verbs
2417 "(*PRUNE)" "(*PRUNE:NAME)"
2418 This zero-width pattern prunes the backtracking tree at the
2419 current point when backtracked into on failure. Consider the
2420 pattern "/A (*PRUNE) B/", where A and B are complex patterns.
2421 Until the "(*PRUNE)" verb is reached, A may backtrack as
2422 necessary to match. Once it is reached, matching continues in B,
2423 which may also backtrack as necessary; however, should B not
2424 match, then no further backtracking will take place, and the
2425 pattern will fail outright at the current starting position.
2426 The following example counts all the possible matching strings
2428 in a pattern (without actually matching any of them).
2429 'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2431 print "Count=$count\n";
2432 which produces:
2434 aaab
2436 aaa
2437 aa
2438 a
2439 aab
2440 aa
2441 a
2442 ab
2443 a
2444 Count=9
2445 If we add a "(*PRUNE)" before the count like the following
2447 'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2449 print "Count=$count\n";
2450 we prevent backtracking and find the count of the longest
2452 matching string at each matching starting point like so:
2453 aaab
2455 aab
2456 ab
2457 Count=3
2458 Any number of "(*PRUNE)" assertions may be used in a pattern.
2460 See also "(?>pattern)" and possessive quantifiers for other ways
2462 to control backtracking. In some cases, the use of "(*PRUNE)"
2463 can be replaced with a "(?>pattern)" with no functional
2464 difference; however, "(*PRUNE)" can be used to handle cases that
2465 cannot be expressed using a "(?>pattern)" alone.
2466 "(*SKIP)" "(*SKIP:NAME)"
2468 This zero-width pattern is similar to "(*PRUNE)", except that on
2469 failure it also signifies that whatever text that was matched
2470 leading up to the "(*SKIP)" pattern being executed cannot be
2471 part of any match of this pattern. This effectively means that
2472 the regex engine "skips" forward to this position on failure and
2473 tries to match again, (assuming that there is sufficient room to
2474 match).
2475 The name of the "(*SKIP:NAME)" pattern has special significance.
2477 If a "(*MARK:NAME)" was encountered while matching, then it is
2478 that position which is used as the "skip point". If no "(*MARK)"
2479 of that name was encountered, then the "(*SKIP)" operator has no
2480 effect. When used without a name the "skip point" is where the
2481 match point was when executing the "(*SKIP)" pattern.
2482 Compare the following to the examples in "(*PRUNE)"; note the
2484 string is twice as long:
2485 'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2487 print "Count=$count\n";
2488 outputs
2490 aaab
2492 aaab
2493 Count=2
2494 Once the 'aaab' at the start of the string has matched, and the
2496 "(*SKIP)" executed, the next starting point will be where the
2497 cursor was when the "(*SKIP)" was executed.
2498 "(*MARK:NAME)" "(*:NAME)"
2500 This zero-width pattern can be used to mark the point reached in
2501 a string when a certain part of the pattern has been
2502 successfully matched. This mark may be given a name. A later
2503 "(*SKIP)" pattern will then skip forward to that point if
2504 backtracked into on failure. Any number of "(*MARK)" patterns
2505 are allowed, and the NAME portion may be duplicated.
2506 In addition to interacting with the "(*SKIP)" pattern,
2508 "(*MARK:NAME)" can be used to "label" a pattern branch, so that
2509 after matching, the program can determine which branches of the
2510 pattern were involved in the match.
2511 When a match is successful, the $REGMARK variable will be set to
2513 the name of the most recently executed "(*MARK:NAME)" that was
2514 involved in the match.
2515 This can be used to determine which branch of a pattern was
2517 matched without using a separate capture group for each branch,
2518 which in turn can result in a performance improvement, as perl
2519 cannot optimize "/(?:(x)|(y)|(z))/" as efficiently as something
2520 like "/(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/".
2521 When a match has failed, and unless another verb has been
2523 involved in failing the match and has provided its own name to
2524 use, the $REGERROR variable will be set to the name of the most
2525 recently executed "(*MARK:NAME)".
2526 See "(*SKIP)" for more details.
2528 As a shortcut "(*MARK:NAME)" can be written "(*:NAME)".
2530 "(*THEN)" "(*THEN:NAME)"
2532 This is similar to the "cut group" operator "::" from Perl 6.
2533 Like "(*PRUNE)", this verb always matches, and when backtracked
2534 into on failure, it causes the regex engine to try the next
2535 alternation in the innermost enclosing group (capturing or
2536 otherwise) that has alternations. The two branches of a
2537 "(?(condition)yes-pattern|no-pattern)" do not count as an
2538 alternation, as far as "(*THEN)" is concerned.
2539 Its name comes from the observation that this operation combined
2541 with the alternation operator ("|") can be used to create what
2542 is essentially a pattern-based if/then/else block:
2543 ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2545 Note that if this operator is used and NOT inside of an
2547 alternation then it acts exactly like the "(*PRUNE)" operator.
2548 / A (*PRUNE) B /
2550 is the same as
2552 / A (*THEN) B /
2554 but
2556 / ( A (*THEN) B | C ) /
2558 is not the same as
2560 / ( A (*PRUNE) B | C ) /
2562 as after matching the A but failing on the B the "(*THEN)" verb
2564 will backtrack and try C; but the "(*PRUNE)" verb will simply
2565 fail.
2566 "(*COMMIT)" "(*COMMIT:args)"
2568 This is the Perl 6 "commit pattern" "<commit>" or ":::". It's a
2569 zero-width pattern similar to "(*SKIP)", except that when
2570 backtracked into on failure it causes the match to fail
2571 outright. No further attempts to find a valid match by advancing
2572 the start pointer will occur again. For example,
2573 'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2575 print "Count=$count\n";
2576 outputs
2578 aaab
2580 Count=1
2581 In other words, once the "(*COMMIT)" has been entered, and if
2583 the pattern does not match, the regex engine will not try any
2584 further matching on the rest of the string.
2585 "(*FAIL)" "(*F)" "(*FAIL:arg)"
2587 This pattern matches nothing and always fails. It can be used to
2588 force the engine to backtrack. It is equivalent to "(?!)", but
2589 easier to read. In fact, "(?!)" gets optimised into "(*FAIL)"
2590 internally. You can provide an argument so that if the match
2591 fails because of this "FAIL" directive the argument can be
2592 obtained from $REGERROR.
2593 It is probably useful only when combined with "(?{})" or
2595 "(??{})".
2596 "(*ACCEPT)" "(*ACCEPT:arg)"
2598 This pattern matches nothing and causes the end of successful
2599 matching at the point at which the "(*ACCEPT)" pattern was
2600 encountered, regardless of whether there is actually more to
2601 match in the string. When inside of a nested pattern, such as
2602 recursion, or in a subpattern dynamically generated via
2603 "(??{})", only the innermost pattern is ended immediately.
2604 If the "(*ACCEPT)" is inside of capturing groups then the groups
2606 are marked as ended at the point at which the "(*ACCEPT)" was
2607 encountered. For instance:
2608 'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2610 will match, and $1 will be "AB" and $2 will be "B", $3 will not
2612 be set. If another branch in the inner parentheses was matched,
2613 such as in the string 'ACDE', then the "D" and "E" would have to
2614 be matched as well.
2615 You can provide an argument, which will be available in the var
2617 $REGMARK after the match completes.
2618 Warning on "\1" Instead of $1
2620 Some people get too used to writing things like:
2621 $pattern =~ s/(\W)/\\\1/g;
2623 This is grandfathered (for \1 to \9) for the RHS of a substitute to
2625 avoid shocking the sed addicts, but it's a dirty habit to get into.
2626 That's because in PerlThink, the righthand side of an "s///" is a
2627 double-quoted string. "\1" in the usual double-quoted string means a
2628 control-A. The customary Unix meaning of "\1" is kludged in for
2629 "s///". However, if you get into the habit of doing that, you get
2630 yourself into trouble if you then add an "/e" modifier.
2631 s/(\d+)/ \1 + 1 /eg; # causes warning under -w
2633 Or if you try to do
2635 s/(\d+)/\1000/;
2637 You can't disambiguate that by saying "\{1}000", whereas you can fix it
2639 with "${1}000". The operation of interpolation should not be confused
2640 with the operation of matching a backreference. Certainly they mean
2641 two different things on the left side of the "s///".
2642 Repeated Patterns Matching a Zero-length Substring
2644 WARNING: Difficult material (and prose) ahead. This section needs a
2645 rewrite.
2646 Regular expressions provide a terse and powerful programming language.
2648 As with most other power tools, power comes together with the ability
2649 to wreak havoc.
2650 A common abuse of this power stems from the ability to make infinite
2652 loops using regular expressions, with something as innocuous as:
2653 'foo' =~ m{ ( o? )* }x;
2655 The "o?" matches at the beginning of ""foo"", and since the position in
2657 the string is not moved by the match, "o?" would match again and again
2658 because of the "*" quantifier. Another common way to create a similar
2659 cycle is with the looping modifier "/g":
2660 @matches = ( 'foo' =~ m{ o? }xg );
2662 or
2664 print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2666 or the loop implied by "split()".
2668 However, long experience has shown that many programming tasks may be
2670 significantly simplified by using repeated subexpressions that may
2671 match zero-length substrings. Here's a simple example being:
2672 @chars = split //, $string; # // is not magic in split
2674 ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2675 Thus Perl allows such constructs, by forcefully breaking the infinite
2677 loop. The rules for this are different for lower-level loops given by
2678 the greedy quantifiers "*+{}", and for higher-level ones like the "/g"
2679 modifier or "split()" operator.
2680 The lower-level loops are interrupted (that is, the loop is broken)
2682 when Perl detects that a repeated expression matched a zero-length
2683 substring. Thus
2684 m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2686 is made equivalent to
2688 m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2690 For example, this program
2692 #!perl -l
2694 "aaaaab" =~ /
2695 (?:
2696 a # non-zero
2697 | # or
2698 (?{print "hello"}) # print hello whenever this
2699 # branch is tried
2700 (?=(b)) # zero-width assertion
2701 )* # any number of times
2702 /x;
2703 print $&;
2704 print $1;
2705 prints
2707 hello
2709 aaaaa
2710 b
2711 Notice that "hello" is only printed once, as when Perl sees that the
2713 sixth iteration of the outermost "(?:)*" matches a zero-length string,
2714 it stops the "*".
2715 The higher-level loops preserve an additional state between iterations:
2717 whether the last match was zero-length. To break the loop, the
2718 following match after a zero-length match is prohibited to have a
2719 length of zero. This prohibition interacts with backtracking (see
2720 "Backtracking"), and so the second best match is chosen if the best
2721 match is of zero length.
2722 For example:
2724 $_ = 'bar';
2726 s/\w??/<$&>/g;
2727 results in "<><b><><a><><r><>". At each position of the string the
2729 best match given by non-greedy "??" is the zero-length match, and the
2730 second best match is what is matched by "\w". Thus zero-length matches
2731 alternate with one-character-long matches.
2732 Similarly, for repeated "m/()/g" the second-best match is the match at
2734 the position one notch further in the string.
2735 The additional state of being matched with zero-length is associated
2737 with the matched string, and is reset by each assignment to "pos()".
2738 Zero-length matches at the end of the previous match are ignored during
2739 "split".
2740 Combining RE Pieces
2742 Each of the elementary pieces of regular expressions which were
2743 described before (such as "ab" or "\Z") could match at most one
2744 substring at the given position of the input string. However, in a
2745 typical regular expression these elementary pieces are combined into
2746 more complicated patterns using combining operators "ST", "S|T", "S*"
2747 etc. (in these examples "S" and "T" are regular subexpressions).
2748 Such combinations can include alternatives, leading to a problem of
2750 choice: if we match a regular expression "a|ab" against "abc", will it
2751 match substring "a" or "ab"? One way to describe which substring is
2752 actually matched is the concept of backtracking (see "Backtracking").
2753 However, this description is too low-level and makes you think in terms
2754 of a particular implementation.
2755 Another description starts with notions of "better"/"worse". All the
2757 substrings which may be matched by the given regular expression can be
2758 sorted from the "best" match to the "worst" match, and it is the "best"
2759 match which is chosen. This substitutes the question of "what is
2760 chosen?" by the question of "which matches are better, and which are
2761 worse?".
2762 Again, for elementary pieces there is no such question, since at most
2764 one match at a given position is possible. This section describes the
2765 notion of better/worse for combining operators. In the description
2766 below "S" and "T" are regular subexpressions.
2767 "ST"
2769 Consider two possible matches, "AB" and "A'B'", "A" and "A'" are
2770 substrings which can be matched by "S", "B" and "B'" are substrings
2771 which can be matched by "T".
2772 If "A" is a better match for "S" than "A'", "AB" is a better match
2774 than "A'B'".
2775 If "A" and "A'" coincide: "AB" is a better match than "AB'" if "B"
2777 is a better match for "T" than "B'".
2778 "S|T"
2780 When "S" can match, it is a better match than when only "T" can
2781 match.
2782 Ordering of two matches for "S" is the same as for "S". Similar
2784 for two matches for "T".
2785 "S{REPEAT_COUNT}"
2787 Matches as "SSS...S" (repeated as many times as necessary).
2788 "S{min,max}"
2790 Matches as "S{max}|S{max-1}|...|S{min+1}|S{min}".
2791 "S{min,max}?"
2793 Matches as "S{min}|S{min+1}|...|S{max-1}|S{max}".
2794 "S?", "S*", "S+"
2796 Same as "S{0,1}", "S{0,BIG_NUMBER}", "S{1,BIG_NUMBER}"
2797 respectively.
2798 "S??", "S*?", "S+?"
2800 Same as "S{0,1}?", "S{0,BIG_NUMBER}?", "S{1,BIG_NUMBER}?"
2801 respectively.
2802 "(?>S)"
2804 Matches the best match for "S" and only that.
2805 "(?=S)", "(?<=S)"
2807 Only the best match for "S" is considered. (This is important only
2808 if "S" has capturing parentheses, and backreferences are used
2809 somewhere else in the whole regular expression.)
2810 "(?!S)", "(?<!S)"
2812 For this grouping operator there is no need to describe the
2813 ordering, since only whether or not "S" can match is important.
2814 "(??{ EXPR })", "(?PARNO)"
2816 The ordering is the same as for the regular expression which is the
2817 result of EXPR, or the pattern contained by capture group PARNO.
2818 "(?(condition)yes-pattern|no-pattern)"
2820 Recall that which of "yes-pattern" or "no-pattern" actually matches
2821 is already determined. The ordering of the matches is the same as
2822 for the chosen subexpression.
2823 The above recipes describe the ordering of matches at a given position.
2825 One more rule is needed to understand how a match is determined for the
2826 whole regular expression: a match at an earlier position is always
2827 better than a match at a later position.
2828 Creating Custom RE Engines
2830 As of Perl 5.10.0, one can create custom regular expression engines.
2831 This is not for the faint of heart, as they have to plug in at the C
2832 level. See perlreapi for more details.
2833 As an alternative, overloaded constants (see overload) provide a simple
2835 way to extend the functionality of the RE engine, by substituting one
2836 pattern for another.
2837 Suppose that we want to enable a new RE escape-sequence "\Y|" which
2839 matches at a boundary between whitespace characters and non-whitespace
2840 characters. Note that "(?=\S)(?<!\S)|(?!\S)(?<=\S)" matches exactly at
2841 these positions, so we want to have each "\Y|" in the place of the more
2842 complicated version. We can create a module "customre" to do this:
2843 package customre;
2845 use overload;
2846 sub import {
2848 shift;
2849 die "No argument to customre::import allowed" if @_;
2850 overload::constant 'qr' => \&convert;
2851 }
2852 sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2854 # We must also take care of not escaping the legitimate \\Y|
2856 # sequence, hence the presence of '\\' in the conversion rules.
2857 my %rules = ( '\\' => '\\\\',
2858 'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2859 sub convert {
2860 my $re = shift;
2861 $re =~ s{
2862 \\ ( \\ | Y . )
2863 }
2864 { $rules{$1} or invalid($re,$1) }sgex;
2865 return $re;
2866 }
2867 Now "use customre" enables the new escape in constant regular
2869 expressions, i.e., those without any runtime variable interpolations.
2870 As documented in overload, this conversion will work only over literal
2871 parts of regular expressions. For "\Y|$re\Y|" the variable part of
2872 this regular expression needs to be converted explicitly (but only if
2873 the special meaning of "\Y|" should be enabled inside $re):
2874 use customre;
2876 $re = <>;
2877 chomp $re;
2878 $re = customre::convert $re;
2879 /\Y|$re\Y|/;
2880 Embedded Code Execution Frequency
2882 The exact rules for how often "(??{})" and "(?{})" are executed in a
2883 pattern are unspecified. In the case of a successful match you can
2884 assume that they DWIM and will be executed in left to right order the
2885 appropriate number of times in the accepting path of the pattern as
2886 would any other meta-pattern. How non-accepting pathways and match
2887 failures affect the number of times a pattern is executed is
2888 specifically unspecified and may vary depending on what optimizations
2889 can be applied to the pattern and is likely to change from version to
2890 version.
2891 For instance in
2893 "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2895 the exact number of times "a" or "b" are printed out is unspecified for
2897 failure, but you may assume they will be printed at least once during a
2898 successful match, additionally you may assume that if "b" is printed,
2899 it will be preceded by at least one "a".
2900 In the case of branching constructs like the following:
2902 /a(b|(?{ print "a" }))c(?{ print "c" })/;
2904 you can assume that the input "ac" will output "ac", and that "abc"
2906 will output only "c".
2907 When embedded code is quantified, successful matches will call the code
2909 once for each matched iteration of the quantifier. For example:
2910 "good" =~ /g(?:o(?{print "o"}))*d/;
2912 will output "o" twice.
2914 PCRE/Python Support
2916 As of Perl 5.10.0, Perl supports several Python/PCRE-specific
2917 extensions to the regex syntax. While Perl programmers are encouraged
2918 to use the Perl-specific syntax, the following are also accepted:
2919 "(?P<NAME>pattern)"
2921 Define a named capture group. Equivalent to "(?<NAME>pattern)".
2922 "(?P=NAME)"
2924 Backreference to a named capture group. Equivalent to "\g{NAME}".
2925 "(?P>NAME)"
2927 Subroutine call to a named capture group. Equivalent to "(?&NAME)".
2928
2930 There are a number of issues with regard to case-insensitive matching
2931 in Unicode rules. See "i" under "Modifiers" above.
2932 This document varies from difficult to understand to completely and
2934 utterly opaque. The wandering prose riddled with jargon is hard to
2935 fathom in several places.
2936 This document needs a rewrite that separates the tutorial content from
2938 the reference content.
2939
2941 The syntax of patterns used in Perl pattern matching evolved from those
2942 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
2943 routines. (The code is actually derived (distantly) from Henry
2944 Spencer's freely redistributable reimplementation of those V8
2945 routines.)
2946 perlrequick.
2948 perlretut.
2950 "Regexp Quote-Like Operators" in perlop.
2952 "Gory details of parsing quoted constructs" in perlop.
2954 perlfaq6.
2956 "pos" in perlfunc.
2958 perllocale.
2960 perlebcdic.
2962 Mastering Regular Expressions by Jeffrey Friedl, published by O'Reilly
2964 and Associates.
2965perl v5.28.2 2019-04-05 PERLRE(1)