1PERLUNIFAQ(1) Perl Programmers Reference Guide PERLUNIFAQ(1)
2
6 perlunifaq - Perl Unicode FAQ
7
9 This is a list of questions and answers about Unicode in Perl, intended
10 to be read after perlunitut.
11 perlunitut isn't really a Unicode tutorial, is it?
13 No, and this isn't really a Unicode FAQ.
14 Perl has an abstracted interface for all supported character encodings,
16 so this is actually a generic "Encode" tutorial and "Encode" FAQ. But
17 many people think that Unicode is special and magical, and I didn't
18 want to disappoint them, so I decided to call the document a Unicode
19 tutorial.
20 What character encodings does Perl support?
22 To find out which character encodings your Perl supports, run:
23 perl -MEncode -le "print for Encode->encodings(':all')"
25 Which version of perl should I use?
27 Well, if you can, upgrade to the most recent, but certainly 5.8.1 or
28 newer. The tutorial and FAQ assume the latest release.
29 You should also check your modules, and upgrade them if necessary. For
31 example, HTML::Entities requires version >= 1.32 to function correctly,
32 even though the changelog is silent about this.
33 What about binary data, like images?
35 Well, apart from a bare "binmode $fh", you shouldn't treat them
36 specially. (The binmode is needed because otherwise Perl may convert
37 line endings on Win32 systems.)
38 Be careful, though, to never combine text strings with binary strings.
40 If you need text in a binary stream, encode your text strings first
41 using the appropriate encoding, then join them with binary strings. See
42 also: "What if I don't encode?".
43 When should I decode or encode?
45 Whenever you're communicating text with anything that is external to
46 your perl process, like a database, a text file, a socket, or another
47 program. Even if the thing you're communicating with is also written in
48 Perl.
49 What if I don't decode?
51 Whenever your encoded, binary string is used together with a text
52 string, Perl will assume that your binary string was encoded with
53 ISO-8859-1, also known as latin-1. If it wasn't latin-1, then your data
54 is unpleasantly converted. For example, if it was UTF-8, the individual
55 bytes of multibyte characters are seen as separate characters, and then
56 again converted to UTF-8. Such double encoding can be compared to
57 double HTML encoding (">"), or double URI encoding (%253E).
58 This silent implicit decoding is known as "upgrading". That may sound
60 positive, but it's best to avoid it.
61 What if I don't encode?
63 Your text string will be sent using the bytes in Perl's internal
64 format. In some cases, Perl will warn you that you're doing something
65 wrong, with a friendly warning:
66 Wide character in print at example.pl line 2.
68 Because the internal format is often UTF-8, these bugs are hard to
70 spot, because UTF-8 is usually the encoding you wanted! But don't be
71 lazy, and don't use the fact that Perl's internal format is UTF-8 to
72 your advantage. Encode explicitly to avoid weird bugs, and to show to
73 maintenance programmers that you thought this through.
74 Is there a way to automatically decode or encode?
76 If all data that comes from a certain handle is encoded in exactly the
77 same way, you can tell the PerlIO system to automatically decode
78 everything, with the "encoding" layer. If you do this, you can't
79 accidentally forget to decode or encode anymore, on things that use the
80 layered handle.
81 You can provide this layer when "open"ing the file:
83 open my $fh, '>:encoding(UTF-8)', $filename; # auto encoding on write
85 open my $fh, '<:encoding(UTF-8)', $filename; # auto decoding on read
86 Or if you already have an open filehandle:
88 binmode $fh, ':encoding(UTF-8)';
90 Some database drivers for DBI can also automatically encode and decode,
92 but that is sometimes limited to the UTF-8 encoding.
93 What if I don't know which encoding was used?
95 Do whatever you can to find out, and if you have to: guess. (Don't
96 forget to document your guess with a comment.)
97 You could open the document in a web browser, and change the character
99 set or character encoding until you can visually confirm that all
100 characters look the way they should.
101 There is no way to reliably detect the encoding automatically, so if
103 people keep sending you data without charset indication, you may have
104 to educate them.
105 Can I use Unicode in my Perl sources?
107 Yes, you can! If your sources are UTF-8 encoded, you can indicate that
108 with the "use utf8" pragma.
109 use utf8;
111 This doesn't do anything to your input, or to your output. It only
113 influences the way your sources are read. You can use Unicode in string
114 literals, in identifiers (but they still have to be "word characters"
115 according to "\w"), and even in custom delimiters.
116 Data::Dumper doesn't restore the UTF8 flag; is it broken?
118 No, Data::Dumper's Unicode abilities are as they should be. There have
119 been some complaints that it should restore the UTF8 flag when the data
120 is read again with "eval". However, you should really not look at the
121 flag, and nothing indicates that Data::Dumper should break this rule.
122 Here's what happens: when Perl reads in a string literal, it sticks to
124 8 bit encoding as long as it can. (But perhaps originally it was
125 internally encoded as UTF-8, when you dumped it.) When it has to give
126 that up because other characters are added to the text string, it
127 silently upgrades the string to UTF-8.
128 If you properly encode your strings for output, none of this is of your
130 concern, and you can just "eval" dumped data as always.
131 Why do regex character classes sometimes match only in the ASCII range?
133 Starting in Perl 5.14 (and partially in Perl 5.12), just put a "use
134 feature 'unicode_strings'" near the beginning of your program. Within
135 its lexical scope you shouldn't have this problem. It also is
136 automatically enabled under "use feature ':5.12'" or "use v5.12" or
137 using "-E" on the command line for Perl 5.12 or higher.
138 The rationale for requiring this is to not break older programs that
140 rely on the way things worked before Unicode came along. Those older
141 programs knew only about the ASCII character set, and so may not work
142 properly for additional characters. When a string is encoded in UTF-8,
143 Perl assumes that the program is prepared to deal with Unicode, but
144 when the string isn't, Perl assumes that only ASCII is wanted, and so
145 those characters that are not ASCII characters aren't recognized as to
146 what they would be in Unicode. "use feature 'unicode_strings'" tells
147 Perl to treat all characters as Unicode, whether the string is encoded
148 in UTF-8 or not, thus avoiding the problem.
149 However, on earlier Perls, or if you pass strings to subroutines
151 outside the feature's scope, you can force Unicode rules by changing
152 the encoding to UTF-8 by doing "utf8::upgrade($string)". This can be
153 used safely on any string, as it checks and does not change strings
154 that have already been upgraded.
155 For a more detailed discussion, see Unicode::Semantics on CPAN.
157 Why do some characters not uppercase or lowercase correctly?
159 See the answer to the previous question.
160 How can I determine if a string is a text string or a binary string?
162 You can't. Some use the UTF8 flag for this, but that's misuse, and
163 makes well behaved modules like Data::Dumper look bad. The flag is
164 useless for this purpose, because it's off when an 8 bit encoding (by
165 default ISO-8859-1) is used to store the string.
166 This is something you, the programmer, has to keep track of; sorry. You
168 could consider adopting a kind of "Hungarian notation" to help with
169 this.
170 How do I convert from encoding FOO to encoding BAR?
172 By first converting the FOO-encoded byte string to a text string, and
173 then the text string to a BAR-encoded byte string:
174 my $text_string = decode('FOO', $foo_string);
176 my $bar_string = encode('BAR', $text_string);
177 or by skipping the text string part, and going directly from one binary
179 encoding to the other:
180 use Encode qw(from_to);
182 from_to($string, 'FOO', 'BAR'); # changes contents of $string
183 or by letting automatic decoding and encoding do all the work:
185 open my $foofh, '<:encoding(FOO)', 'example.foo.txt';
187 open my $barfh, '>:encoding(BAR)', 'example.bar.txt';
188 print { $barfh } $_ while <$foofh>;
189 What are "decode_utf8" and "encode_utf8"?
191 These are alternate syntaxes for "decode('utf8', ...)" and
192 "encode('utf8', ...)". Do not use these functions for data exchange.
193 Instead use "decode('UTF-8', ...)" and "encode('UTF-8', ...)"; see
194 "What's the difference between UTF-8 and utf8?" below.
195 What is a "wide character"?
197 This is a term used for characters occupying more than one byte.
198 The Perl warning "Wide character in ..." is caused by such a character.
200 With no specified encoding layer, Perl tries to fit things into a
201 single byte. When it can't, it emits this warning (if warnings are
202 enabled), and uses UTF-8 encoded data instead.
203 To avoid this warning and to avoid having different output encodings in
205 a single stream, always specify an encoding explicitly, for example
206 with a PerlIO layer:
207 binmode STDOUT, ":encoding(UTF-8)";
209
211 What is "the UTF8 flag"?
212 Please, unless you're hacking the internals, or debugging weirdness,
213 don't think about the UTF8 flag at all. That means that you very
214 probably shouldn't use "is_utf8", "_utf8_on" or "_utf8_off" at all.
215 The UTF8 flag, also called SvUTF8, is an internal flag that indicates
217 that the current internal representation is UTF-8. Without the flag, it
218 is assumed to be ISO-8859-1. Perl converts between these automatically.
219 (Actually Perl usually assumes the representation is ASCII; see "Why do
220 regex character classes sometimes match only in the ASCII range?"
221 above.)
222 One of Perl's internal formats happens to be UTF-8. Unfortunately, Perl
224 can't keep a secret, so everyone knows about this. That is the source
225 of much confusion. It's better to pretend that the internal format is
226 some unknown encoding, and that you always have to encode and decode
227 explicitly.
228 What about the "use bytes" pragma?
230 Don't use it. It makes no sense to deal with bytes in a text string,
231 and it makes no sense to deal with characters in a byte string. Do the
232 proper conversions (by decoding/encoding), and things will work out
233 well: you get character counts for decoded data, and byte counts for
234 encoded data.
235 "use bytes" is usually a failed attempt to do something useful. Just
237 forget about it.
238 What about the "use encoding" pragma?
240 Don't use it. Unfortunately, it assumes that the programmer's
241 environment and that of the user will use the same encoding. It will
242 use the same encoding for the source code and for STDIN and STDOUT.
243 When a program is copied to another machine, the source code does not
244 change, but the STDIO environment might.
245 If you need non-ASCII characters in your source code, make it a UTF-8
247 encoded file and "use utf8".
248 If you need to set the encoding for STDIN, STDOUT, and STDERR, for
250 example based on the user's locale, "use open".
251 What is the difference between ":encoding" and ":utf8"?
253 Because UTF-8 is one of Perl's internal formats, you can often just
254 skip the encoding or decoding step, and manipulate the UTF8 flag
255 directly.
256 Instead of ":encoding(UTF-8)", you can simply use ":utf8", which skips
258 the encoding step if the data was already represented as UTF8
259 internally. This is widely accepted as good behavior when you're
260 writing, but it can be dangerous when reading, because it causes
261 internal inconsistency when you have invalid byte sequences. Using
262 ":utf8" for input can sometimes result in security breaches, so please
263 use ":encoding(UTF-8)" instead.
264 Instead of "decode" and "encode", you could use "_utf8_on" and
266 "_utf8_off", but this is considered bad style. Especially "_utf8_on"
267 can be dangerous, for the same reason that ":utf8" can.
268 There are some shortcuts for oneliners; see -C in perlrun.
270 What's the difference between "UTF-8" and "utf8"?
272 "UTF-8" is the official standard. "utf8" is Perl's way of being liberal
273 in what it accepts. If you have to communicate with things that aren't
274 so liberal, you may want to consider using "UTF-8". If you have to
275 communicate with things that are too liberal, you may have to use
276 "utf8". The full explanation is in "UTF-8 vs. utf8 vs. UTF8" in Encode.
277 "UTF-8" is internally known as "utf-8-strict". The tutorial uses UTF-8
279 consistently, even where utf8 is actually used internally, because the
280 distinction can be hard to make, and is mostly irrelevant.
281 For example, utf8 can be used for code points that don't exist in
283 Unicode, like 9999999, but if you encode that to UTF-8, you get a
284 substitution character (by default; see "Handling Malformed Data" in
285 Encode for more ways of dealing with this.)
286 Okay, if you insist: the "internal format" is utf8, not UTF-8. (When
288 it's not some other encoding.)
289 I lost track; what encoding is the internal format really?
291 It's good that you lost track, because you shouldn't depend on the
292 internal format being any specific encoding. But since you asked: by
293 default, the internal format is either ISO-8859-1 (latin-1), or utf8,
294 depending on the history of the string. On EBCDIC platforms, this may
295 be different even.
296 Perl knows how it stored the string internally, and will use that
298 knowledge when you "encode". In other words: don't try to find out what
299 the internal encoding for a certain string is, but instead just encode
300 it into the encoding that you want.
301
303 Juerd Waalboer <#####@juerd.nl>
304
306 perlunicode, perluniintro, Encode
307perl v5.30.2 2020-03-27 PERLUNIFAQ(1)