1Mojolicious::Guides::ReUnsdeerriCnogn(t3r)ibuted Perl DoMcoujmoelnitcaitoiuosn::Guides::Rendering(3)
2
6 Mojolicious::Guides::Rendering - Rendering content
7
9 This document explains content generation with the Mojolicious
10 renderer.
11
13 Essentials every Mojolicious developer should know.
14 Renderer
16 The renderer is a tiny black box turning stash data into actual
17 responses utilizing multiple template systems and data encoding
18 modules.
19 {text => 'Hello.'} -> 200 OK, text/html, 'Hello.'
21 {json => {x => 3}} -> 200 OK, application/json, '{"x":3}'
22 {text => 'Oops.', status => '410'} -> 410 Gone, text/html, 'Oops.'
23 Templates can be automatically detected if enough information is
25 provided by the developer or routes. Template names are expected to
26 follow the "template.format.handler" scheme, with "template" defaulting
27 to "controller/action" or the route name, "format" defaulting to "html"
28 and "handler" to "ep".
29 {controller => 'users', action => 'list'} -> 'users/list.html.ep'
31 {template => 'foo', format => 'txt'} -> 'foo.txt.ep'
32 {template => 'foo', handler => 'epl'} -> 'foo.html.epl'
33 The "controller" value gets converted from "CamelCase" to "snake_case"
35 using "decamelize" in Mojo::Util and "-" characters replaced with "/".
36 {controller => 'My::Users', action => 'add'} -> 'my/users/add.html.ep'
38 {controller => 'my-users', action => 'show'} -> 'my/users/show.html.ep'
39 All templates should be in the "templates" directories of the
41 application, which can be customized with "paths" in
42 Mojolicious::Renderer, or one of the the "DATA" sections from "classes"
43 in Mojolicious::Renderer.
44 __DATA__
46 @@ time.html.ep
48 % use Time::Piece;
49 % my $now = localtime;
50 <!DOCTYPE html>
51 <html>
52 <head><title>Time</title></head>
53 <body>The time is <%= $now->hms %>.</body>
54 </html>
55 @@ hello.txt.ep
57 ...
58 The renderer can be easily extended to support additional template
60 systems with plugins, but more about that later.
61 Embedded Perl
63 Mojolicious includes a minimalistic but very powerful template system
64 out of the box called Embedded Perl or "ep" for short. It is based on
65 Mojo::Template and allows the embedding of Perl code right into actual
66 content using a small set of special tags and line start characters.
67 For all templates strict, warnings, utf8 and Perl 5.16 features are
68 automatically enabled.
69 <% Perl code %>
71 <%= Perl expression, replaced with XML escaped result %>
72 <%== Perl expression, replaced with result %>
73 <%# Comment, useful for debugging %>
74 <%% Replaced with "<%", useful for generating templates %>
75 % Perl code line, treated as "<% line =%>" (explained later)
76 %= Perl expression line, treated as "<%= line %>"
77 %== Perl expression line, treated as "<%== line %>"
78 %# Comment line, useful for debugging
79 %% Replaced with "%", useful for generating templates
80 Tags and lines work pretty much the same, but depending on context one
82 will usually look a bit better. Semicolons get automatically appended
83 to all expressions.
84 <% my $i = 10; %>
86 <ul>
87 <% for my $j (1 .. $i) { %>
88 <li>
89 <%= $j %>
90 </li>
91 <% } %>
92 </ul>
93 % my $i = 10;
95 <ul>
96 % for my $j (1 .. $i) {
97 <li>
98 %= $j
99 </li>
100 % }
101 </ul>
102 Aside from differences in whitespace handling, both examples generate
104 similar Perl code, a naive translation could look like this.
105 my $output = '';
107 my $i = 10;
108 $output .= '<ul>';
109 for my $j (1 .. $i) {
110 $output .= '<li>';
111 $output .= xml_escape scalar + $j;
112 $output .= '</li>';
113 }
114 $output .= '</ul>';
115 return $output;
116 An additional equal sign can be used to disable escaping of the
118 characters "<", ">", "&", "'" and """ in results from Perl expressions,
119 which is the default to prevent XSS attacks against your application.
120 <%= 'I ♥ Mojolicious!' %>
122 <%== '<p>I ♥ Mojolicious!</p>' %>
123 Only Mojo::ByteStream objects are excluded from automatic escaping.
125 <%= b('<p>I ♥ Mojolicious!</p>') %>
127 Whitespace characters around tags can be trimmed by adding an
129 additional equal sign to the end of a tag.
130 <% for (1 .. 3) { %>
132 <%= 'Trim all whitespace characters around this expression' =%>
133 <% } %>
134 Newline characters can be escaped with a backslash.
136 This is <%= 1 + 1 %> a\
138 single line
139 And a backslash in front of a newline character can be escaped with
141 another backslash.
142 This will <%= 1 + 1 %> result\\
144 in multiple\\
145 lines
146 A newline character gets appended automatically to every template,
148 unless the last character is a backslash. And empty lines at the end of
149 a template are ignored.
150 There is <%= 1 + 1 %> no newline at the end here\
152 At the beginning of the template, stash values that don't have invalid
154 characters in their name get automatically initialized as normal
155 variables, and the controller object as both $self and $c.
156 $c->stash(name => 'tester');
158 Hello <%= $name %> from <%= $c->tx->remote_address %>.
160 A prefix like "myapp.*" is commonly used for stash values that you
162 don't want to expose in templates.
163 $c->stash('myapp.name' => 'tester');
165 There are also many helper functions available, but more about that
167 later.
168 <%= dumper {foo => 'bar'} %>
170
172 Most commonly used features every Mojolicious developer should know
173 about.
174 Automatic rendering
176 The renderer can be manually started by calling the method "render" in
177 Mojolicious::Controller, but that's usually not necessary, because it
178 will get automatically called if nothing has been rendered after the
179 router finished its work. This also means you can have routes pointing
180 only to templates without actual actions.
181 $c->render;
183 There is one big difference though, by calling it manually you can make
185 sure that templates use the current controller object, and not the
186 default controller specified with the attribute "controller_class" in
187 Mojolicious.
188 $c->render_later;
190 You can also disable automatic rendering with the method "render_later"
192 in Mojolicious::Controller, which can be very useful to delay rendering
193 when a non-blocking operation has to be performed first.
194 Rendering templates
196 The renderer will always try to detect the right template, but you can
197 also use the "template" stash value to render a specific one.
198 Everything before the last slash will be interpreted as the
199 subdirectory path in which to find the template.
200 # foo/bar/baz.*.*
202 $c->render(template => 'foo/bar/baz');
203 Choosing a specific "format" and "handler" is just as easy.
205 # foo/bar/baz.txt.epl
207 $c->render(template => 'foo/bar/baz', format => 'txt', handler => 'epl');
208 Because rendering a specific template is the most common task it also
210 has a shortcut.
211 $c->render('foo/bar/baz');
213 If you're not sure in advance if a template actually exists, you can
215 also use the method "render_maybe" in Mojolicious::Controller to try
216 multiple alternatives.
217 $c->render_maybe('localized/baz') or $c->render('foo/bar/baz');
219 Rendering to strings
221 Sometimes you might want to use the rendered result directly instead of
222 generating a response, for example, to send emails, this can be done
223 with "render_to_string" in Mojolicious::Controller.
224 my $html = $c->render_to_string('mail');
226 No encoding will be performed, making it easy to reuse the result in
228 other templates or to generate binary data.
229 my $pdf = $c->render_to_string('invoice', format => 'pdf');
231 $c->render(data => $pdf, format => 'pdf');
232 All arguments passed will get localized automatically and are only
234 available during this render operation.
235 Template variants
237 To make your application look great on many different devices you can
238 also use the "variant" stash value to choose between different variants
239 of your templates.
240 # foo/bar/baz.html+phone.ep
242 # foo/bar/baz.html.ep
243 $c->render('foo/bar/baz', variant => 'phone');
244 This can be done very liberally since it only applies when a template
246 with the correct name actually exists and falls back to the generic one
247 otherwise.
248 Rendering inline templates
250 Some renderers such as "ep" allow templates to be passed "inline".
251 $c->render(inline => 'The result is <%= 1 + 1 %>.');
253 Since auto-detection depends on a path you might have to supply a
255 "handler" too.
256 $c->render(inline => "<%= shift->param('foo') %>", handler => 'epl');
258 Rendering text
260 Characters can be rendered to bytes with the "text" stash value, the
261 given content will be automatically encoded with "encoding" in
262 Mojolicious::Renderer.
263 $c->render(text => 'I ♥ Mojolicious!');
265 Rendering data
267 Bytes can be rendered with the "data" stash value, no encoding will be
268 performed.
269 $c->render(data => $bytes);
271 Rendering JSON
273 The "json" stash value allows you to pass Perl data structures to the
274 renderer which get directly encoded to JSON with Mojo::JSON.
275 $c->render(json => {foo => [1, 'test', 3]});
277 Status code
279 Response status codes can be changed with the "status" stash value.
280 $c->render(text => 'Oops.', status => 500);
282 Content type
284 The "Content-Type" header of the response is actually based on the MIME
285 type mapping of the "format" stash value.
286 # Content-Type: text/plain
288 $c->render(text => 'Hello.', format => 'txt');
289 # Content-Type: image/png
291 $c->render(data => $bytes, format => 'png');
292 These mappings can be easily extended or changed with "types" in
294 Mojolicious.
295 # Add new MIME type
297 $app->types->type(md => 'text/markdown');
298 Stash data
300 Any of the native Perl data types can be passed to templates as
301 references through the "stash" in Mojolicious::Controller.
302 $c->stash(description => 'web framework');
304 $c->stash(frameworks => ['Catalyst', 'Mojolicious']);
305 $c->stash(spinoffs => {minion => 'job queue'});
306 %= $description
308 %= $frameworks->[1]
309 %= $spinoffs->{minion}
310 Since everything is just Perl normal control structures just work.
312 % for my $framework (@$frameworks) {
314 <%= $framework %> is a <%= $description %>.
315 % }
316 % if (my $description = $spinoffs->{minion}) {
318 Minion is a <%= $description %>.
319 % }
320 For templates that might get rendered in different ways and where
322 you're not sure if a stash value will actually be set, you can just use
323 the helper "stash" in Mojolicious::Plugin::DefaultHelpers.
324 % if (my $spinoffs = stash 'spinoffs') {
326 Minion is a <%= $spinoffs->{minion} %>.
327 % }
328 Helpers
330 Helpers are little functions you can use in templates as well as
331 application and controller code.
332 # Template
334 %= dumper [1, 2, 3]
335 # Application
337 my $serialized = $app->dumper([1, 2, 3]);
338 # Controller
340 my $serialized = $c->dumper([1, 2, 3]);
341 We differentiate between default helpers, which are more general
343 purpose like "dumper" in Mojolicious::Plugin::DefaultHelpers, and tag
344 helpers like "link_to" in Mojolicious::Plugin::TagHelpers, which are
345 template specific and mostly used to generate HTML tags.
346 %= link_to Mojolicious => 'https://mojolicious.org'
348 In controllers you can also use the method "helpers" in
350 Mojolicious::Controller to fully qualify helper calls and ensure that
351 they don't conflict with existing methods you may already have.
352 my $serialized = $c->helpers->dumper([1, 2, 3]);
354 A list of all built-in helpers can be found in
356 Mojolicious::Plugin::DefaultHelpers and
357 Mojolicious::Plugin::TagHelpers.
358 Content negotiation
360 For resources with different representations and that require truly
361 RESTful content negotiation you can also use "respond_to" in
362 Mojolicious::Plugin::DefaultHelpers instead of "render" in
363 Mojolicious::Controller.
364 # /hello (Accept: application/json) -> "json"
366 # /hello (Accept: application/xml) -> "xml"
367 # /hello.json -> "json"
368 # /hello.xml -> "xml"
369 # /hello?format=json -> "json"
370 # /hello?format=xml -> "xml"
371 $c->respond_to(
372 json => {json => {hello => 'world'}},
373 xml => {text => '<hello>world</hello>'}
374 );
375 The best possible representation will be automatically selected from
377 the "format" "GET"/"POST" parameter, "format" stash value or "Accept"
378 request header and stored in the "format" stash value. To change MIME
379 type mappings for the "Accept" request header or the "Content-Type"
380 response header you can use "types" in Mojolicious.
381 $c->respond_to(
383 json => {json => {hello => 'world'}},
384 html => sub {
385 $c->content_for(head => '<meta name="author" content="sri">');
386 $c->render(template => 'hello', message => 'world')
387 }
388 );
389 Callbacks can be used for representations that are too complex to fit
391 into a single render call.
392 # /hello (Accept: application/json) -> "json"
394 # /hello (Accept: text/html) -> "html"
395 # /hello (Accept: image/png) -> "any"
396 # /hello.json -> "json"
397 # /hello.html -> "html"
398 # /hello.png -> "any"
399 # /hello?format=json -> "json"
400 # /hello?format=html -> "html"
401 # /hello?format=png -> "any"
402 $c->respond_to(
403 json => {json => {hello => 'world'}},
404 html => {template => 'hello', message => 'world'},
405 any => {text => '', status => 204}
406 );
407 And if no viable representation could be found, the "any" fallback will
409 be used or an empty 204 response rendered automatically.
410 # /hello -> "html"
412 # /hello (Accept: text/html) -> "html"
413 # /hello (Accept: text/xml) -> "xml"
414 # /hello (Accept: text/plain) -> undef
415 # /hello.html -> "html"
416 # /hello.xml -> "xml"
417 # /hello.txt -> undef
418 # /hello?format=html -> "html"
419 # /hello?format=xml -> "xml"
420 # /hello?format=txt -> undef
421 if (my $format = $c->accepts('html', 'xml')) {
422 ...
423 }
424 For even more advanced negotiation logic you can also use the helper
426 "accepts" in Mojolicious::Plugin::DefaultHelpers.
427 Rendering "exception" and "not_found" pages
429 By now you've probably already encountered the built-in 404 (Not Found)
430 and 500 (Server Error) pages, that get rendered automatically when you
431 make a mistake. Those are fallbacks for when your own exception
432 handling fails, which can be especially helpful during development. You
433 can also render them manually with the helpers "reply->exception" in
434 Mojolicious::Plugin::DefaultHelpers and "reply->not_found" in
435 Mojolicious::Plugin::DefaultHelpers.
436 use Mojolicious::Lite;
438 use Scalar::Util qw(looks_like_number);
439 get '/divide/:dividend/by/:divisor' => sub {
441 my $c = shift;
442 my $dividend = $c->param('dividend');
444 my $divisor = $c->param('divisor');
445 # 404
447 return $c->reply->not_found
448 unless looks_like_number $dividend && looks_like_number $divisor;
449 # 500
451 return $c->reply->exception('Division by zero!') if $divisor == 0;
452 # 200
454 $c->render(text => $dividend / $divisor);
455 };
456 app->start;
458 You can also change the templates of those pages, since you most likely
460 want to show your users something more closely related to your
461 application in production. The renderer will always try to find
462 "exception.$mode.$format.*" or "not_found.$mode.$format.*" before
463 falling back to the built-in default templates.
464 use Mojolicious::Lite;
466 get '/dies' => sub { die 'Intentional error' };
468 app->start;
470 __DATA__
471 @@ exception.production.html.ep
473 <!DOCTYPE html>
474 <html>
475 <head><title>Server error</title></head>
476 <body>
477 <h1>Exception</h1>
478 <p><%= $exception->message %></p>
479 <h1>Stash</h1>
480 <pre><%= dumper $snapshot %></pre>
481 </body>
482 </html>
483 The hook "before_render" in Mojolicious makes even more advanced
485 customizations possible by allowing you to intercept and modify the
486 arguments passed to the renderer.
487 use Mojolicious::Lite;
489 hook before_render => sub {
491 my ($c, $args) = @_;
492 # Make sure we are rendering the exception template
494 return unless my $template = $args->{template};
495 return unless $template eq 'exception';
496 # Switch to JSON rendering if content negotiation allows it
498 return unless $c->accepts('json');
499 $args->{json} = {exception => $c->stash('exception')};
500 };
501 get '/' => sub { die "This sho...ALL GLORY TO THE HYPNOTOAD!\n" };
503 app->start;
505 Layouts
507 Most of the time when using "ep" templates you will want to wrap your
508 generated content in an HTML skeleton, thanks to layouts that's
509 absolutely trivial.
510 use Mojolicious::Lite;
512 get '/' => {template => 'foo/bar'};
514 app->start;
516 __DATA__
517 @@ foo/bar.html.ep
519 % layout 'mylayout';
520 Hello World!
521 @@ layouts/mylayout.html.ep
523 <!DOCTYPE html>
524 <html>
525 <head><title>MyApp</title></head>
526 <body><%= content %></body>
527 </html>
528 You just select the right layout template with the helper "layout" in
530 Mojolicious::Plugin::DefaultHelpers and place the result of the current
531 template with the helper "content" in
532 Mojolicious::Plugin::DefaultHelpers. You can also pass along normal
533 stash values to the "layout" helper.
534 use Mojolicious::Lite;
536 get '/' => {template => 'foo/bar'};
538 app->start;
540 __DATA__
541 @@ foo/bar.html.ep
543 % layout 'mylayout', title => 'Hi there';
544 Hello World!
545 @@ layouts/mylayout.html.ep
547 <!DOCTYPE html>
548 <html>
549 <head><title><%= $title %></title></head>
550 <body><%= content %></body>
551 </html>
552 Instead of the "layout" helper you could also just use the "layout"
554 stash value, or call "render" in Mojolicious::Controller with the
555 "layout" argument.
556 $c->render(template => 'mytemplate', layout => 'mylayout');
558 To set a "layout" stash value application-wide you can use "defaults"
560 in Mojolicious.
561 $app->defaults(layout => 'mylayout');
563 Layouts can also be used with "render_to_string" in
565 Mojolicious::Controller, but the "layout" value needs to be passed as a
566 render argument (not a stash value).
567 my $html = $c->render_to_string('reminder', layout => 'mail');
569 Partial templates
571 You can break up bigger templates into smaller, more manageable chunks.
572 These partial templates can also be shared with other templates. Just
573 use the helper "include" in Mojolicious::Plugin::DefaultHelpers to
574 include one template into another.
575 use Mojolicious::Lite;
577 get '/' => {template => 'foo/bar'};
579 app->start;
581 __DATA__
582 @@ foo/bar.html.ep
584 <!DOCTYPE html>
585 <html>
586 %= include '_header', title => 'Howdy'
587 <body>Bar</body>
588 </html>
589 @@ _header.html.ep
591 <head><title><%= $title %></title></head>
592 You can name partial templates however you like, but a leading
594 underscore is a commonly used naming convention.
595 Reusable template blocks
597 It's never fun to repeat yourself, that's why you can build reusable
598 template blocks in "ep" that work very similar to normal Perl
599 functions, with the "begin" and "end" keywords. Just be aware that both
600 keywords are part of the surrounding tag and not actual Perl code, so
601 there can only be whitespace after "begin" and before "end".
602 use Mojolicious::Lite;
604 get '/' => 'welcome';
606 app->start;
608 __DATA__
609 @@ welcome.html.ep
611 <% my $block = begin %>
612 % my $name = shift;
613 Hello <%= $name %>.
614 <% end %>
615 <%= $block->('Wolfgang') %>
616 <%= $block->('Baerbel') %>
617 A naive translation of the template to Perl code could look like this.
619 my $output = '';
621 my $block = sub {
622 my $name = shift;
623 my $output = '';
624 $output .= 'Hello ';
625 $output .= xml_escape scalar + $name;
626 $output .= '.';
627 return Mojo::ByteStream->new($output);
628 };
629 $output .= xml_escape scalar + $block->('Wolfgang');
630 $output .= xml_escape scalar + $block->('Baerbel');
631 return $output;
632 While template blocks cannot be shared between templates, they are most
634 commonly used to pass parts of a template to helpers.
635 Adding helpers
637 You should always try to keep your actions small and reuse as much code
638 as possible. Helpers make this very easy, they get passed the current
639 controller object as first argument, and you can use them to do pretty
640 much anything an action could do.
641 use Mojolicious::Lite;
643 helper debug => sub {
645 my ($c, $str) = @_;
646 $c->app->log->debug($str);
647 };
648 get '/' => sub {
650 my $c = shift;
651 $c->debug('Hello from an action!');
652 } => 'index';
653 app->start;
655 __DATA__
656 @@ index.html.ep
658 % debug 'Hello from a template!';
659 Helpers can also accept template blocks as last argument, this for
661 example, allows very pleasant to use tag helpers and filters. Wrapping
662 the helper result into a Mojo::ByteStream object can prevent accidental
663 double escaping.
664 use Mojolicious::Lite;
666 use Mojo::ByteStream;
667 helper trim_newline => sub {
669 my ($c, $block) = @_;
670 my $result = $block->();
671 $result =~ s/\n//g;
672 return Mojo::ByteStream->new($result);
673 };
674 get '/' => 'index';
676 app->start;
678 __DATA__
679 @@ index.html.ep
681 %= trim_newline begin
682 Some text.
683 %= 1 + 1
684 More text.
685 % end
686 Similar to stash values, you can use a prefix like "myapp.*" to keep
688 helpers from getting exposed in templates as functions, and to organize
689 them into namespaces as your application grows. Every prefix
690 automatically becomes a helper that returns a proxy object containing
691 the current controller object and on which you can call the nested
692 helpers.
693 use Mojolicious::Lite;
695 helper 'cache_control.no_caching' => sub {
697 my $c = shift;
698 $c->res->headers->cache_control('private, max-age=0, no-cache');
699 };
700 helper 'cache_control.five_minutes' => sub {
702 my $c = shift;
703 $c->res->headers->cache_control('public, max-age=300');
704 };
705 get '/news' => sub {
707 my $c = shift;
708 $c->cache_control->no_caching;
709 $c->render(text => 'Always up to date.');
710 };
711 get '/some_older_story' => sub {
713 my $c = shift;
714 $c->cache_control->five_minutes;
715 $c->render(text => 'This one can be cached for a bit.');
716 };
717 app->start;
719 While helpers can also be redefined, this should only be done very
721 carefully to avoid conflicts.
722 Content blocks
724 The helper "content_for" in Mojolicious::Plugin::DefaultHelpers allows
725 you to pass whole blocks of content from one template to another. This
726 can be very useful when your layout has distinct sections, such as
727 sidebars, where content should be inserted by the template.
728 use Mojolicious::Lite;
730 get '/' => 'foo';
732 app->start;
734 __DATA__
735 @@ foo.html.ep
737 % layout 'mylayout';
738 % content_for header => begin
739 <meta http-equiv="Content-Type" content="text/html">
740 % end
741 <div>Hello World!</div>
742 % content_for header => begin
743 <meta http-equiv="Pragma" content="no-cache">
744 % end
745 @@ layouts/mylayout.html.ep
747 <!DOCTYPE html>
748 <html>
749 <head><%= content 'header' %></head>
750 <body><%= content %></body>
751 </html>
752 Forms
754 To build HTML forms more efficiently you can use tag helpers like
755 "form_for" in Mojolicious::Plugin::TagHelpers, which can automatically
756 select a request method for you if a route name is provided. And since
757 most browsers only allow forms to be submitted with "GET" and "POST",
758 but not request methods like "PUT" or "DELETE", they are spoofed with
759 an "_method" query parameter.
760 use Mojolicious::Lite;
762 get '/' => 'form';
764 # PUT /nothing
766 # POST /nothing?_method=PUT
767 put '/nothing' => sub {
768 my $c = shift;
769 # Prevent double form submission with redirect
771 my $value = $c->param('whatever');
772 $c->flash(confirmation => "We did nothing with your value ($value).");
773 $c->redirect_to('form');
774 };
775 app->start;
777 __DATA__
778 @@ form.html.ep
780 <!DOCTYPE html>
781 <html>
782 <body>
783 % if (my $confirmation = flash 'confirmation') {
784 <p><%= $confirmation %></p>
785 % }
786 %= form_for nothing => begin
787 %= text_field whatever => 'I ♥ Mojolicious!'
788 %= submit_button
789 % end
790 </body>
791 </html>
792 The helpers "flash" in Mojolicious::Plugin::DefaultHelpers and
794 "redirect_to" in Mojolicious::Plugin::DefaultHelpers are often used
795 together to prevent double form submission, allowing users to receive a
796 confirmation message that will vanish if they decide to reload the page
797 they've been redirected to.
798 Form validation
800 You can use "validation" in Mojolicious::Plugin::DefaultHelpers to
801 validate "GET" and "POST" parameters submitted to your application. All
802 unknown fields will be ignored by default, so you have to decide which
803 should be required or optional before you can perform checks on their
804 values. Every check is performed right away, so you can use the results
805 immediately to build more advanced validation logic with methods like
806 "is_valid" in Mojolicious::Validator::Validation.
807 use Mojolicious::Lite;
809 get '/' => sub {
811 my $c = shift;
812 # Check if parameters have been submitted
814 my $v = $c->validation;
815 return $c->render('index') unless $v->has_data;
816 # Validate parameters ("pass_again" depends on "pass")
818 $v->required('user')->size(1, 20)->like(qr/^[a-z0-9]+$/);
819 $v->required('pass_again')->equal_to('pass')
820 if $v->optional('pass')->size(7, 500)->is_valid;
821 # Check if validation failed
823 return $c->render('index') if $v->has_error;
824 # Render confirmation
826 $c->render('thanks');
827 };
828 app->start;
830 __DATA__
831 @@ index.html.ep
833 <!DOCTYPE html>
834 <html>
835 <head>
836 <style>
837 label.field-with-error { color: #dd7e5e }
838 input.field-with-error { background-color: #fd9e7e }
839 </style>
840 </head>
841 <body>
842 %= form_for index => begin
843 %= label_for user => 'Username (required, 1-20 characters, a-z/0-9)'
844 <br>
845 %= text_field 'user', id => 'user'
846 %= submit_button
847 <br>
848 %= label_for pass => 'Password (optional, 7-500 characters)'
849 <br>
850 %= password_field 'pass', id => 'pass'
851 <br>
852 %= label_for pass_again => 'Password again (equal to the value above)'
853 <br>
854 %= password_field 'pass_again', id => 'pass_again'
855 % end
856 </body>
857 </html>
858 @@ thanks.html.ep
860 <!DOCTYPE html>
861 <html><body>Thank you <%= validation->param('user') %>.</body></html>
862 Form elements generated with tag helpers from
864 Mojolicious::Plugin::TagHelpers will automatically remember their
865 previous values and add the class "field-with-error" for fields that
866 failed validation to make styling with CSS easier.
867 <label class="field-with-error" for="user">
869 Username (required, only characters e-t)
870 </label>
871 <input class="field-with-error" type="text" name="user" value="sri">
872 For a full list of available checks see also "CHECKS" in
874 Mojolicious::Validator.
875 Adding form validation checks
877 Validation checks can be registered with "add_check" in
878 Mojolicious::Validator and return a false value if they were
879 successful. A true value may be used to pass along additional
880 information which can then be retrieved with "error" in
881 Mojolicious::Validator::Validation.
882 use Mojolicious::Lite;
884 # Add "range" check
886 app->validator->add_check(range => sub {
887 my ($v, $name, $value, $min, $max) = @_;
888 return $value < $min || $value > $max;
889 });
890 get '/' => 'form';
892 post '/test' => sub {
894 my $c = shift;
895 # Validate parameters with custom check
897 my $v = $c->validation;
898 $v->required('number')->range(3, 23);
899 # Render form again if validation failed
901 return $c->render('form') if $v->has_error;
902 # Prevent double form submission with redirect
904 $c->flash(number => $v->param('number'));
905 $c->redirect_to('form');
906 };
907 app->start;
909 __DATA__
910 @@ form.html.ep
912 <!DOCTYPE html>
913 <html>
914 <body>
915 % if (my $number = flash 'number') {
916 <p>Thanks, the number <%= $number %> was valid.</p>
917 % }
918 %= form_for test => begin
919 % if (my $err = validation->error('number')) {
920 <p>
921 %= 'Value is required.' if $err->[0] eq 'required'
922 %= 'Value needs to be between 3 and 23.' if $err->[0] eq 'range'
923 </p>
924 % }
925 %= text_field 'number'
926 %= submit_button
927 % end
928 </body>
929 </html>
930 Cross-site request forgery
932 CSRF is a very common attack on web applications that trick your logged
933 in users to submit forms they did not intend to send, with something as
934 mundane as a link. All you have to do, to protect your users from this,
935 is to add an additional hidden field to your forms with "csrf_field" in
936 Mojolicious::Plugin::TagHelpers, and validate it with "csrf_protect" in
937 Mojolicious::Validator::Validation.
938 use Mojolicious::Lite;
940 get '/' => {template => 'target'};
942 post '/' => sub {
944 my $c = shift;
945 # Check CSRF token
947 my $v = $c->validation;
948 return $c->render(text => 'Bad CSRF token!', status => 403)
949 if $v->csrf_protect->has_error('csrf_token');
950 my $city = $v->required('city')->param('city');
952 $c->render(text => "Low orbit ion cannon pointed at $city!")
953 unless $v->has_error;
954 } => 'target';
955 app->start;
957 __DATA__
958 @@ target.html.ep
960 <!DOCTYPE html>
961 <html>
962 <body>
963 %= form_for target => begin
964 %= csrf_field
965 %= label_for city => 'Which city to point low orbit ion cannon at?'
966 %= text_field 'city', id => 'city'
967 %= submit_button
968 %= end
969 </body>
970 </html>
971 For Ajax requests and the like, you can also generate a token directly
973 with the helper "csrf_token" in Mojolicious::Plugin::DefaultHelpers,
974 and then pass it along with the "X-CSRF-Token" request header.
975
977 Less commonly used and more powerful features.
978 Template inheritance
980 Inheritance takes the layout concept above one step further, the
981 helpers "content" in Mojolicious::Plugin::DefaultHelpers and "extends"
982 in Mojolicious::Plugin::DefaultHelpers allow you to build skeleton
983 templates with named blocks that child templates can override.
984 use Mojolicious::Lite;
986 # first > mylayout
988 get '/first' => {template => 'first', layout => 'mylayout'};
989 # third > second > first > mylayout
991 get '/third' => {template => 'third', layout => 'mylayout'};
992 app->start;
994 __DATA__
995 @@ layouts/mylayout.html.ep
997 <!DOCTYPE html>
998 <html>
999 <head><title>Hello</title></head>
1000 <body><%= content %></body>
1001 </html>
1002 @@ first.html.ep
1004 %= content header => begin
1005 Default header
1006 % end
1007 <div>Hello World!</div>
1008 %= content footer => begin
1009 Default footer
1010 % end
1011 @@ second.html.ep
1013 % extends 'first';
1014 % content header => begin
1015 New header
1016 % end
1017 @@ third.html.ep
1019 % extends 'second';
1020 % content footer => begin
1021 New footer
1022 % end
1023 This chain could go on and on to allow a very high level of template
1025 reuse.
1026 Serving static files
1028 Static files are automatically served from the "public" directories of
1029 the application, which can be customized with "paths" in
1030 Mojolicious::Static, or one of the "DATA" sections from "classes" in
1031 Mojolicious::Static. And if that's not enough you can also serve them
1032 manually with "reply->static" in Mojolicious::Plugin::DefaultHelpers
1033 and "reply->file" in Mojolicious::Plugin::DefaultHelpers.
1034 use Mojolicious::Lite;
1036 get '/' => sub {
1038 my $c = shift;
1039 $c->reply->static('index.html');
1040 };
1041 get '/some_download' => sub {
1043 my $c = shift;
1044 $c->res->headers->content_disposition('attachment; filename=bar.png;');
1045 $c->reply->static('foo/bar.png');
1046 };
1047 get '/leak' => sub {
1049 my $c = shift;
1050 $c->reply->file('/etc/passwd');
1051 };
1052 app->start;
1054 Custom responses
1056 Most response content, static as well as dynamic, gets served through
1057 Mojo::Asset::File and Mojo::Asset::Memory objects. For somewhat static
1058 content, like cached JSON data or temporary files, you can create your
1059 own and use the helper "reply->asset" in
1060 Mojolicious::Plugin::DefaultHelpers to serve them while allowing
1061 content negotiation to be performed with "Range", "If-Modified-Since"
1062 and "If-None-Match" headers.
1063 use Mojolicious::Lite;
1065 use Mojo::Asset::File;
1066 get '/leak' => sub {
1068 my $c = shift;
1069 $c->res->headers->content_type('text/plain');
1070 $c->reply->asset(Mojo::Asset::File->new(path => '/etc/passwd'));
1071 };
1072 app->start;
1074 For even more control you can also just skip the helper and use
1076 "rendered" in Mojolicious::Controller to tell the renderer when you're
1077 done generating a response.
1078 use Mojolicious::Lite;
1080 use Mojo::Asset::File;
1081 get '/leak' => sub {
1083 my $c = shift;
1084 $c->res->headers->content_type('text/plain');
1085 $c->res->content->asset(Mojo::Asset::File->new(path => '/etc/passwd'));
1086 $c->rendered(200);
1087 };
1088 app->start;
1090 Helper plugins
1092 Some helpers might be useful enough for you to share them between
1093 multiple applications, plugins make that very simple.
1094 package Mojolicious::Plugin::DebugHelper;
1096 use Mojo::Base 'Mojolicious::Plugin';
1097 sub register {
1099 my ($self, $app) = @_;
1100 $app->helper(debug => sub {
1101 my ($c, $str) = @_;
1102 $c->app->log->debug($str);
1103 });
1104 }
1105 1;
1107 The "register" method will be called when you load the plugin. And to
1109 add your helper to the application, you can use "helper" in
1110 Mojolicious.
1111 use Mojolicious::Lite;
1113 plugin 'DebugHelper';
1115 get '/' => sub {
1117 my $c = shift;
1118 $c->debug('It works!');
1119 $c->render(text => 'Hello!');
1120 };
1121 app->start;
1123 A skeleton for a full CPAN compatible plugin distribution can be
1125 automatically generated.
1126 $ mojo generate plugin DebugHelper
1128 And if you have a "PAUSE" account (which can be requested at
1130 <http://pause.perl.org>), you are only a few commands away from
1131 releasing it to CPAN.
1132 $ perl Makefile.PL
1134 $ make test
1135 $ make manifest
1136 $ make dist
1137 $ mojo cpanify -u USER -p PASS Mojolicious-Plugin-DebugHelper-0.01.tar.gz
1138 Bundling assets with plugins
1140 Assets such as templates and static files can be easily bundled with
1141 your plugins, even if you plan to release them to CPAN.
1142 $ mojo generate plugin AlertAssets
1144 $ mkdir Mojolicious-Plugin-AlertAssets/lib/Mojolicious/Plugin/AlertAssets
1145 $ cd Mojolicious-Plugin-AlertAssets/lib/Mojolicious/Plugin/AlertAssets
1146 $ mkdir public
1147 $ echo 'alert("Hello World!");' > public/alertassets.js
1148 $ mkdir templates
1149 $ echo '%= javascript "/alertassets.js"' > templates/alertassets.html.ep
1150 Just give them reasonably unique names, ideally based on the name of
1152 your plugin, and append their respective directories to the list of
1153 search paths when "register" is called.
1154 package Mojolicious::Plugin::AlertAssets;
1156 use Mojo::Base 'Mojolicious::Plugin';
1157 use Mojo::File qw(curfile);
1159 sub register {
1161 my ($self, $app) = @_;
1162 # Append "templates" and "public" directories
1164 my $base = curfile->sibling('AlertAssets');
1165 push @{$app->renderer->paths}, $base->child('templates')->to_string;
1166 push @{$app->static->paths}, $base->child('public')->to_string;
1167 }
1168 1;
1170 Both will work just like normal "templates" and "public" directories
1172 once you've installed and loaded the plugin, with slightly lower
1173 precedence.
1174 use Mojolicious::Lite;
1176 plugin 'AlertAssets';
1178 get '/alert_me';
1180 app->start;
1182 __DATA__
1183 @@ alert_me.html.ep
1185 <!DOCTYPE html>
1186 <html>
1187 <head>
1188 <title>Alert me!</title>
1189 %= include 'alertassets'
1190 </head>
1191 <body>You've been alerted.</body>
1192 </html>
1193 And it works just the same for assets bundled in the "DATA" section of
1195 your plugin.
1196 package Mojolicious::Plugin::AlertAssets;
1198 use Mojo::Base 'Mojolicious::Plugin';
1199 sub register {
1201 my ($self, $app) = @_;
1202 # Append class
1204 push @{$app->renderer->classes}, __PACKAGE__;
1205 push @{$app->static->classes}, __PACKAGE__;
1206 }
1207 1;
1209 __DATA__
1210 @@ alertassets.js
1212 alert("Hello World!");
1213 @@ alertassets.html.ep
1215 %= javascript "/alertassets.js"
1216 Post-processing dynamic content
1218 While post-processing tasks are generally very easy with the hook
1219 "after_dispatch" in Mojolicious, for content generated by the renderer
1220 it is a lot more efficient to use "after_render" in Mojolicious.
1221 use Mojolicious::Lite;
1223 use IO::Compress::Gzip qw(gzip);
1224 hook after_render => sub {
1226 my ($c, $output, $format) = @_;
1227 # Check if "gzip => 1" has been set in the stash
1229 return unless $c->stash->{gzip};
1230 # Check if user agent accepts gzip compression
1232 return unless ($c->req->headers->accept_encoding // '') =~ /gzip/i;
1233 $c->res->headers->append(Vary => 'Accept-Encoding');
1234 # Compress content with gzip
1236 $c->res->headers->content_encoding('gzip');
1237 gzip $output, \my $compressed;
1238 $$output = $compressed;
1239 };
1240 get '/' => {template => 'hello', title => 'Hello', gzip => 1};
1242 app->start;
1244 __DATA__
1245 @@ hello.html.ep
1247 <!DOCTYPE html>
1248 <html>
1249 <head><title><%= title %></title></head>
1250 <body>Compressed content.</body>
1251 </html>
1252 If you want to compress all dynamically generated content you can also
1254 activate "compress" in Mojolicious::Renderer.
1255 Streaming
1257 You don't have to render all content at once, the method "write" in
1258 Mojolicious::Controller can also be used to stream a series of smaller
1259 chunks.
1260 use Mojolicious::Lite;
1262 get '/' => sub {
1264 my $c = shift;
1265 # Prepare body
1267 my $body = 'Hello World!';
1268 $c->res->headers->content_length(length $body);
1269 # Start writing directly with a drain callback
1271 my $drain = sub {
1272 my $c = shift;
1273 my $chunk = substr $body, 0, 1, '';
1274 $c->write($chunk, length $body ? __SUB__ : undef);
1275 };
1276 $c->$drain;
1277 };
1278 app->start;
1280 The drain callback will be executed whenever the entire previous chunk
1282 of data has actually been written.
1283 HTTP/1.1 200 OK
1285 Date: Sat, 13 Sep 2014 16:48:29 GMT
1286 Content-Length: 12
1287 Server: Mojolicious (Perl)
1288 Hello World!
1290 Instead of providing a "Content-Length" header you can also call
1292 "finish" in Mojolicious::Controller and close the connection manually
1293 once you are done.
1294 use Mojolicious::Lite;
1296 get '/' => sub {
1298 my $c = shift;
1299 # Prepare body
1301 my $body = 'Hello World!';
1302 # Start writing directly with a drain callback
1304 my $drain = sub {
1305 my $c = shift;
1306 my $chunk = substr $body, 0, 1, '';
1307 length $chunk ? $c->write($chunk, __SUB__) : $c->finish;
1308 };
1309 $c->$drain;
1310 };
1311 app->start;
1313 While this is rather inefficient, as it prevents keep-alive, it is
1315 sometimes necessary for EventSource and similar applications.
1316 HTTP/1.1 200 OK
1318 Date: Sat, 13 Sep 2014 16:48:29 GMT
1319 Connection: close
1320 Server: Mojolicious (Perl)
1321 Hello World!
1323 Chunked transfer encoding
1325 For very dynamic content you might not know the response content length
1326 in advance, that's where the chunked transfer encoding and
1327 "write_chunk" in Mojolicious::Controller come in handy. A common use
1328 would be to send the "head" section of an HTML document to the browser
1329 in advance and speed up preloading of referenced images and
1330 stylesheets.
1331 use Mojolicious::Lite;
1333 get '/' => sub {
1335 my $c = shift;
1336 $c->write_chunk('<html><head><title>Example</title></head>' => sub {
1337 my $c = shift;
1338 $c->finish('<body>Example</body></html>');
1339 });
1340 };
1341 app->start;
1343 The optional drain callback ensures that all previous chunks have been
1345 written before processing continues. To end the stream you can call
1346 "finish" in Mojolicious::Controller or write an empty chunk of data.
1347 HTTP/1.1 200 OK
1349 Date: Sat, 13 Sep 2014 16:48:29 GMT
1350 Transfer-Encoding: chunked
1351 Server: Mojolicious (Perl)
1352 29
1354 <html><head><title>Example</title></head>
1355 1b
1356 <body>Example</body></html>
1357 0
1358 Especially in combination with long inactivity timeouts this can be
1360 very useful for Comet (long polling). Due to limitations in some web
1361 servers this might not work perfectly in all deployment environments.
1362 Encoding
1364 Templates stored in files are expected to be "UTF-8" by default, but
1365 that can be easily changed with "encoding" in Mojolicious::Renderer.
1366 $app->renderer->encoding('koi8-r');
1368 All templates from the "DATA" section are bound to the encoding of the
1370 Perl script.
1371 use Mojolicious::Lite;
1373 get '/heart';
1375 app->start;
1377 __DATA__
1378 @@ heart.html.ep
1380 I ♥ Mojolicious!
1381 Base64 encoded DATA files
1383 Base64 encoded static files such as images can be easily stored in the
1384 "DATA" section of your application, similar to templates.
1385 use Mojolicious::Lite;
1387 get '/' => {text => 'I ♥ Mojolicious!'};
1389 app->start;
1391 __DATA__
1392 @@ favicon.ico (base64)
1394 ...base64 encoded image...
1395 Inflating DATA templates
1397 Templates stored in files get preferred over files from the "DATA"
1398 section, this allows you to include a default set of templates in your
1399 application that the user can later customize. The command
1400 Mojolicious::Command::Author::inflate will write all templates and
1401 static files from the "DATA" section into actual files in the
1402 "templates" and "public" directories.
1403 $ ./myapp.pl inflate
1405 Customizing the template syntax
1407 You can easily change the whole template syntax by loading
1408 Mojolicious::Plugin::EPRenderer with a custom configuration.
1409 use Mojolicious::Lite;
1411 plugin EPRenderer => {
1413 name => 'mustache',
1414 template => {
1415 tag_start => '{{',
1416 tag_end => '}}'
1417 }
1418 };
1419 get '/:name' => {name => 'Anonymous'} => 'index';
1421 app->start;
1423 __DATA__
1424 @@ index.html.mustache
1426 Hello {{= $name }}.
1427 Mojo::Template contains the whole list of available options.
1429 Adding your favorite template system
1431 Maybe you would prefer a different template system than "ep", which is
1432 provided by Mojolicious::Plugin::EPRenderer, and there is not already a
1433 plugin on CPAN for your favorite one. All you have to do, is to add a
1434 new "handler" with "add_handler" in Mojolicious::Renderer when
1435 "register" is called.
1436 package Mojolicious::Plugin::MyRenderer;
1438 use Mojo::Base 'Mojolicious::Plugin';
1439 sub register {
1441 my ($self, $app) = @_;
1442 # Add "mine" handler
1444 $app->renderer->add_handler(mine => sub {
1445 my ($renderer, $c, $output, $options) = @_;
1446 # Check for one-time use inline template
1448 my $inline_template = $options->{inline};
1449 # Check for appropriate template in "templates" directories
1451 my $template_path = $renderer->template_path($options);
1452 # Check for appropriate template in DATA sections
1454 my $data_template = $renderer->get_data_template($options);
1455 # This part is up to you and your template system :)
1457 ...
1458 # Pass the rendered result back to the renderer
1460 $$output = 'Hello World!';
1461 # Or just die if an error occurs
1463 die 'Something went wrong with the template';
1464 });
1465 }
1466 1;
1468 An "inline" template, if provided by the user, will be passed along
1470 with the options. You can use "template_path" in Mojolicious::Renderer
1471 to search the "templates" directories of the application, and
1472 "get_data_template" in Mojolicious::Renderer to search the "DATA"
1473 sections.
1474 use Mojolicious::Lite;
1476 plugin 'MyRenderer';
1478 # Render an inline template
1480 get '/inline' => {inline => '...', handler => 'mine'};
1481 # Render a template from the DATA section
1483 get '/data' => {template => 'test'};
1484 app->start;
1486 __DATA__
1487 @@ test.html.mine
1489 ...
1490 Adding a handler to generate binary data
1492 By default the renderer assumes that every "handler" generates
1493 characters that need to be automatically encoded, but this can be
1494 easily disabled if you're generating bytes instead.
1495 use Mojolicious::Lite;
1497 use Storable qw(nfreeze);
1498 # Add "storable" handler
1500 app->renderer->add_handler(storable => sub {
1501 my ($renderer, $c, $output, $options) = @_;
1502 # Disable automatic encoding
1504 delete $options->{encoding};
1505 # Encode data from stash value
1507 $$output = nfreeze delete $c->stash->{storable};
1508 });
1509 # Set "handler" value automatically if "storable" value is set already
1511 app->hook(before_render => sub {
1512 my ($c, $args) = @_;
1513 $args->{handler} = 'storable'
1514 if exists $args->{storable} || exists $c->stash->{storable};
1515 });
1516 get '/' => {storable => {i => '♥ mojolicious'}};
1518 app->start;
1520 The hook "before_render" in Mojolicious can be used to make stash
1522 values like "storable" special, so that they no longer require a
1523 "handler" value to be set explicitly.
1524 # Explicit "handler" value
1526 $c->render(storable => {i => '♥ mojolicious'}, handler => 'storable');
1527 # Implicit "handler" value (with "before_render" hook)
1529 $c->render(storable => {i => '♥ mojolicious'});
1530
1532 You can continue with Mojolicious::Guides now or take a look at the
1533 Mojolicious wiki <http://github.com/mojolicious/mojo/wiki>, which
1534 contains a lot more documentation and examples by many different
1535 authors.
1536
1538 If you have any questions the documentation might not yet answer, don't
1539 hesitate to ask on the mailing list
1540 <http://groups.google.com/group/mojolicious> or the official IRC
1541 channel "#mojo" on "irc.freenode.net" (chat now!
1542 <https://webchat.freenode.net/#mojo>).
1543perl v5.32.0 2020-07-28 Mojolicious::Guides::Rendering(3)