1PERLRETUT(1) Perl Programmers Reference Guide PERLRETUT(1)
2
6 perlretut - Perl regular expressions tutorial
7
9 This page provides a basic tutorial on understanding, creating and
10 using regular expressions in Perl. It serves as a complement to the
11 reference page on regular expressions perlre. Regular expressions are
12 an integral part of the "m//", "s///", "qr//" and "split" operators and
13 so this tutorial also overlaps with "Regexp Quote-Like Operators" in
14 perlop and "split" in perlfunc.
15 Perl is widely renowned for excellence in text processing, and regular
17 expressions are one of the big factors behind this fame. Perl regular
18 expressions display an efficiency and flexibility unknown in most other
19 computer languages. Mastering even the basics of regular expressions
20 will allow you to manipulate text with surprising ease.
21 What is a regular expression? At its most basic, a regular expression
23 is a template that is used to determine if a string has certain
24 characteristics. The string is most often some text, such as a line,
25 sentence, web page, or even a whole book, but it doesn't have to be.
26 It could be binary data, for example. Biologists often use Perl to
27 look for patterns in long DNA sequences.
28 Suppose we want to determine if the text in variable, $var contains the
30 sequence of characters "m u s h r o o m" (blanks added for legibility).
31 We can write in Perl
32 $var =~ m/mushroom/
34 The value of this expression will be TRUE if $var contains that
36 sequence of characters anywhere within it, and FALSE otherwise. The
37 portion enclosed in '/' characters denotes the characteristic we are
38 looking for. We use the term pattern for it. The process of looking
39 to see if the pattern occurs in the string is called matching, and the
40 "=~" operator along with the "m//" tell Perl to try to match the
41 pattern against the string. Note that the pattern is also a string,
42 but a very special kind of one, as we will see. Patterns are in common
43 use these days; examples are the patterns typed into a search engine to
44 find web pages and the patterns used to list files in a directory,
45 e.g., ""ls *.txt"" or ""dir *.*"". In Perl, the patterns described by
46 regular expressions are used not only to search strings, but to also
47 extract desired parts of strings, and to do search and replace
48 operations.
49 Regular expressions have the undeserved reputation of being abstract
51 and difficult to understand. This really stems simply because the
52 notation used to express them tends to be terse and dense, and not
53 because of inherent complexity. We recommend using the "/x" regular
54 expression modifier (described below) along with plenty of white space
55 to make them less dense, and easier to read. Regular expressions are
56 constructed using simple concepts like conditionals and loops and are
57 no more difficult to understand than the corresponding "if"
58 conditionals and "while" loops in the Perl language itself.
59 This tutorial flattens the learning curve by discussing regular
61 expression concepts, along with their notation, one at a time and with
62 many examples. The first part of the tutorial will progress from the
63 simplest word searches to the basic regular expression concepts. If
64 you master the first part, you will have all the tools needed to solve
65 about 98% of your needs. The second part of the tutorial is for those
66 comfortable with the basics and hungry for more power tools. It
67 discusses the more advanced regular expression operators and introduces
68 the latest cutting-edge innovations.
69 A note: to save time, "regular expression" is often abbreviated as
71 regexp or regex. Regexp is a more natural abbreviation than regex, but
72 is harder to pronounce. The Perl pod documentation is evenly split on
73 regexp vs regex; in Perl, there is more than one way to abbreviate it.
74 We'll use regexp in this tutorial.
75 New in v5.22, "use re 'strict'" applies stricter rules than otherwise
77 when compiling regular expression patterns. It can find things that,
78 while legal, may not be what you intended.
79
81 Simple word matching
82 The simplest regexp is simply a word, or more generally, a string of
83 characters. A regexp consisting of just a word matches any string that
84 contains that word:
85 "Hello World" =~ /World/; # matches
87 What is this Perl statement all about? "Hello World" is a simple
89 double-quoted string. "World" is the regular expression and the "//"
90 enclosing "/World/" tells Perl to search a string for a match. The
91 operator "=~" associates the string with the regexp match and produces
92 a true value if the regexp matched, or false if the regexp did not
93 match. In our case, "World" matches the second word in "Hello World",
94 so the expression is true. Expressions like this are useful in
95 conditionals:
96 if ("Hello World" =~ /World/) {
98 print "It matches\n";
99 }
100 else {
101 print "It doesn't match\n";
102 }
103 There are useful variations on this theme. The sense of the match can
105 be reversed by using the "!~" operator:
106 if ("Hello World" !~ /World/) {
108 print "It doesn't match\n";
109 }
110 else {
111 print "It matches\n";
112 }
113 The literal string in the regexp can be replaced by a variable:
115 my $greeting = "World";
117 if ("Hello World" =~ /$greeting/) {
118 print "It matches\n";
119 }
120 else {
121 print "It doesn't match\n";
122 }
123 If you're matching against the special default variable $_, the "$_ =~"
125 part can be omitted:
126 $_ = "Hello World";
128 if (/World/) {
129 print "It matches\n";
130 }
131 else {
132 print "It doesn't match\n";
133 }
134 And finally, the "//" default delimiters for a match can be changed to
136 arbitrary delimiters by putting an 'm' out front:
137 "Hello World" =~ m!World!; # matches, delimited by '!'
139 "Hello World" =~ m{World}; # matches, note the paired '{}'
140 "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
141 # '/' becomes an ordinary char
142 "/World/", "m!World!", and "m{World}" all represent the same thing.
144 When, e.g., the quote ('"') is used as a delimiter, the forward slash
145 '/' becomes an ordinary character and can be used in this regexp
146 without trouble.
147 Let's consider how different regexps would match "Hello World":
149 "Hello World" =~ /world/; # doesn't match
151 "Hello World" =~ /o W/; # matches
152 "Hello World" =~ /oW/; # doesn't match
153 "Hello World" =~ /World /; # doesn't match
154 The first regexp "world" doesn't match because regexps are by default
156 case-sensitive. The second regexp matches because the substring 'o W'
157 occurs in the string "Hello World". The space character ' ' is treated
158 like any other character in a regexp and is needed to match in this
159 case. The lack of a space character is the reason the third regexp
160 'oW' doesn't match. The fourth regexp ""World "" doesn't match because
161 there is a space at the end of the regexp, but not at the end of the
162 string. The lesson here is that regexps must match a part of the
163 string exactly in order for the statement to be true.
164 If a regexp matches in more than one place in the string, Perl will
166 always match at the earliest possible point in the string:
167 "Hello World" =~ /o/; # matches 'o' in 'Hello'
169 "That hat is red" =~ /hat/; # matches 'hat' in 'That'
170 With respect to character matching, there are a few more points you
172 need to know about. First of all, not all characters can be used "as-
173 is" in a match. Some characters, called metacharacters, are generally
174 reserved for use in regexp notation. The metacharacters are
175 {}[]()^$.|*+?-#\
177 This list is not as definitive as it may appear (or be claimed to be in
179 other documentation). For example, "#" is a metacharacter only when
180 the "/x" pattern modifier (described below) is used, and both "}" and
181 "]" are metacharacters only when paired with opening "{" or "["
182 respectively; other gotchas apply.
183 The significance of each of these will be explained in the rest of the
185 tutorial, but for now, it is important only to know that a
186 metacharacter can be matched as-is by putting a backslash before it:
187 "2+2=4" =~ /2+2/; # doesn't match, + is a metacharacter
189 "2+2=4" =~ /2\+2/; # matches, \+ is treated like an ordinary +
190 "The interval is [0,1)." =~ /[0,1)./ # is a syntax error!
191 "The interval is [0,1)." =~ /\[0,1\)\./ # matches
192 "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/; # matches
193 In the last regexp, the forward slash '/' is also backslashed, because
195 it is used to delimit the regexp. This can lead to LTS (leaning
196 toothpick syndrome), however, and it is often more readable to change
197 delimiters.
198 "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!; # easier to read
200 The backslash character '\' is a metacharacter itself and needs to be
202 backslashed:
203 'C:\WIN32' =~ /C:\\WIN/; # matches
205 In situations where it doesn't make sense for a particular
207 metacharacter to mean what it normally does, it automatically loses its
208 metacharacter-ness and becomes an ordinary character that is to be
209 matched literally. For example, the '}' is a metacharacter only when
210 it is the mate of a '{' metacharacter. Otherwise it is treated as a
211 literal RIGHT CURLY BRACKET. This may lead to unexpected results.
212 "use re 'strict'" can catch some of these.
213 In addition to the metacharacters, there are some ASCII characters
215 which don't have printable character equivalents and are instead
216 represented by escape sequences. Common examples are "\t" for a tab,
217 "\n" for a newline, "\r" for a carriage return and "\a" for a bell (or
218 alert). If your string is better thought of as a sequence of arbitrary
219 bytes, the octal escape sequence, e.g., "\033", or hexadecimal escape
220 sequence, e.g., "\x1B" may be a more natural representation for your
221 bytes. Here are some examples of escapes:
222 "1000\t2000" =~ m(0\t2) # matches
224 "1000\n2000" =~ /0\n20/ # matches
225 "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
226 "cat" =~ /\o{143}\x61\x74/ # matches in ASCII, but a weird way
227 # to spell cat
228 If you've been around Perl a while, all this talk of escape sequences
230 may seem familiar. Similar escape sequences are used in double-quoted
231 strings and in fact the regexps in Perl are mostly treated as double-
232 quoted strings. This means that variables can be used in regexps as
233 well. Just like double-quoted strings, the values of the variables in
234 the regexp will be substituted in before the regexp is evaluated for
235 matching purposes. So we have:
236 $foo = 'house';
238 'housecat' =~ /$foo/; # matches
239 'cathouse' =~ /cat$foo/; # matches
240 'housecat' =~ /${foo}cat/; # matches
241 So far, so good. With the knowledge above you can already perform
243 searches with just about any literal string regexp you can dream up.
244 Here is a very simple emulation of the Unix grep program:
245 % cat > simple_grep
247 #!/usr/bin/perl
248 $regexp = shift;
249 while (<>) {
250 print if /$regexp/;
251 }
252 ^D
253 % chmod +x simple_grep
255 % simple_grep abba /usr/dict/words
257 Babbage
258 cabbage
259 cabbages
260 sabbath
261 Sabbathize
262 Sabbathizes
263 sabbatical
264 scabbard
265 scabbards
266 This program is easy to understand. "#!/usr/bin/perl" is the standard
268 way to invoke a perl program from the shell. "$regexp = shift;" saves
269 the first command line argument as the regexp to be used, leaving the
270 rest of the command line arguments to be treated as files.
271 "while (<>)" loops over all the lines in all the files. For each line,
272 "print if /$regexp/;" prints the line if the regexp matches the line.
273 In this line, both "print" and "/$regexp/" use the default variable $_
274 implicitly.
275 With all of the regexps above, if the regexp matched anywhere in the
277 string, it was considered a match. Sometimes, however, we'd like to
278 specify where in the string the regexp should try to match. To do
279 this, we would use the anchor metacharacters '^' and '$'. The anchor
280 '^' means match at the beginning of the string and the anchor '$' means
281 match at the end of the string, or before a newline at the end of the
282 string. Here is how they are used:
283 "housekeeper" =~ /keeper/; # matches
285 "housekeeper" =~ /^keeper/; # doesn't match
286 "housekeeper" =~ /keeper$/; # matches
287 "housekeeper\n" =~ /keeper$/; # matches
288 The second regexp doesn't match because '^' constrains "keeper" to
290 match only at the beginning of the string, but "housekeeper" has keeper
291 starting in the middle. The third regexp does match, since the '$'
292 constrains "keeper" to match only at the end of the string.
293 When both '^' and '$' are used at the same time, the regexp has to
295 match both the beginning and the end of the string, i.e., the regexp
296 matches the whole string. Consider
297 "keeper" =~ /^keep$/; # doesn't match
299 "keeper" =~ /^keeper$/; # matches
300 "" =~ /^$/; # ^$ matches an empty string
301 The first regexp doesn't match because the string has more to it than
303 "keep". Since the second regexp is exactly the string, it matches.
304 Using both '^' and '$' in a regexp forces the complete string to match,
305 so it gives you complete control over which strings match and which
306 don't. Suppose you are looking for a fellow named bert, off in a
307 string by himself:
308 "dogbert" =~ /bert/; # matches, but not what you want
310 "dilbert" =~ /^bert/; # doesn't match, but ..
312 "bertram" =~ /^bert/; # matches, so still not good enough
313 "bertram" =~ /^bert$/; # doesn't match, good
315 "dilbert" =~ /^bert$/; # doesn't match, good
316 "bert" =~ /^bert$/; # matches, perfect
317 Of course, in the case of a literal string, one could just as easily
319 use the string comparison "$string eq 'bert'" and it would be more
320 efficient. The "^...$" regexp really becomes useful when we add in
321 the more powerful regexp tools below.
322 Using character classes
324 Although one can already do quite a lot with the literal string regexps
325 above, we've only scratched the surface of regular expression
326 technology. In this and subsequent sections we will introduce regexp
327 concepts (and associated metacharacter notations) that will allow a
328 regexp to represent not just a single character sequence, but a whole
329 class of them.
330 One such concept is that of a character class. A character class
332 allows a set of possible characters, rather than just a single
333 character, to match at a particular point in a regexp. You can define
334 your own custom character classes. These are denoted by brackets
335 "[...]", with the set of characters to be possibly matched inside.
336 Here are some examples:
337 /cat/; # matches 'cat'
339 /[bcr]at/; # matches 'bat, 'cat', or 'rat'
340 /item[0123456789]/; # matches 'item0' or ... or 'item9'
341 "abc" =~ /[cab]/; # matches 'a'
342 In the last statement, even though 'c' is the first character in the
344 class, 'a' matches because the first character position in the string
345 is the earliest point at which the regexp can match.
346 /[yY][eE][sS]/; # match 'yes' in a case-insensitive way
348 # 'yes', 'Yes', 'YES', etc.
349 This regexp displays a common task: perform a case-insensitive match.
351 Perl provides a way of avoiding all those brackets by simply appending
352 an 'i' to the end of the match. Then "/[yY][eE][sS]/;" can be
353 rewritten as "/yes/i;". The 'i' stands for case-insensitive and is an
354 example of a modifier of the matching operation. We will meet other
355 modifiers later in the tutorial.
356 We saw in the section above that there were ordinary characters, which
358 represented themselves, and special characters, which needed a
359 backslash '\' to represent themselves. The same is true in a character
360 class, but the sets of ordinary and special characters inside a
361 character class are different than those outside a character class.
362 The special characters for a character class are "-]\^$" (and the
363 pattern delimiter, whatever it is). ']' is special because it denotes
364 the end of a character class. '$' is special because it denotes a
365 scalar variable. '\' is special because it is used in escape
366 sequences, just like above. Here is how the special characters "]$\"
367 are handled:
368 /[\]c]def/; # matches ']def' or 'cdef'
370 $x = 'bcr';
371 /[$x]at/; # matches 'bat', 'cat', or 'rat'
372 /[\$x]at/; # matches '$at' or 'xat'
373 /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
374 The last two are a little tricky. In "[\$x]", the backslash protects
376 the dollar sign, so the character class has two members '$' and 'x'.
377 In "[\\$x]", the backslash is protected, so $x is treated as a variable
378 and substituted in double quote fashion.
379 The special character '-' acts as a range operator within character
381 classes, so that a contiguous set of characters can be written as a
382 range. With ranges, the unwieldy "[0123456789]" and "[abc...xyz]"
383 become the svelte "[0-9]" and "[a-z]". Some examples are
384 /item[0-9]/; # matches 'item0' or ... or 'item9'
386 /[0-9bx-z]aa/; # matches '0aa', ..., '9aa',
387 # 'baa', 'xaa', 'yaa', or 'zaa'
388 /[0-9a-fA-F]/; # matches a hexadecimal digit
389 /[0-9a-zA-Z_]/; # matches a "word" character,
390 # like those in a Perl variable name
391 If '-' is the first or last character in a character class, it is
393 treated as an ordinary character; "[-ab]", "[ab-]" and "[a\-b]" are all
394 equivalent.
395 The special character '^' in the first position of a character class
397 denotes a negated character class, which matches any character but
398 those in the brackets. Both "[...]" and "[^...]" must match a
399 character, or the match fails. Then
400 /[^a]at/; # doesn't match 'aat' or 'at', but matches
402 # all other 'bat', 'cat, '0at', '%at', etc.
403 /[^0-9]/; # matches a non-numeric character
404 /[a^]at/; # matches 'aat' or '^at'; here '^' is ordinary
405 Now, even "[0-9]" can be a bother to write multiple times, so in the
407 interest of saving keystrokes and making regexps more readable, Perl
408 has several abbreviations for common character classes, as shown below.
409 Since the introduction of Unicode, unless the "/a" modifier is in
410 effect, these character classes match more than just a few characters
411 in the ASCII range.
412 • "\d" matches a digit, not just "[0-9]" but also digits from non-
414 roman scripts
415 • "\s" matches a whitespace character, the set "[\ \t\r\n\f]" and
417 others
418 • "\w" matches a word character (alphanumeric or '_'), not just
420 "[0-9a-zA-Z_]" but also digits and characters from non-roman
421 scripts
422 • "\D" is a negated "\d"; it represents any other character than a
424 digit, or "[^\d]"
425 • "\S" is a negated "\s"; it represents any non-whitespace character
427 "[^\s]"
428 • "\W" is a negated "\w"; it represents any non-word character
430 "[^\w]"
431 • The period '.' matches any character but "\n" (unless the modifier
433 "/s" is in effect, as explained below).
434 • "\N", like the period, matches any character but "\n", but it does
436 so regardless of whether the modifier "/s" is in effect.
437 The "/a" modifier, available starting in Perl 5.14, is used to
439 restrict the matches of "\d", "\s", and "\w" to just those in the ASCII
440 range. It is useful to keep your program from being needlessly exposed
441 to full Unicode (and its accompanying security considerations) when all
442 you want is to process English-like text. (The "a" may be doubled,
443 "/aa", to provide even more restrictions, preventing case-insensitive
444 matching of ASCII with non-ASCII characters; otherwise a Unicode
445 "Kelvin Sign" would caselessly match a "k" or "K".)
446 The "\d\s\w\D\S\W" abbreviations can be used both inside and outside of
448 bracketed character classes. Here are some in use:
449 /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
451 /[\d\s]/; # matches any digit or whitespace character
452 /\w\W\w/; # matches a word char, followed by a
453 # non-word char, followed by a word char
454 /..rt/; # matches any two chars, followed by 'rt'
455 /end\./; # matches 'end.'
456 /end[.]/; # same thing, matches 'end.'
457 Because a period is a metacharacter, it needs to be escaped to match as
459 an ordinary period. Because, for example, "\d" and "\w" are sets of
460 characters, it is incorrect to think of "[^\d\w]" as "[\D\W]"; in fact
461 "[^\d\w]" is the same as "[^\w]", which is the same as "[\W]". Think De
462 Morgan's laws.
463 In actuality, the period and "\d\s\w\D\S\W" abbreviations are
465 themselves types of character classes, so the ones surrounded by
466 brackets are just one type of character class. When we need to make a
467 distinction, we refer to them as "bracketed character classes."
468 An anchor useful in basic regexps is the word anchor "\b". This
470 matches a boundary between a word character and a non-word character
471 "\w\W" or "\W\w":
472 $x = "Housecat catenates house and cat";
474 $x =~ /cat/; # matches cat in 'housecat'
475 $x =~ /\bcat/; # matches cat in 'catenates'
476 $x =~ /cat\b/; # matches cat in 'housecat'
477 $x =~ /\bcat\b/; # matches 'cat' at end of string
478 Note in the last example, the end of the string is considered a word
480 boundary.
481 For natural language processing (so that, for example, apostrophes are
483 included in words), use instead "\b{wb}"
484 "don't" =~ / .+? \b{wb} /x; # matches the whole string
486 You might wonder why '.' matches everything but "\n" - why not every
488 character? The reason is that often one is matching against lines and
489 would like to ignore the newline characters. For instance, while the
490 string "\n" represents one line, we would like to think of it as empty.
491 Then
492 "" =~ /^$/; # matches
494 "\n" =~ /^$/; # matches, $ anchors before "\n"
495 "" =~ /./; # doesn't match; it needs a char
497 "" =~ /^.$/; # doesn't match; it needs a char
498 "\n" =~ /^.$/; # doesn't match; it needs a char other than "\n"
499 "a" =~ /^.$/; # matches
500 "a\n" =~ /^.$/; # matches, $ anchors before "\n"
501 This behavior is convenient, because we usually want to ignore newlines
503 when we count and match characters in a line. Sometimes, however, we
504 want to keep track of newlines. We might even want '^' and '$' to
505 anchor at the beginning and end of lines within the string, rather than
506 just the beginning and end of the string. Perl allows us to choose
507 between ignoring and paying attention to newlines by using the "/s" and
508 "/m" modifiers. "/s" and "/m" stand for single line and multi-line and
509 they determine whether a string is to be treated as one continuous
510 string, or as a set of lines. The two modifiers affect two aspects of
511 how the regexp is interpreted: 1) how the '.' character class is
512 defined, and 2) where the anchors '^' and '$' are able to match. Here
513 are the four possible combinations:
514 • no modifiers: Default behavior. '.' matches any character except
516 "\n". '^' matches only at the beginning of the string and '$'
517 matches only at the end or before a newline at the end.
518 • s modifier ("/s"): Treat string as a single long line. '.' matches
520 any character, even "\n". '^' matches only at the beginning of the
521 string and '$' matches only at the end or before a newline at the
522 end.
523 • m modifier ("/m"): Treat string as a set of multiple lines. '.'
525 matches any character except "\n". '^' and '$' are able to match
526 at the start or end of any line within the string.
527 • both s and m modifiers ("/sm"): Treat string as a single long line,
529 but detect multiple lines. '.' matches any character, even "\n".
530 '^' and '$', however, are able to match at the start or end of any
531 line within the string.
532 Here are examples of "/s" and "/m" in action:
534 $x = "There once was a girl\nWho programmed in Perl\n";
536 $x =~ /^Who/; # doesn't match, "Who" not at start of string
538 $x =~ /^Who/s; # doesn't match, "Who" not at start of string
539 $x =~ /^Who/m; # matches, "Who" at start of second line
540 $x =~ /^Who/sm; # matches, "Who" at start of second line
541 $x =~ /girl.Who/; # doesn't match, "." doesn't match "\n"
543 $x =~ /girl.Who/s; # matches, "." matches "\n"
544 $x =~ /girl.Who/m; # doesn't match, "." doesn't match "\n"
545 $x =~ /girl.Who/sm; # matches, "." matches "\n"
546 Most of the time, the default behavior is what is wanted, but "/s" and
548 "/m" are occasionally very useful. If "/m" is being used, the start of
549 the string can still be matched with "\A" and the end of the string can
550 still be matched with the anchors "\Z" (matches both the end and the
551 newline before, like '$'), and "\z" (matches only the end):
552 $x =~ /^Who/m; # matches, "Who" at start of second line
554 $x =~ /\AWho/m; # doesn't match, "Who" is not at start of string
555 $x =~ /girl$/m; # matches, "girl" at end of first line
557 $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
558 $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
560 $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
561 We now know how to create choices among classes of characters in a
563 regexp. What about choices among words or character strings? Such
564 choices are described in the next section.
565 Matching this or that
567 Sometimes we would like our regexp to be able to match different
568 possible words or character strings. This is accomplished by using the
569 alternation metacharacter '|'. To match "dog" or "cat", we form the
570 regexp "dog|cat". As before, Perl will try to match the regexp at the
571 earliest possible point in the string. At each character position,
572 Perl will first try to match the first alternative, "dog". If "dog"
573 doesn't match, Perl will then try the next alternative, "cat". If
574 "cat" doesn't match either, then the match fails and Perl moves to the
575 next position in the string. Some examples:
576 "cats and dogs" =~ /cat|dog|bird/; # matches "cat"
578 "cats and dogs" =~ /dog|cat|bird/; # matches "cat"
579 Even though "dog" is the first alternative in the second regexp, "cat"
581 is able to match earlier in the string.
582 "cats" =~ /c|ca|cat|cats/; # matches "c"
584 "cats" =~ /cats|cat|ca|c/; # matches "cats"
585 Here, all the alternatives match at the first string position, so the
587 first alternative is the one that matches. If some of the alternatives
588 are truncations of the others, put the longest ones first to give them
589 a chance to match.
590 "cab" =~ /a|b|c/ # matches "c"
592 # /a|b|c/ == /[abc]/
593 The last example points out that character classes are like
595 alternations of characters. At a given character position, the first
596 alternative that allows the regexp match to succeed will be the one
597 that matches.
598 Grouping things and hierarchical matching
600 Alternation allows a regexp to choose among alternatives, but by itself
601 it is unsatisfying. The reason is that each alternative is a whole
602 regexp, but sometime we want alternatives for just part of a regexp.
603 For instance, suppose we want to search for housecats or housekeepers.
604 The regexp "housecat|housekeeper" fits the bill, but is inefficient
605 because we had to type "house" twice. It would be nice to have parts
606 of the regexp be constant, like "house", and some parts have
607 alternatives, like "cat|keeper".
608 The grouping metacharacters "()" solve this problem. Grouping allows
610 parts of a regexp to be treated as a single unit. Parts of a regexp
611 are grouped by enclosing them in parentheses. Thus we could solve the
612 "housecat|housekeeper" by forming the regexp as "house(cat|keeper)".
613 The regexp "house(cat|keeper)" means match "house" followed by either
614 "cat" or "keeper". Some more examples are
615 /(a|b)b/; # matches 'ab' or 'bb'
617 /(ac|b)b/; # matches 'acb' or 'bb'
618 /(^a|b)c/; # matches 'ac' at start of string or 'bc' anywhere
619 /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
620 /house(cat|)/; # matches either 'housecat' or 'house'
622 /house(cat(s|)|)/; # matches either 'housecats' or 'housecat' or
623 # 'house'. Note groups can be nested.
624 /(19|20|)\d\d/; # match years 19xx, 20xx, or the Y2K problem, xx
626 "20" =~ /(19|20|)\d\d/; # matches the null alternative '()\d\d',
627 # because '20\d\d' can't match
628 Alternations behave the same way in groups as out of them: at a given
630 string position, the leftmost alternative that allows the regexp to
631 match is taken. So in the last example at the first string position,
632 "20" matches the second alternative, but there is nothing left over to
633 match the next two digits "\d\d". So Perl moves on to the next
634 alternative, which is the null alternative and that works, since "20"
635 is two digits.
636 The process of trying one alternative, seeing if it matches, and moving
638 on to the next alternative, while going back in the string from where
639 the previous alternative was tried, if it doesn't, is called
640 backtracking. The term "backtracking" comes from the idea that
641 matching a regexp is like a walk in the woods. Successfully matching a
642 regexp is like arriving at a destination. There are many possible
643 trailheads, one for each string position, and each one is tried in
644 order, left to right. From each trailhead there may be many paths,
645 some of which get you there, and some which are dead ends. When you
646 walk along a trail and hit a dead end, you have to backtrack along the
647 trail to an earlier point to try another trail. If you hit your
648 destination, you stop immediately and forget about trying all the other
649 trails. You are persistent, and only if you have tried all the trails
650 from all the trailheads and not arrived at your destination, do you
651 declare failure. To be concrete, here is a step-by-step analysis of
652 what Perl does when it tries to match the regexp
653 "abcde" =~ /(abd|abc)(df|d|de)/;
655 0. Start with the first letter in the string 'a'.
657 1. Try the first alternative in the first group 'abd'.
660 2. Match 'a' followed by 'b'. So far so good.
663 3. 'd' in the regexp doesn't match 'c' in the string - a dead end. So
666 backtrack two characters and pick the second alternative in the first
667 group 'abc'.
668 4. Match 'a' followed by 'b' followed by 'c'. We are on a roll and
671 have satisfied the first group. Set $1 to 'abc'.
672 5 Move on to the second group and pick the first alternative 'df'.
675 6 Match the 'd'.
678 7. 'f' in the regexp doesn't match 'e' in the string, so a dead end.
681 Backtrack one character and pick the second alternative in the second
682 group 'd'.
683 8. 'd' matches. The second grouping is satisfied, so set $2 to 'd'.
686 9. We are at the end of the regexp, so we are done! We have matched
689 'abcd' out of the string "abcde".
690 There are a couple of things to note about this analysis. First, the
692 third alternative in the second group 'de' also allows a match, but we
693 stopped before we got to it - at a given character position, leftmost
694 wins. Second, we were able to get a match at the first character
695 position of the string 'a'. If there were no matches at the first
696 position, Perl would move to the second character position 'b' and
697 attempt the match all over again. Only when all possible paths at all
698 possible character positions have been exhausted does Perl give up and
699 declare "$string =~ /(abd|abc)(df|d|de)/;" to be false.
700 Even with all this work, regexp matching happens remarkably fast. To
702 speed things up, Perl compiles the regexp into a compact sequence of
703 opcodes that can often fit inside a processor cache. When the code is
704 executed, these opcodes can then run at full throttle and search very
705 quickly.
706 Extracting matches
708 The grouping metacharacters "()" also serve another completely
709 different function: they allow the extraction of the parts of a string
710 that matched. This is very useful to find out what matched and for
711 text processing in general. For each grouping, the part that matched
712 inside goes into the special variables $1, $2, etc. They can be used
713 just as ordinary variables:
714 # extract hours, minutes, seconds
716 if ($time =~ /(\d\d):(\d\d):(\d\d)/) { # match hh:mm:ss format
717 $hours = $1;
718 $minutes = $2;
719 $seconds = $3;
720 }
721 Now, we know that in scalar context, "$time =~ /(\d\d):(\d\d):(\d\d)/"
723 returns a true or false value. In list context, however, it returns
724 the list of matched values "($1,$2,$3)". So we could write the code
725 more compactly as
726 # extract hours, minutes, seconds
728 ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
729 If the groupings in a regexp are nested, $1 gets the group with the
731 leftmost opening parenthesis, $2 the next opening parenthesis, etc.
732 Here is a regexp with nested groups:
733 /(ab(cd|ef)((gi)|j))/;
735 1 2 34
736 If this regexp matches, $1 contains a string starting with 'ab', $2 is
738 either set to 'cd' or 'ef', $3 equals either 'gi' or 'j', and $4 is
739 either set to 'gi', just like $3, or it remains undefined.
740 For convenience, Perl sets $+ to the string held by the highest
742 numbered $1, $2,... that got assigned (and, somewhat related, $^N to
743 the value of the $1, $2,... most-recently assigned; i.e. the $1, $2,...
744 associated with the rightmost closing parenthesis used in the match).
745 Backreferences
747 Closely associated with the matching variables $1, $2, ... are the
748 backreferences "\g1", "\g2",... Backreferences are simply matching
749 variables that can be used inside a regexp. This is a really nice
750 feature; what matches later in a regexp is made to depend on what
751 matched earlier in the regexp. Suppose we wanted to look for doubled
752 words in a text, like "the the". The following regexp finds all
753 3-letter doubles with a space in between:
754 /\b(\w\w\w)\s\g1\b/;
756 The grouping assigns a value to "\g1", so that the same 3-letter
758 sequence is used for both parts.
759 A similar task is to find words consisting of two identical parts:
761 % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
763 beriberi
764 booboo
765 coco
766 mama
767 murmur
768 papa
769 The regexp has a single grouping which considers 4-letter combinations,
771 then 3-letter combinations, etc., and uses "\g1" to look for a repeat.
772 Although $1 and "\g1" represent the same thing, care should be taken to
773 use matched variables $1, $2,... only outside a regexp and
774 backreferences "\g1", "\g2",... only inside a regexp; not doing so may
775 lead to surprising and unsatisfactory results.
776 Relative backreferences
778 Counting the opening parentheses to get the correct number for a
779 backreference is error-prone as soon as there is more than one
780 capturing group. A more convenient technique became available with
781 Perl 5.10: relative backreferences. To refer to the immediately
782 preceding capture group one now may write "\g-1" or "\g{-1}", the next
783 but last is available via "\g-2" or "\g{-2}", and so on.
784 Another good reason in addition to readability and maintainability for
786 using relative backreferences is illustrated by the following example,
787 where a simple pattern for matching peculiar strings is used:
788 $a99a = '([a-z])(\d)\g2\g1'; # matches a11a, g22g, x33x, etc.
790 Now that we have this pattern stored as a handy string, we might feel
792 tempted to use it as a part of some other pattern:
793 $line = "code=e99e";
795 if ($line =~ /^(\w+)=$a99a$/){ # unexpected behavior!
796 print "$1 is valid\n";
797 } else {
798 print "bad line: '$line'\n";
799 }
800 But this doesn't match, at least not the way one might expect. Only
802 after inserting the interpolated $a99a and looking at the resulting
803 full text of the regexp is it obvious that the backreferences have
804 backfired. The subexpression "(\w+)" has snatched number 1 and demoted
805 the groups in $a99a by one rank. This can be avoided by using relative
806 backreferences:
807 $a99a = '([a-z])(\d)\g{-1}\g{-2}'; # safe for being interpolated
809 Named backreferences
811 Perl 5.10 also introduced named capture groups and named
812 backreferences. To attach a name to a capturing group, you write
813 either "(?<name>...)" or "(?'name'...)". The backreference may then be
814 written as "\g{name}". It is permissible to attach the same name to
815 more than one group, but then only the leftmost one of the eponymous
816 set can be referenced. Outside of the pattern a named capture group is
817 accessible through the "%+" hash.
818 Assuming that we have to match calendar dates which may be given in one
820 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
821 three suitable patterns where we use 'd', 'm' and 'y' respectively as
822 the names of the groups capturing the pertaining components of a date.
823 The matching operation combines the three patterns as alternatives:
824 $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
826 $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
827 $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
828 for my $d (qw(2006-10-21 15.01.2007 10/31/2005)) {
829 if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
830 print "day=$+{d} month=$+{m} year=$+{y}\n";
831 }
832 }
833 If any of the alternatives matches, the hash "%+" is bound to contain
835 the three key-value pairs.
836 Alternative capture group numbering
838 Yet another capturing group numbering technique (also as from Perl
839 5.10) deals with the problem of referring to groups within a set of
840 alternatives. Consider a pattern for matching a time of the day, civil
841 or military style:
842 if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
844 # process hour and minute
845 }
846 Processing the results requires an additional if statement to determine
848 whether $1 and $2 or $3 and $4 contain the goodies. It would be easier
849 if we could use group numbers 1 and 2 in second alternative as well,
850 and this is exactly what the parenthesized construct "(?|...)", set
851 around an alternative achieves. Here is an extended version of the
852 previous pattern:
853 if($time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/){
855 print "hour=$1 minute=$2 zone=$3\n";
856 }
857 Within the alternative numbering group, group numbers start at the same
859 position for each alternative. After the group, numbering continues
860 with one higher than the maximum reached across all the alternatives.
861 Position information
863 In addition to what was matched, Perl also provides the positions of
864 what was matched as contents of the "@-" and "@+" arrays. "$-[0]" is
865 the position of the start of the entire match and $+[0] is the position
866 of the end. Similarly, "$-[n]" is the position of the start of the $n
867 match and $+[n] is the position of the end. If $n is undefined, so are
868 "$-[n]" and $+[n]. Then this code
869 $x = "Mmm...donut, thought Homer";
871 $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
872 foreach $exp (1..$#-) {
873 no strict 'refs';
874 print "Match $exp: '$$exp' at position ($-[$exp],$+[$exp])\n";
875 }
876 prints
878 Match 1: 'Mmm' at position (0,3)
880 Match 2: 'donut' at position (6,11)
881 Even if there are no groupings in a regexp, it is still possible to
883 find out what exactly matched in a string. If you use them, Perl will
884 set "$`" to the part of the string before the match, will set $& to the
885 part of the string that matched, and will set "$'" to the part of the
886 string after the match. An example:
887 $x = "the cat caught the mouse";
889 $x =~ /cat/; # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
890 $x =~ /the/; # $` = '', $& = 'the', $' = ' cat caught the mouse'
891 In the second match, "$`" equals '' because the regexp matched at the
893 first character position in the string and stopped; it never saw the
894 second "the".
895 If your code is to run on Perl versions earlier than 5.20, it is
897 worthwhile to note that using "$`" and "$'" slows down regexp matching
898 quite a bit, while $& slows it down to a lesser extent, because if they
899 are used in one regexp in a program, they are generated for all regexps
900 in the program. So if raw performance is a goal of your application,
901 they should be avoided. If you need to extract the corresponding
902 substrings, use "@-" and "@+" instead:
903 $` is the same as substr( $x, 0, $-[0] )
905 $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
906 $' is the same as substr( $x, $+[0] )
907 As of Perl 5.10, the "${^PREMATCH}", "${^MATCH}" and "${^POSTMATCH}"
909 variables may be used. These are only set if the "/p" modifier is
910 present. Consequently they do not penalize the rest of the program.
911 In Perl 5.20, "${^PREMATCH}", "${^MATCH}" and "${^POSTMATCH}" are
912 available whether the "/p" has been used or not (the modifier is
913 ignored), and "$`", "$'" and $& do not cause any speed difference.
914 Non-capturing groupings
916 A group that is required to bundle a set of alternatives may or may not
917 be useful as a capturing group. If it isn't, it just creates a
918 superfluous addition to the set of available capture group values,
919 inside as well as outside the regexp. Non-capturing groupings, denoted
920 by "(?:regexp)", still allow the regexp to be treated as a single unit,
921 but don't establish a capturing group at the same time. Both capturing
922 and non-capturing groupings are allowed to co-exist in the same regexp.
923 Because there is no extraction, non-capturing groupings are faster than
924 capturing groupings. Non-capturing groupings are also handy for
925 choosing exactly which parts of a regexp are to be extracted to
926 matching variables:
927 # match a number, $1-$4 are set, but we only want $1
929 /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
930 # match a number faster , only $1 is set
932 /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
933 # match a number, get $1 = whole number, $2 = exponent
935 /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
936 Non-capturing groupings are also useful for removing nuisance elements
938 gathered from a split operation where parentheses are required for some
939 reason:
940 $x = '12aba34ba5';
942 @num = split /(a|b)+/, $x; # @num = ('12','a','34','a','5')
943 @num = split /(?:a|b)+/, $x; # @num = ('12','34','5')
944 In Perl 5.22 and later, all groups within a regexp can be set to non-
946 capturing by using the new "/n" flag:
947 "hello" =~ /(hi|hello)/n; # $1 is not set!
949 See "n" in perlre for more information.
951 Matching repetitions
953 The examples in the previous section display an annoying weakness. We
954 were only matching 3-letter words, or chunks of words of 4 letters or
955 less. We'd like to be able to match words or, more generally, strings
956 of any length, without writing out tedious alternatives like
957 "\w\w\w\w|\w\w\w|\w\w|\w".
958 This is exactly the problem the quantifier metacharacters '?', '*',
960 '+', and "{}" were created for. They allow us to delimit the number of
961 repeats for a portion of a regexp we consider to be a match.
962 Quantifiers are put immediately after the character, character class,
963 or grouping that we want to specify. They have the following meanings:
964 • "a?" means: match 'a' 1 or 0 times
966 • "a*" means: match 'a' 0 or more times, i.e., any number of times
968 • "a+" means: match 'a' 1 or more times, i.e., at least once
970 • "a{n,m}" means: match at least "n" times, but not more than "m"
972 times.
973 • "a{n,}" means: match at least "n" or more times
975 • "a{,n}" means: match at most "n" times, or fewer
977 • "a{n}" means: match exactly "n" times
979 If you like, you can add blanks (tab or space characters) within the
981 braces, but adjacent to them, and/or next to the comma (if any).
982 Here are some examples:
984 /[a-z]+\s+\d*/; # match a lowercase word, at least one space, and
986 # any number of digits
987 /(\w+)\s+\g1/; # match doubled words of arbitrary length
988 /y(es)?/i; # matches 'y', 'Y', or a case-insensitive 'yes'
989 $year =~ /^\d{2,4}$/; # make sure year is at least 2 but not more
990 # than 4 digits
991 $year =~ /^\d{ 2, 4 }$/; # Same; for those who like wide open
992 # spaces.
993 $year =~ /^\d{2, 4}$/; # Same.
994 $year =~ /^\d{4}$|^\d{2}$/; # better match; throw out 3-digit dates
995 $year =~ /^\d{2}(\d{2})?$/; # same thing written differently.
996 # However, this captures the last two
997 # digits in $1 and the other does not.
998 % simple_grep '^(\w+)\g1$' /usr/dict/words # isn't this easier?
1000 beriberi
1001 booboo
1002 coco
1003 mama
1004 murmur
1005 papa
1006 For all of these quantifiers, Perl will try to match as much of the
1008 string as possible, while still allowing the regexp to succeed. Thus
1009 with "/a?.../", Perl will first try to match the regexp with the 'a'
1010 present; if that fails, Perl will try to match the regexp without the
1011 'a' present. For the quantifier '*', we get the following:
1012 $x = "the cat in the hat";
1014 $x =~ /^(.*)(cat)(.*)$/; # matches,
1015 # $1 = 'the '
1016 # $2 = 'cat'
1017 # $3 = ' in the hat'
1018 Which is what we might expect, the match finds the only "cat" in the
1020 string and locks onto it. Consider, however, this regexp:
1021 $x =~ /^(.*)(at)(.*)$/; # matches,
1023 # $1 = 'the cat in the h'
1024 # $2 = 'at'
1025 # $3 = '' (0 characters match)
1026 One might initially guess that Perl would find the "at" in "cat" and
1028 stop there, but that wouldn't give the longest possible string to the
1029 first quantifier ".*". Instead, the first quantifier ".*" grabs as
1030 much of the string as possible while still having the regexp match. In
1031 this example, that means having the "at" sequence with the final "at"
1032 in the string. The other important principle illustrated here is that,
1033 when there are two or more elements in a regexp, the leftmost
1034 quantifier, if there is one, gets to grab as much of the string as
1035 possible, leaving the rest of the regexp to fight over scraps. Thus in
1036 our example, the first quantifier ".*" grabs most of the string, while
1037 the second quantifier ".*" gets the empty string. Quantifiers that
1038 grab as much of the string as possible are called maximal match or
1039 greedy quantifiers.
1040 When a regexp can match a string in several different ways, we can use
1042 the principles above to predict which way the regexp will match:
1043 • Principle 0: Taken as a whole, any regexp will be matched at the
1045 earliest possible position in the string.
1046 • Principle 1: In an alternation "a|b|c...", the leftmost alternative
1048 that allows a match for the whole regexp will be the one used.
1049 • Principle 2: The maximal matching quantifiers '?', '*', '+' and
1051 "{n,m}" will in general match as much of the string as possible
1052 while still allowing the whole regexp to match.
1053 • Principle 3: If there are two or more elements in a regexp, the
1055 leftmost greedy quantifier, if any, will match as much of the
1056 string as possible while still allowing the whole regexp to match.
1057 The next leftmost greedy quantifier, if any, will try to match as
1058 much of the string remaining available to it as possible, while
1059 still allowing the whole regexp to match. And so on, until all the
1060 regexp elements are satisfied.
1061 As we have seen above, Principle 0 overrides the others. The regexp
1063 will be matched as early as possible, with the other principles
1064 determining how the regexp matches at that earliest character position.
1065 Here is an example of these principles in action:
1067 $x = "The programming republic of Perl";
1069 $x =~ /^(.+)(e|r)(.*)$/; # matches,
1070 # $1 = 'The programming republic of Pe'
1071 # $2 = 'r'
1072 # $3 = 'l'
1073 This regexp matches at the earliest string position, 'T'. One might
1075 think that 'e', being leftmost in the alternation, would be matched,
1076 but 'r' produces the longest string in the first quantifier.
1077 $x =~ /(m{1,2})(.*)$/; # matches,
1079 # $1 = 'mm'
1080 # $2 = 'ing republic of Perl'
1081 Here, The earliest possible match is at the first 'm' in "programming".
1083 "m{1,2}" is the first quantifier, so it gets to match a maximal "mm".
1084 $x =~ /.*(m{1,2})(.*)$/; # matches,
1086 # $1 = 'm'
1087 # $2 = 'ing republic of Perl'
1088 Here, the regexp matches at the start of the string. The first
1090 quantifier ".*" grabs as much as possible, leaving just a single 'm'
1091 for the second quantifier "m{1,2}".
1092 $x =~ /(.?)(m{1,2})(.*)$/; # matches,
1094 # $1 = 'a'
1095 # $2 = 'mm'
1096 # $3 = 'ing republic of Perl'
1097 Here, ".?" eats its maximal one character at the earliest possible
1099 position in the string, 'a' in "programming", leaving "m{1,2}" the
1100 opportunity to match both 'm''s. Finally,
1101 "aXXXb" =~ /(X*)/; # matches with $1 = ''
1103 because it can match zero copies of 'X' at the beginning of the string.
1105 If you definitely want to match at least one 'X', use "X+", not "X*".
1106 Sometimes greed is not good. At times, we would like quantifiers to
1108 match a minimal piece of string, rather than a maximal piece. For this
1109 purpose, Larry Wall created the minimal match or non-greedy quantifiers
1110 "??", "*?", "+?", and "{}?". These are the usual quantifiers with a
1111 '?' appended to them. They have the following meanings:
1112 • "a??" means: match 'a' 0 or 1 times. Try 0 first, then 1.
1114 • "a*?" means: match 'a' 0 or more times, i.e., any number of times,
1116 but as few times as possible
1117 • "a+?" means: match 'a' 1 or more times, i.e., at least once, but as
1119 few times as possible
1120 • "a{n,m}?" means: match at least "n" times, not more than "m" times,
1122 as few times as possible
1123 • "a{n,}?" means: match at least "n" times, but as few times as
1125 possible
1126 • "a{,n}?" means: match at most "n" times, but as few times as
1128 possible
1129 • "a{n}?" means: match exactly "n" times. Because we match exactly
1131 "n" times, "a{n}?" is equivalent to "a{n}" and is just there for
1132 notational consistency.
1133 Let's look at the example above, but with minimal quantifiers:
1135 $x = "The programming republic of Perl";
1137 $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1138 # $1 = 'Th'
1139 # $2 = 'e'
1140 # $3 = ' programming republic of Perl'
1141 The minimal string that will allow both the start of the string '^' and
1143 the alternation to match is "Th", with the alternation "e|r" matching
1144 'e'. The second quantifier ".*" is free to gobble up the rest of the
1145 string.
1146 $x =~ /(m{1,2}?)(.*?)$/; # matches,
1148 # $1 = 'm'
1149 # $2 = 'ming republic of Perl'
1150 The first string position that this regexp can match is at the first
1152 'm' in "programming". At this position, the minimal "m{1,2}?" matches
1153 just one 'm'. Although the second quantifier ".*?" would prefer to
1154 match no characters, it is constrained by the end-of-string anchor '$'
1155 to match the rest of the string.
1156 $x =~ /(.*?)(m{1,2}?)(.*)$/; # matches,
1158 # $1 = 'The progra'
1159 # $2 = 'm'
1160 # $3 = 'ming republic of Perl'
1161 In this regexp, you might expect the first minimal quantifier ".*?" to
1163 match the empty string, because it is not constrained by a '^' anchor
1164 to match the beginning of the word. Principle 0 applies here, however.
1165 Because it is possible for the whole regexp to match at the start of
1166 the string, it will match at the start of the string. Thus the first
1167 quantifier has to match everything up to the first 'm'. The second
1168 minimal quantifier matches just one 'm' and the third quantifier
1169 matches the rest of the string.
1170 $x =~ /(.??)(m{1,2})(.*)$/; # matches,
1172 # $1 = 'a'
1173 # $2 = 'mm'
1174 # $3 = 'ing republic of Perl'
1175 Just as in the previous regexp, the first quantifier ".??" can match
1177 earliest at position 'a', so it does. The second quantifier is greedy,
1178 so it matches "mm", and the third matches the rest of the string.
1179 We can modify principle 3 above to take into account non-greedy
1181 quantifiers:
1182 • Principle 3: If there are two or more elements in a regexp, the
1184 leftmost greedy (non-greedy) quantifier, if any, will match as much
1185 (little) of the string as possible while still allowing the whole
1186 regexp to match. The next leftmost greedy (non-greedy) quantifier,
1187 if any, will try to match as much (little) of the string remaining
1188 available to it as possible, while still allowing the whole regexp
1189 to match. And so on, until all the regexp elements are satisfied.
1190 Just like alternation, quantifiers are also susceptible to
1192 backtracking. Here is a step-by-step analysis of the example
1193 $x = "the cat in the hat";
1195 $x =~ /^(.*)(at)(.*)$/; # matches,
1196 # $1 = 'the cat in the h'
1197 # $2 = 'at'
1198 # $3 = '' (0 matches)
1199 0. Start with the first letter in the string 't'.
1201 1. The first quantifier '.*' starts out by matching the whole string
1204 ""the cat in the hat"".
1205 2. 'a' in the regexp element 'at' doesn't match the end of the string.
1208 Backtrack one character.
1209 3. 'a' in the regexp element 'at' still doesn't match the last letter
1212 of the string 't', so backtrack one more character.
1213 4. Now we can match the 'a' and the 't'.
1216 5. Move on to the third element '.*'. Since we are at the end of the
1219 string and '.*' can match 0 times, assign it the empty string.
1220 6. We are done!
1223 Most of the time, all this moving forward and backtracking happens
1225 quickly and searching is fast. There are some pathological regexps,
1226 however, whose execution time exponentially grows with the size of the
1227 string. A typical structure that blows up in your face is of the form
1228 /(a|b+)*/;
1230 The problem is the nested indeterminate quantifiers. There are many
1232 different ways of partitioning a string of length n between the '+' and
1233 '*': one repetition with "b+" of length n, two repetitions with the
1234 first "b+" length k and the second with length n-k, m repetitions whose
1235 bits add up to length n, etc. In fact there are an exponential number
1236 of ways to partition a string as a function of its length. A regexp
1237 may get lucky and match early in the process, but if there is no match,
1238 Perl will try every possibility before giving up. So be careful with
1239 nested '*''s, "{n,m}"'s, and '+''s. The book Mastering Regular
1240 Expressions by Jeffrey Friedl gives a wonderful discussion of this and
1241 other efficiency issues.
1242 Possessive quantifiers
1244 Backtracking during the relentless search for a match may be a waste of
1245 time, particularly when the match is bound to fail. Consider the
1246 simple pattern
1247 /^\w+\s+\w+$/; # a word, spaces, a word
1249 Whenever this is applied to a string which doesn't quite meet the
1251 pattern's expectations such as "abc " or "abc def ", the regexp
1252 engine will backtrack, approximately once for each character in the
1253 string. But we know that there is no way around taking all of the
1254 initial word characters to match the first repetition, that all spaces
1255 must be eaten by the middle part, and the same goes for the second
1256 word.
1257 With the introduction of the possessive quantifiers in Perl 5.10, we
1259 have a way of instructing the regexp engine not to backtrack, with the
1260 usual quantifiers with a '+' appended to them. This makes them greedy
1261 as well as stingy; once they succeed they won't give anything back to
1262 permit another solution. They have the following meanings:
1263 • "a{n,m}+" means: match at least "n" times, not more than "m" times,
1265 as many times as possible, and don't give anything up. "a?+" is
1266 short for "a{0,1}+"
1267 • "a{n,}+" means: match at least "n" times, but as many times as
1269 possible, and don't give anything up. "a++" is short for "a{1,}+".
1270 • "a{,n}+" means: match as many times as possible up to at most "n"
1272 times, and don't give anything up. "a*+" is short for "a{0,}+".
1273 • "a{n}+" means: match exactly "n" times. It is just there for
1275 notational consistency.
1276 These possessive quantifiers represent a special case of a more general
1278 concept, the independent subexpression, see below.
1279 As an example where a possessive quantifier is suitable we consider
1281 matching a quoted string, as it appears in several programming
1282 languages. The backslash is used as an escape character that indicates
1283 that the next character is to be taken literally, as another character
1284 for the string. Therefore, after the opening quote, we expect a
1285 (possibly empty) sequence of alternatives: either some character except
1286 an unescaped quote or backslash or an escaped character.
1287 /"(?:[^"\\]++|\\.)*+"/;
1289 Building a regexp
1291 At this point, we have all the basic regexp concepts covered, so let's
1292 give a more involved example of a regular expression. We will build a
1293 regexp that matches numbers.
1294 The first task in building a regexp is to decide what we want to match
1296 and what we want to exclude. In our case, we want to match both
1297 integers and floating point numbers and we want to reject any string
1298 that isn't a number.
1299 The next task is to break the problem down into smaller problems that
1301 are easily converted into a regexp.
1302 The simplest case is integers. These consist of a sequence of digits,
1304 with an optional sign in front. The digits we can represent with "\d+"
1305 and the sign can be matched with "[+-]". Thus the integer regexp is
1306 /[+-]?\d+/; # matches integers
1308 A floating point number potentially has a sign, an integral part, a
1310 decimal point, a fractional part, and an exponent. One or more of
1311 these parts is optional, so we need to check out the different
1312 possibilities. Floating point numbers which are in proper form include
1313 123., 0.345, .34, -1e6, and 25.4E-72. As with integers, the sign out
1314 front is completely optional and can be matched by "[+-]?". We can see
1315 that if there is no exponent, floating point numbers must have a
1316 decimal point, otherwise they are integers. We might be tempted to
1317 model these with "\d*\.\d*", but this would also match just a single
1318 decimal point, which is not a number. So the three cases of floating
1319 point number without exponent are
1320 /[+-]?\d+\./; # 1., 321., etc.
1322 /[+-]?\.\d+/; # .1, .234, etc.
1323 /[+-]?\d+\.\d+/; # 1.0, 30.56, etc.
1324 These can be combined into a single regexp with a three-way
1326 alternation:
1327 /[+-]?(\d+\.\d+|\d+\.|\.\d+)/; # floating point, no exponent
1329 In this alternation, it is important to put '\d+\.\d+' before '\d+\.'.
1331 If '\d+\.' were first, the regexp would happily match that and ignore
1332 the fractional part of the number.
1333 Now consider floating point numbers with exponents. The key
1335 observation here is that both integers and numbers with decimal points
1336 are allowed in front of an exponent. Then exponents, like the overall
1337 sign, are independent of whether we are matching numbers with or
1338 without decimal points, and can be "decoupled" from the mantissa. The
1339 overall form of the regexp now becomes clear:
1340 /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1342 The exponent is an 'e' or 'E', followed by an integer. So the exponent
1344 regexp is
1345 /[eE][+-]?\d+/; # exponent
1347 Putting all the parts together, we get a regexp that matches numbers:
1349 /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/; # Ta da!
1351 Long regexps like this may impress your friends, but can be hard to
1353 decipher. In complex situations like this, the "/x" modifier for a
1354 match is invaluable. It allows one to put nearly arbitrary whitespace
1355 and comments into a regexp without affecting their meaning. Using it,
1356 we can rewrite our "extended" regexp in the more pleasing form
1357 /^
1359 [+-]? # first, match an optional sign
1360 ( # then match integers or f.p. mantissas:
1361 \d+\.\d+ # mantissa of the form a.b
1362 |\d+\. # mantissa of the form a.
1363 |\.\d+ # mantissa of the form .b
1364 |\d+ # integer of the form a
1365 )
1366 ( [eE] [+-]? \d+ )? # finally, optionally match an exponent
1367 $/x;
1368 If whitespace is mostly irrelevant, how does one include space
1370 characters in an extended regexp? The answer is to backslash it '\ ' or
1371 put it in a character class "[ ]". The same thing goes for pound
1372 signs: use "\#" or "[#]". For instance, Perl allows a space between
1373 the sign and the mantissa or integer, and we could add this to our
1374 regexp as follows:
1375 /^
1377 [+-]?\ * # first, match an optional sign *and space*
1378 ( # then match integers or f.p. mantissas:
1379 \d+\.\d+ # mantissa of the form a.b
1380 |\d+\. # mantissa of the form a.
1381 |\.\d+ # mantissa of the form .b
1382 |\d+ # integer of the form a
1383 )
1384 ( [eE] [+-]? \d+ )? # finally, optionally match an exponent
1385 $/x;
1386 In this form, it is easier to see a way to simplify the alternation.
1388 Alternatives 1, 2, and 4 all start with "\d+", so it could be factored
1389 out:
1390 /^
1392 [+-]?\ * # first, match an optional sign
1393 ( # then match integers or f.p. mantissas:
1394 \d+ # start out with a ...
1395 (
1396 \.\d* # mantissa of the form a.b or a.
1397 )? # ? takes care of integers of the form a
1398 |\.\d+ # mantissa of the form .b
1399 )
1400 ( [eE] [+-]? \d+ )? # finally, optionally match an exponent
1401 $/x;
1402 Starting in Perl v5.26, specifying "/xx" changes the square-bracketed
1404 portions of a pattern to ignore tabs and space characters unless they
1405 are escaped by preceding them with a backslash. So, we could write
1406 /^
1408 [ + - ]?\ * # first, match an optional sign
1409 ( # then match integers or f.p. mantissas:
1410 \d+ # start out with a ...
1411 (
1412 \.\d* # mantissa of the form a.b or a.
1413 )? # ? takes care of integers of the form a
1414 |\.\d+ # mantissa of the form .b
1415 )
1416 ( [ e E ] [ + - ]? \d+ )? # finally, optionally match an exponent
1417 $/xx;
1418 This doesn't really improve the legibility of this example, but it's
1420 available in case you want it. Squashing the pattern down to the
1421 compact form, we have
1422 /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1424 This is our final regexp. To recap, we built a regexp by
1426 • specifying the task in detail,
1428 • breaking down the problem into smaller parts,
1430 • translating the small parts into regexps,
1432 • combining the regexps,
1434 • and optimizing the final combined regexp.
1436 These are also the typical steps involved in writing a computer
1438 program. This makes perfect sense, because regular expressions are
1439 essentially programs written in a little computer language that
1440 specifies patterns.
1441 Using regular expressions in Perl
1443 The last topic of Part 1 briefly covers how regexps are used in Perl
1444 programs. Where do they fit into Perl syntax?
1445 We have already introduced the matching operator in its default
1447 "/regexp/" and arbitrary delimiter "m!regexp!" forms. We have used the
1448 binding operator "=~" and its negation "!~" to test for string matches.
1449 Associated with the matching operator, we have discussed the single
1450 line "/s", multi-line "/m", case-insensitive "/i" and extended "/x"
1451 modifiers. There are a few more things you might want to know about
1452 matching operators.
1453 Prohibiting substitution
1455 If you change $pattern after the first substitution happens, Perl will
1457 ignore it. If you don't want any substitutions at all, use the special
1458 delimiter "m''":
1459 @pattern = ('Seuss');
1461 while (<>) {
1462 print if m'@pattern'; # matches literal '@pattern', not 'Seuss'
1463 }
1464 Similar to strings, "m''" acts like apostrophes on a regexp; all other
1466 'm' delimiters act like quotes. If the regexp evaluates to the empty
1467 string, the regexp in the last successful match is used instead. So we
1468 have
1469 "dog" =~ /d/; # 'd' matches
1471 "dogbert" =~ //; # this matches the 'd' regexp used before
1472 Global matching
1474 The final two modifiers we will discuss here, "/g" and "/c", concern
1476 multiple matches. The modifier "/g" stands for global matching and
1477 allows the matching operator to match within a string as many times as
1478 possible. In scalar context, successive invocations against a string
1479 will have "/g" jump from match to match, keeping track of position in
1480 the string as it goes along. You can get or set the position with the
1481 "pos()" function.
1482 The use of "/g" is shown in the following example. Suppose we have a
1484 string that consists of words separated by spaces. If we know how many
1485 words there are in advance, we could extract the words using groupings:
1486 $x = "cat dog house"; # 3 words
1488 $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1489 # $1 = 'cat'
1490 # $2 = 'dog'
1491 # $3 = 'house'
1492 But what if we had an indeterminate number of words? This is the sort
1494 of task "/g" was made for. To extract all words, form the simple
1495 regexp "(\w+)" and loop over all matches with "/(\w+)/g":
1496 while ($x =~ /(\w+)/g) {
1498 print "Word is $1, ends at position ", pos $x, "\n";
1499 }
1500 prints
1502 Word is cat, ends at position 3
1504 Word is dog, ends at position 7
1505 Word is house, ends at position 13
1506 A failed match or changing the target string resets the position. If
1508 you don't want the position reset after failure to match, add the "/c",
1509 as in "/regexp/gc". The current position in the string is associated
1510 with the string, not the regexp. This means that different strings
1511 have different positions and their respective positions can be set or
1512 read independently.
1513 In list context, "/g" returns a list of matched groupings, or if there
1515 are no groupings, a list of matches to the whole regexp. So if we
1516 wanted just the words, we could use
1517 @words = ($x =~ /(\w+)/g); # matches,
1519 # $words[0] = 'cat'
1520 # $words[1] = 'dog'
1521 # $words[2] = 'house'
1522 Closely associated with the "/g" modifier is the "\G" anchor. The "\G"
1524 anchor matches at the point where the previous "/g" match left off.
1525 "\G" allows us to easily do context-sensitive matching:
1526 $metric = 1; # use metric units
1528 ...
1529 $x = <FILE>; # read in measurement
1530 $x =~ /^([+-]?\d+)\s*/g; # get magnitude
1531 $weight = $1;
1532 if ($metric) { # error checking
1533 print "Units error!" unless $x =~ /\Gkg\./g;
1534 }
1535 else {
1536 print "Units error!" unless $x =~ /\Glbs\./g;
1537 }
1538 $x =~ /\G\s+(widget|sprocket)/g; # continue processing
1539 The combination of "/g" and "\G" allows us to process the string a bit
1541 at a time and use arbitrary Perl logic to decide what to do next.
1542 Currently, the "\G" anchor is only fully supported when used to anchor
1543 to the start of the pattern.
1544 "\G" is also invaluable in processing fixed-length records with
1546 regexps. Suppose we have a snippet of coding region DNA, encoded as
1547 base pair letters "ATCGTTGAAT..." and we want to find all the stop
1548 codons "TGA". In a coding region, codons are 3-letter sequences, so we
1549 can think of the DNA snippet as a sequence of 3-letter records. The
1550 naive regexp
1551 # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1553 $dna = "ATCGTTGAATGCAAATGACATGAC";
1554 $dna =~ /TGA/;
1555 doesn't work; it may match a "TGA", but there is no guarantee that the
1557 match is aligned with codon boundaries, e.g., the substring "GTT GAA"
1558 gives a match. A better solution is
1559 while ($dna =~ /(\w\w\w)*?TGA/g) { # note the minimal *?
1561 print "Got a TGA stop codon at position ", pos $dna, "\n";
1562 }
1563 which prints
1565 Got a TGA stop codon at position 18
1567 Got a TGA stop codon at position 23
1568 Position 18 is good, but position 23 is bogus. What happened?
1570 The answer is that our regexp works well until we get past the last
1572 real match. Then the regexp will fail to match a synchronized "TGA"
1573 and start stepping ahead one character position at a time, not what we
1574 want. The solution is to use "\G" to anchor the match to the codon
1575 alignment:
1576 while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1578 print "Got a TGA stop codon at position ", pos $dna, "\n";
1579 }
1580 This prints
1582 Got a TGA stop codon at position 18
1584 which is the correct answer. This example illustrates that it is
1586 important not only to match what is desired, but to reject what is not
1587 desired.
1588 (There are other regexp modifiers that are available, such as "/o", but
1590 their specialized uses are beyond the scope of this introduction. )
1591 Search and replace
1593 Regular expressions also play a big role in search and replace
1595 operations in Perl. Search and replace is accomplished with the "s///"
1596 operator. The general form is "s/regexp/replacement/modifiers", with
1597 everything we know about regexps and modifiers applying in this case as
1598 well. The replacement is a Perl double-quoted string that replaces in
1599 the string whatever is matched with the "regexp". The operator "=~" is
1600 also used here to associate a string with "s///". If matching against
1601 $_, the "$_ =~" can be dropped. If there is a match, "s///" returns
1602 the number of substitutions made; otherwise it returns false. Here are
1603 a few examples:
1604 $x = "Time to feed the cat!";
1606 $x =~ s/cat/hacker/; # $x contains "Time to feed the hacker!"
1607 if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1608 $more_insistent = 1;
1609 }
1610 $y = "'quoted words'";
1611 $y =~ s/^'(.*)'$/$1/; # strip single quotes,
1612 # $y contains "quoted words"
1613 In the last example, the whole string was matched, but only the part
1615 inside the single quotes was grouped. With the "s///" operator, the
1616 matched variables $1, $2, etc. are immediately available for use in the
1617 replacement expression, so we use $1 to replace the quoted string with
1618 just what was quoted. With the global modifier, "s///g" will search
1619 and replace all occurrences of the regexp in the string:
1620 $x = "I batted 4 for 4";
1622 $x =~ s/4/four/; # doesn't do it all:
1623 # $x contains "I batted four for 4"
1624 $x = "I batted 4 for 4";
1625 $x =~ s/4/four/g; # does it all:
1626 # $x contains "I batted four for four"
1627 If you prefer "regex" over "regexp" in this tutorial, you could use the
1629 following program to replace it:
1630 % cat > simple_replace
1632 #!/usr/bin/perl
1633 $regexp = shift;
1634 $replacement = shift;
1635 while (<>) {
1636 s/$regexp/$replacement/g;
1637 print;
1638 }
1639 ^D
1640 % simple_replace regexp regex perlretut.pod
1642 In "simple_replace" we used the "s///g" modifier to replace all
1644 occurrences of the regexp on each line. (Even though the regular
1645 expression appears in a loop, Perl is smart enough to compile it only
1646 once.) As with "simple_grep", both the "print" and the
1647 "s/$regexp/$replacement/g" use $_ implicitly.
1648 If you don't want "s///" to change your original variable you can use
1650 the non-destructive substitute modifier, "s///r". This changes the
1651 behavior so that "s///r" returns the final substituted string (instead
1652 of the number of substitutions):
1653 $x = "I like dogs.";
1655 $y = $x =~ s/dogs/cats/r;
1656 print "$x $y\n";
1657 That example will print "I like dogs. I like cats". Notice the original
1659 $x variable has not been affected. The overall result of the
1660 substitution is instead stored in $y. If the substitution doesn't
1661 affect anything then the original string is returned:
1662 $x = "I like dogs.";
1664 $y = $x =~ s/elephants/cougars/r;
1665 print "$x $y\n"; # prints "I like dogs. I like dogs."
1666 One other interesting thing that the "s///r" flag allows is chaining
1668 substitutions:
1669 $x = "Cats are great.";
1671 print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~
1672 s/Frogs/Hedgehogs/r, "\n";
1673 # prints "Hedgehogs are great."
1674 A modifier available specifically to search and replace is the "s///e"
1676 evaluation modifier. "s///e" treats the replacement text as Perl code,
1677 rather than a double-quoted string. The value that the code returns is
1678 substituted for the matched substring. "s///e" is useful if you need
1679 to do a bit of computation in the process of replacing text. This
1680 example counts character frequencies in a line:
1681 $x = "Bill the cat";
1683 $x =~ s/(.)/$chars{$1}++;$1/eg; # final $1 replaces char with itself
1684 print "frequency of '$_' is $chars{$_}\n"
1685 foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1686 This prints
1688 frequency of ' ' is 2
1690 frequency of 't' is 2
1691 frequency of 'l' is 2
1692 frequency of 'B' is 1
1693 frequency of 'c' is 1
1694 frequency of 'e' is 1
1695 frequency of 'h' is 1
1696 frequency of 'i' is 1
1697 frequency of 'a' is 1
1698 As with the match "m//" operator, "s///" can use other delimiters, such
1700 as "s!!!" and "s{}{}", and even "s{}//". If single quotes are used
1701 "s'''", then the regexp and replacement are treated as single-quoted
1702 strings and there are no variable substitutions. "s///" in list
1703 context returns the same thing as in scalar context, i.e., the number
1704 of matches.
1705 The split function
1707 The "split()" function is another place where a regexp is used. "split
1709 /regexp/, string, limit" separates the "string" operand into a list of
1710 substrings and returns that list. The regexp must be designed to match
1711 whatever constitutes the separators for the desired substrings. The
1712 "limit", if present, constrains splitting into no more than "limit"
1713 number of strings. For example, to split a string into words, use
1714 $x = "Calvin and Hobbes";
1716 @words = split /\s+/, $x; # $word[0] = 'Calvin'
1717 # $word[1] = 'and'
1718 # $word[2] = 'Hobbes'
1719 If the empty regexp "//" is used, the regexp always matches and the
1721 string is split into individual characters. If the regexp has
1722 groupings, then the resulting list contains the matched substrings from
1723 the groupings as well. For instance,
1724 $x = "/usr/bin/perl";
1726 @dirs = split m!/!, $x; # $dirs[0] = ''
1727 # $dirs[1] = 'usr'
1728 # $dirs[2] = 'bin'
1729 # $dirs[3] = 'perl'
1730 @parts = split m!(/)!, $x; # $parts[0] = ''
1731 # $parts[1] = '/'
1732 # $parts[2] = 'usr'
1733 # $parts[3] = '/'
1734 # $parts[4] = 'bin'
1735 # $parts[5] = '/'
1736 # $parts[6] = 'perl'
1737 Since the first character of $x matched the regexp, "split" prepended
1739 an empty initial element to the list.
1740 If you have read this far, congratulations! You now have all the basic
1742 tools needed to use regular expressions to solve a wide range of text
1743 processing problems. If this is your first time through the tutorial,
1744 why not stop here and play around with regexps a while.... Part 2
1745 concerns the more esoteric aspects of regular expressions and those
1746 concepts certainly aren't needed right at the start.
1747
1749 OK, you know the basics of regexps and you want to know more. If
1750 matching regular expressions is analogous to a walk in the woods, then
1751 the tools discussed in Part 1 are analogous to topo maps and a compass,
1752 basic tools we use all the time. Most of the tools in part 2 are
1753 analogous to flare guns and satellite phones. They aren't used too
1754 often on a hike, but when we are stuck, they can be invaluable.
1755 What follows are the more advanced, less used, or sometimes esoteric
1757 capabilities of Perl regexps. In Part 2, we will assume you are
1758 comfortable with the basics and concentrate on the advanced features.
1759 More on characters, strings, and character classes
1761 There are a number of escape sequences and character classes that we
1762 haven't covered yet.
1763 There are several escape sequences that convert characters or strings
1765 between upper and lower case, and they are also available within
1766 patterns. "\l" and "\u" convert the next character to lower or upper
1767 case, respectively:
1768 $x = "perl";
1770 $string =~ /\u$x/; # matches 'Perl' in $string
1771 $x = "M(rs?|s)\\."; # note the double backslash
1772 $string =~ /\l$x/; # matches 'mr.', 'mrs.', and 'ms.',
1773 A "\L" or "\U" indicates a lasting conversion of case, until terminated
1775 by "\E" or thrown over by another "\U" or "\L":
1776 $x = "This word is in lower case:\L SHOUT\E";
1778 $x =~ /shout/; # matches
1779 $x = "I STILL KEYPUNCH CARDS FOR MY 360";
1780 $x =~ /\Ukeypunch/; # matches punch card string
1781 If there is no "\E", case is converted until the end of the string. The
1783 regexps "\L\u$word" or "\u\L$word" convert the first character of $word
1784 to uppercase and the rest of the characters to lowercase. (Beyond
1785 ASCII characters, it gets somewhat more complicated; "\u" actually
1786 performs titlecase mapping, which for most characters is the same as
1787 uppercase, but not for all; see
1788 <https://unicode.org/faq/casemap_charprop.html#4>.)
1789 Control characters can be escaped with "\c", so that a control-Z
1791 character would be matched with "\cZ". The escape sequence "\Q"..."\E"
1792 quotes, or protects most non-alphabetic characters. For instance,
1793 $x = "\QThat !^*&%~& cat!";
1795 $x =~ /\Q!^*&%~&\E/; # check for rough language
1796 It does not protect '$' or '@', so that variables can still be
1798 substituted.
1799 "\Q", "\L", "\l", "\U", "\u" and "\E" are actually part of double-
1801 quotish syntax, and not part of regexp syntax proper. They will work
1802 if they appear in a regular expression embedded directly in a program,
1803 but not when contained in a string that is interpolated in a pattern.
1804 Perl regexps can handle more than just the standard ASCII character
1806 set. Perl supports Unicode, a standard for representing the alphabets
1807 from virtually all of the world's written languages, and a host of
1808 symbols. Perl's text strings are Unicode strings, so they can contain
1809 characters with a value (codepoint or character number) higher than
1810 255.
1811 What does this mean for regexps? Well, regexp users don't need to know
1813 much about Perl's internal representation of strings. But they do need
1814 to know 1) how to represent Unicode characters in a regexp and 2) that
1815 a matching operation will treat the string to be searched as a sequence
1816 of characters, not bytes. The answer to 1) is that Unicode characters
1817 greater than "chr(255)" are represented using the "\x{hex}" notation,
1818 because "\x"XY (without curly braces and XY are two hex digits) doesn't
1819 go further than 255. (Starting in Perl 5.14, if you're an octal fan,
1820 you can also use "\o{oct}".)
1821 /\x{263a}/; # match a Unicode smiley face :)
1823 /\x{ 263a }/; # Same
1824 NOTE: In Perl 5.6.0 it used to be that one needed to say "use utf8" to
1826 use any Unicode features. This is no longer the case: for almost all
1827 Unicode processing, the explicit "utf8" pragma is not needed. (The
1828 only case where it matters is if your Perl script is in Unicode and
1829 encoded in UTF-8, then an explicit "use utf8" is needed.)
1830 Figuring out the hexadecimal sequence of a Unicode character you want
1832 or deciphering someone else's hexadecimal Unicode regexp is about as
1833 much fun as programming in machine code. So another way to specify
1834 Unicode characters is to use the named character escape sequence
1835 "\N{name}". name is a name for the Unicode character, as specified in
1836 the Unicode standard. For instance, if we wanted to represent or match
1837 the astrological sign for the planet Mercury, we could use
1838 $x = "abc\N{MERCURY}def";
1840 $x =~ /\N{MERCURY}/; # matches
1841 $x =~ /\N{ MERCURY }/; # Also matches
1842 One can also use "short" names:
1844 print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1846 print "\N{greek:Sigma} is an upper-case sigma.\n";
1847 You can also restrict names to a certain alphabet by specifying the
1849 charnames pragma:
1850 use charnames qw(greek);
1852 print "\N{sigma} is Greek sigma\n";
1853 An index of character names is available on-line from the Unicode
1855 Consortium, <https://www.unicode.org/charts/charindex.html>;
1856 explanatory material with links to other resources at
1857 <https://www.unicode.org/standard/where>.
1858 Starting in Perl v5.32, an alternative to "\N{...}" for full names is
1860 available, and that is to say
1861 /\p{Name=greek small letter sigma}/
1863 The casing of the character name is irrelevant when used in "\p{}", as
1865 are most spaces, underscores and hyphens. (A few outlier characters
1866 cause problems with ignoring all of them always. The details (which
1867 you can look up when you get more proficient, and if ever needed) are
1868 in <https://www.unicode.org/reports/tr44/tr44-24.html#UAX44-LM2>).
1869 The answer to requirement 2) is that a regexp (mostly) uses Unicode
1871 characters. The "mostly" is for messy backward compatibility reasons,
1872 but starting in Perl 5.14, any regexp compiled in the scope of a "use
1873 feature 'unicode_strings'" (which is automatically turned on within the
1874 scope of a "use v5.12" or higher) will turn that "mostly" into
1875 "always". If you want to handle Unicode properly, you should ensure
1876 that 'unicode_strings' is turned on. Internally, this is encoded to
1877 bytes using either UTF-8 or a native 8 bit encoding, depending on the
1878 history of the string, but conceptually it is a sequence of characters,
1879 not bytes. See perlunitut for a tutorial about that.
1880 Let us now discuss Unicode character classes, most usually called
1882 "character properties". These are represented by the "\p{name}" escape
1883 sequence. The negation of this is "\P{name}". For example, to match
1884 lower and uppercase characters,
1885 $x = "BOB";
1887 $x =~ /^\p{IsUpper}/; # matches, uppercase char class
1888 $x =~ /^\P{IsUpper}/; # doesn't match, char class sans uppercase
1889 $x =~ /^\p{IsLower}/; # doesn't match, lowercase char class
1890 $x =~ /^\P{IsLower}/; # matches, char class sans lowercase
1891 (The ""Is"" is optional.)
1893 There are many, many Unicode character properties. For the full list
1895 see perluniprops. Most of them have synonyms with shorter names, also
1896 listed there. Some synonyms are a single character. For these, you
1897 can drop the braces. For instance, "\pM" is the same thing as
1898 "\p{Mark}", meaning things like accent marks.
1899 The Unicode "\p{Script}" and "\p{Script_Extensions}" properties are
1901 used to categorize every Unicode character into the language script it
1902 is written in. For example, English, French, and a bunch of other
1903 European languages are written in the Latin script. But there is also
1904 the Greek script, the Thai script, the Katakana script, etc. ("Script"
1905 is an older, less advanced, form of "Script_Extensions", retained only
1906 for backwards compatibility.) You can test whether a character is in a
1907 particular script with, for example "\p{Latin}", "\p{Greek}", or
1908 "\p{Katakana}". To test if it isn't in the Balinese script, you would
1909 use "\P{Balinese}". (These all use "Script_Extensions" under the hood,
1910 as that gives better results.)
1911 What we have described so far is the single form of the "\p{...}"
1913 character classes. There is also a compound form which you may run
1914 into. These look like "\p{name=value}" or "\p{name:value}" (the equals
1915 sign and colon can be used interchangeably). These are more general
1916 than the single form, and in fact most of the single forms are just
1917 Perl-defined shortcuts for common compound forms. For example, the
1918 script examples in the previous paragraph could be written equivalently
1919 as "\p{Script_Extensions=Latin}", "\p{Script_Extensions:Greek}",
1920 "\p{script_extensions=katakana}", and "\P{script_extensions=balinese}"
1921 (case is irrelevant between the "{}" braces). You may never have to
1922 use the compound forms, but sometimes it is necessary, and their use
1923 can make your code easier to understand.
1924 "\X" is an abbreviation for a character class that comprises a Unicode
1926 extended grapheme cluster. This represents a "logical character": what
1927 appears to be a single character, but may be represented internally by
1928 more than one. As an example, using the Unicode full names, e.g.,
1929 "A + COMBINING RING" is a grapheme cluster with base character "A" and
1930 combining character "COMBINING RING, which translates in Danish to "A"
1931 with the circle atop it, as in the word Aangstrom.
1932 For the full and latest information about Unicode see the latest
1934 Unicode standard, or the Unicode Consortium's website
1935 <https://www.unicode.org>
1936 As if all those classes weren't enough, Perl also defines POSIX-style
1938 character classes. These have the form "[:name:]", with name the name
1939 of the POSIX class. The POSIX classes are "alpha", "alnum", "ascii",
1940 "cntrl", "digit", "graph", "lower", "print", "punct", "space", "upper",
1941 and "xdigit", and two extensions, "word" (a Perl extension to match
1942 "\w"), and "blank" (a GNU extension). The "/a" modifier restricts
1943 these to matching just in the ASCII range; otherwise they can match the
1944 same as their corresponding Perl Unicode classes: "[:upper:]" is the
1945 same as "\p{IsUpper}", etc. (There are some exceptions and gotchas
1946 with this; see perlrecharclass for a full discussion.) The "[:digit:]",
1947 "[:word:]", and "[:space:]" correspond to the familiar "\d", "\w", and
1948 "\s" character classes. To negate a POSIX class, put a '^' in front of
1949 the name, so that, e.g., "[:^digit:]" corresponds to "\D" and, under
1950 Unicode, "\P{IsDigit}". The Unicode and POSIX character classes can be
1951 used just like "\d", with the exception that POSIX character classes
1952 can only be used inside of a character class:
1953 /\s+[abc[:digit:]xyz]\s*/; # match a,b,c,x,y,z, or a digit
1955 /^=item\s[[:digit:]]/; # match '=item',
1956 # followed by a space and a digit
1957 /\s+[abc\p{IsDigit}xyz]\s+/; # match a,b,c,x,y,z, or a digit
1958 /^=item\s\p{IsDigit}/; # match '=item',
1959 # followed by a space and a digit
1960 Whew! That is all the rest of the characters and character classes.
1962 Compiling and saving regular expressions
1964 In Part 1 we mentioned that Perl compiles a regexp into a compact
1965 sequence of opcodes. Thus, a compiled regexp is a data structure that
1966 can be stored once and used again and again. The regexp quote "qr//"
1967 does exactly that: "qr/string/" compiles the "string" as a regexp and
1968 transforms the result into a form that can be assigned to a variable:
1969 $reg = qr/foo+bar?/; # reg contains a compiled regexp
1971 Then $reg can be used as a regexp:
1973 $x = "fooooba";
1975 $x =~ $reg; # matches, just like /foo+bar?/
1976 $x =~ /$reg/; # same thing, alternate form
1977 $reg can also be interpolated into a larger regexp:
1979 $x =~ /(abc)?$reg/; # still matches
1981 As with the matching operator, the regexp quote can use different
1983 delimiters, e.g., "qr!!", "qr{}" or "qr~~". Apostrophes as delimiters
1984 ("qr''") inhibit any interpolation.
1985 Pre-compiled regexps are useful for creating dynamic matches that don't
1987 need to be recompiled each time they are encountered. Using pre-
1988 compiled regexps, we write a "grep_step" program which greps for a
1989 sequence of patterns, advancing to the next pattern as soon as one has
1990 been satisfied.
1991 % cat > grep_step
1993 #!/usr/bin/perl
1994 # grep_step - match <number> regexps, one after the other
1995 # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
1996 $number = shift;
1998 $regexp[$_] = shift foreach (0..$number-1);
1999 @compiled = map qr/$_/, @regexp;
2000 while ($line = <>) {
2001 if ($line =~ /$compiled[0]/) {
2002 print $line;
2003 shift @compiled;
2004 last unless @compiled;
2005 }
2006 }
2007 ^D
2008 % grep_step 3 shift print last grep_step
2010 $number = shift;
2011 print $line;
2012 last unless @compiled;
2013 Storing pre-compiled regexps in an array @compiled allows us to simply
2015 loop through the regexps without any recompilation, thus gaining
2016 flexibility without sacrificing speed.
2017 Composing regular expressions at runtime
2019 Backtracking is more efficient than repeated tries with different
2020 regular expressions. If there are several regular expressions and a
2021 match with any of them is acceptable, then it is possible to combine
2022 them into a set of alternatives. If the individual expressions are
2023 input data, this can be done by programming a join operation. We'll
2024 exploit this idea in an improved version of the "simple_grep" program:
2025 a program that matches multiple patterns:
2026 % cat > multi_grep
2028 #!/usr/bin/perl
2029 # multi_grep - match any of <number> regexps
2030 # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2031 $number = shift;
2033 $regexp[$_] = shift foreach (0..$number-1);
2034 $pattern = join '|', @regexp;
2035 while ($line = <>) {
2037 print $line if $line =~ /$pattern/;
2038 }
2039 ^D
2040 % multi_grep 2 shift for multi_grep
2042 $number = shift;
2043 $regexp[$_] = shift foreach (0..$number-1);
2044 Sometimes it is advantageous to construct a pattern from the input that
2046 is to be analyzed and use the permissible values on the left hand side
2047 of the matching operations. As an example for this somewhat
2048 paradoxical situation, let's assume that our input contains a command
2049 verb which should match one out of a set of available command verbs,
2050 with the additional twist that commands may be abbreviated as long as
2051 the given string is unique. The program below demonstrates the basic
2052 algorithm.
2053 % cat > keymatch
2055 #!/usr/bin/perl
2056 $kwds = 'copy compare list print';
2057 while( $cmd = <> ){
2058 $cmd =~ s/^\s+|\s+$//g; # trim leading and trailing spaces
2059 if( ( @matches = $kwds =~ /\b$cmd\w*/g ) == 1 ){
2060 print "command: '@matches'\n";
2061 } elsif( @matches == 0 ){
2062 print "no such command: '$cmd'\n";
2063 } else {
2064 print "not unique: '$cmd' (could be one of: @matches)\n";
2065 }
2066 }
2067 ^D
2068 % keymatch
2070 li
2071 command: 'list'
2072 co
2073 not unique: 'co' (could be one of: copy compare)
2074 printer
2075 no such command: 'printer'
2076 Rather than trying to match the input against the keywords, we match
2078 the combined set of keywords against the input. The pattern matching
2079 operation "$kwds =~ /\b($cmd\w*)/g" does several things at the same
2080 time. It makes sure that the given command begins where a keyword
2081 begins ("\b"). It tolerates abbreviations due to the added "\w*". It
2082 tells us the number of matches ("scalar @matches") and all the keywords
2083 that were actually matched. You could hardly ask for more.
2084 Embedding comments and modifiers in a regular expression
2086 Starting with this section, we will be discussing Perl's set of
2087 extended patterns. These are extensions to the traditional regular
2088 expression syntax that provide powerful new tools for pattern matching.
2089 We have already seen extensions in the form of the minimal matching
2090 constructs "??", "*?", "+?", "{n,m}?", "{n,}?", and "{,n}?". Most of
2091 the extensions below have the form "(?char...)", where the "char" is a
2092 character that determines the type of extension.
2093 The first extension is an embedded comment "(?#text)". This embeds a
2095 comment into the regular expression without affecting its meaning. The
2096 comment should not have any closing parentheses in the text. An
2097 example is
2098 /(?# Match an integer:)[+-]?\d+/;
2100 This style of commenting has been largely superseded by the raw,
2102 freeform commenting that is allowed with the "/x" modifier.
2103 Most modifiers, such as "/i", "/m", "/s" and "/x" (or any combination
2105 thereof) can also be embedded in a regexp using "(?i)", "(?m)", "(?s)",
2106 and "(?x)". For instance,
2107 /(?i)yes/; # match 'yes' case insensitively
2109 /yes/i; # same thing
2110 /(?x)( # freeform version of an integer regexp
2111 [+-]? # match an optional sign
2112 \d+ # match a sequence of digits
2113 )
2114 /x;
2115 Embedded modifiers can have two important advantages over the usual
2117 modifiers. Embedded modifiers allow a custom set of modifiers for each
2118 regexp pattern. This is great for matching an array of regexps that
2119 must have different modifiers:
2120 $pattern[0] = '(?i)doctor';
2122 $pattern[1] = 'Johnson';
2123 ...
2124 while (<>) {
2125 foreach $patt (@pattern) {
2126 print if /$patt/;
2127 }
2128 }
2129 The second advantage is that embedded modifiers (except "/p", which
2131 modifies the entire regexp) only affect the regexp inside the group the
2132 embedded modifier is contained in. So grouping can be used to localize
2133 the modifier's effects:
2134 /Answer: ((?i)yes)/; # matches 'Answer: yes', 'Answer: YES', etc.
2136 Embedded modifiers can also turn off any modifiers already present by
2138 using, e.g., "(?-i)". Modifiers can also be combined into a single
2139 expression, e.g., "(?s-i)" turns on single line mode and turns off case
2140 insensitivity.
2141 Embedded modifiers may also be added to a non-capturing grouping.
2143 "(?i-m:regexp)" is a non-capturing grouping that matches "regexp" case
2144 insensitively and turns off multi-line mode.
2145 Looking ahead and looking behind
2147 This section concerns the lookahead and lookbehind assertions. First,
2148 a little background.
2149 In Perl regular expressions, most regexp elements "eat up" a certain
2151 amount of string when they match. For instance, the regexp element
2152 "[abc]" eats up one character of the string when it matches, in the
2153 sense that Perl moves to the next character position in the string
2154 after the match. There are some elements, however, that don't eat up
2155 characters (advance the character position) if they match. The
2156 examples we have seen so far are the anchors. The anchor '^' matches
2157 the beginning of the line, but doesn't eat any characters. Similarly,
2158 the word boundary anchor "\b" matches wherever a character matching
2159 "\w" is next to a character that doesn't, but it doesn't eat up any
2160 characters itself. Anchors are examples of zero-width assertions:
2161 zero-width, because they consume no characters, and assertions, because
2162 they test some property of the string. In the context of our walk in
2163 the woods analogy to regexp matching, most regexp elements move us
2164 along a trail, but anchors have us stop a moment and check our
2165 surroundings. If the local environment checks out, we can proceed
2166 forward. But if the local environment doesn't satisfy us, we must
2167 backtrack.
2168 Checking the environment entails either looking ahead on the trail,
2170 looking behind, or both. '^' looks behind, to see that there are no
2171 characters before. '$' looks ahead, to see that there are no
2172 characters after. "\b" looks both ahead and behind, to see if the
2173 characters on either side differ in their "word-ness".
2174 The lookahead and lookbehind assertions are generalizations of the
2176 anchor concept. Lookahead and lookbehind are zero-width assertions
2177 that let us specify which characters we want to test for. The
2178 lookahead assertion is denoted by "(?=regexp)" or (starting in 5.32,
2179 experimentally in 5.28) "(*pla:regexp)" or
2180 "(*positive_lookahead:regexp)"; and the lookbehind assertion is denoted
2181 by "(?<=fixed-regexp)" or (starting in 5.32, experimentally in 5.28)
2182 "(*plb:fixed-regexp)" or "(*positive_lookbehind:fixed-regexp)". Some
2183 examples are
2184 $x = "I catch the housecat 'Tom-cat' with catnip";
2186 $x =~ /cat(*pla:\s)/; # matches 'cat' in 'housecat'
2187 @catwords = ($x =~ /(?<=\s)cat\w+/g); # matches,
2188 # $catwords[0] = 'catch'
2189 # $catwords[1] = 'catnip'
2190 $x =~ /\bcat\b/; # matches 'cat' in 'Tom-cat'
2191 $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2192 # middle of $x
2193 Note that the parentheses in these are non-capturing, since these are
2195 zero-width assertions. Thus in the second regexp, the substrings
2196 captured are those of the whole regexp itself. Lookahead can match
2197 arbitrary regexps, but lookbehind prior to 5.30 "(?<=fixed-regexp)"
2198 only works for regexps of fixed width, i.e., a fixed number of
2199 characters long. Thus "(?<=(ab|bc))" is fine, but "(?<=(ab)*)" prior
2200 to 5.30 is not.
2201 The negated versions of the lookahead and lookbehind assertions are
2203 denoted by "(?!regexp)" and "(?<!fixed-regexp)" respectively. Or,
2204 starting in 5.32 (experimentally in 5.28), "(*nla:regexp)",
2205 "(*negative_lookahead:regexp)", "(*nlb:regexp)", or
2206 "(*negative_lookbehind:regexp)". They evaluate true if the regexps do
2207 not match:
2208 $x = "foobar";
2210 $x =~ /foo(?!bar)/; # doesn't match, 'bar' follows 'foo'
2211 $x =~ /foo(?!baz)/; # matches, 'baz' doesn't follow 'foo'
2212 $x =~ /(?<!\s)foo/; # matches, there is no \s before 'foo'
2213 Here is an example where a string containing blank-separated words,
2215 numbers and single dashes is to be split into its components. Using
2216 "/\s+/" alone won't work, because spaces are not required between
2217 dashes, or a word or a dash. Additional places for a split are
2218 established by looking ahead and behind:
2219 $str = "one two - --6-8";
2221 @toks = split / \s+ # a run of spaces
2222 | (?<=\S) (?=-) # any non-space followed by '-'
2223 | (?<=-) (?=\S) # a '-' followed by any non-space
2224 /x, $str; # @toks = qw(one two - - - 6 - 8)
2225 Using independent subexpressions to prevent backtracking
2227 Independent subexpressions (or atomic subexpressions) are regular
2228 expressions, in the context of a larger regular expression, that
2229 function independently of the larger regular expression. That is, they
2230 consume as much or as little of the string as they wish without regard
2231 for the ability of the larger regexp to match. Independent
2232 subexpressions are represented by "(?>regexp)" or (starting in 5.32,
2233 experimentally in 5.28) "(*atomic:regexp)". We can illustrate their
2234 behavior by first considering an ordinary regexp:
2235 $x = "ab";
2237 $x =~ /a*ab/; # matches
2238 This obviously matches, but in the process of matching, the
2240 subexpression "a*" first grabbed the 'a'. Doing so, however, wouldn't
2241 allow the whole regexp to match, so after backtracking, "a*" eventually
2242 gave back the 'a' and matched the empty string. Here, what "a*"
2243 matched was dependent on what the rest of the regexp matched.
2244 Contrast that with an independent subexpression:
2246 $x =~ /(?>a*)ab/; # doesn't match!
2248 The independent subexpression "(?>a*)" doesn't care about the rest of
2250 the regexp, so it sees an 'a' and grabs it. Then the rest of the
2251 regexp "ab" cannot match. Because "(?>a*)" is independent, there is no
2252 backtracking and the independent subexpression does not give up its
2253 'a'. Thus the match of the regexp as a whole fails. A similar
2254 behavior occurs with completely independent regexps:
2255 $x = "ab";
2257 $x =~ /a*/g; # matches, eats an 'a'
2258 $x =~ /\Gab/g; # doesn't match, no 'a' available
2259 Here "/g" and "\G" create a "tag team" handoff of the string from one
2261 regexp to the other. Regexps with an independent subexpression are
2262 much like this, with a handoff of the string to the independent
2263 subexpression, and a handoff of the string back to the enclosing
2264 regexp.
2265 The ability of an independent subexpression to prevent backtracking can
2267 be quite useful. Suppose we want to match a non-empty string enclosed
2268 in parentheses up to two levels deep. Then the following regexp
2269 matches:
2270 $x = "abc(de(fg)h"; # unbalanced parentheses
2272 $x =~ /\( ( [ ^ () ]+ | \( [ ^ () ]* \) )+ \)/xx;
2273 The regexp matches an open parenthesis, one or more copies of an
2275 alternation, and a close parenthesis. The alternation is two-way, with
2276 the first alternative "[^()]+" matching a substring with no parentheses
2277 and the second alternative "\([^()]*\)" matching a substring delimited
2278 by parentheses. The problem with this regexp is that it is
2279 pathological: it has nested indeterminate quantifiers of the form
2280 "(a+|b)+". We discussed in Part 1 how nested quantifiers like this
2281 could take an exponentially long time to execute if no match were
2282 possible. To prevent the exponential blowup, we need to prevent
2283 useless backtracking at some point. This can be done by enclosing the
2284 inner quantifier as an independent subexpression:
2285 $x =~ /\( ( (?> [ ^ () ]+ ) | \([ ^ () ]* \) )+ \)/xx;
2287 Here, "(?>[^()]+)" breaks the degeneracy of string partitioning by
2289 gobbling up as much of the string as possible and keeping it. Then
2290 match failures fail much more quickly.
2291 Conditional expressions
2293 A conditional expression is a form of if-then-else statement that
2294 allows one to choose which patterns are to be matched, based on some
2295 condition. There are two types of conditional expression:
2296 "(?(condition)yes-regexp)" and "(?(condition)yes-regexp|no-regexp)".
2297 "(?(condition)yes-regexp)" is like an 'if () {}' statement in Perl. If
2298 the condition is true, the yes-regexp will be matched. If the
2299 condition is false, the yes-regexp will be skipped and Perl will move
2300 onto the next regexp element. The second form is like an
2301 'if () {} else {}' statement in Perl. If the condition is true, the
2302 yes-regexp will be matched, otherwise the no-regexp will be matched.
2303 The condition can have several forms. The first form is simply an
2305 integer in parentheses "(integer)". It is true if the corresponding
2306 backreference "\integer" matched earlier in the regexp. The same thing
2307 can be done with a name associated with a capture group, written as
2308 "(<name>)" or "('name')". The second form is a bare zero-width
2309 assertion "(?...)", either a lookahead, a lookbehind, or a code
2310 assertion (discussed in the next section). The third set of forms
2311 provides tests that return true if the expression is executed within a
2312 recursion ("(R)") or is being called from some capturing group,
2313 referenced either by number ("(R1)", "(R2)",...) or by name
2314 ("(R&name)").
2315 The integer or name form of the "condition" allows us to choose, with
2317 more flexibility, what to match based on what matched earlier in the
2318 regexp. This searches for words of the form "$x$x" or "$x$y$y$x":
2319 % simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
2321 beriberi
2322 coco
2323 couscous
2324 deed
2325 ...
2326 toot
2327 toto
2328 tutu
2329 The lookbehind "condition" allows, along with backreferences, an
2331 earlier part of the match to influence a later part of the match. For
2332 instance,
2333 /[ATGC]+(?(?<=AA)G|C)$/;
2335 matches a DNA sequence such that it either ends in "AAG", or some other
2337 base pair combination and 'C'. Note that the form is "(?(?<=AA)G|C)"
2338 and not "(?((?<=AA))G|C)"; for the lookahead, lookbehind or code
2339 assertions, the parentheses around the conditional are not needed.
2340 Defining named patterns
2342 Some regular expressions use identical subpatterns in several places.
2343 Starting with Perl 5.10, it is possible to define named subpatterns in
2344 a section of the pattern so that they can be called up by name anywhere
2345 in the pattern. This syntactic pattern for this definition group is
2346 "(?(DEFINE)(?<name>pattern)...)". An insertion of a named pattern is
2347 written as "(?&name)".
2348 The example below illustrates this feature using the pattern for
2350 floating point numbers that was presented earlier on. The three
2351 subpatterns that are used more than once are the optional sign, the
2352 digit sequence for an integer and the decimal fraction. The "DEFINE"
2353 group at the end of the pattern contains their definition. Notice that
2354 the decimal fraction pattern is the first place where we can reuse the
2355 integer pattern.
2356 /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
2358 (?: [eE](?&osg)(?&int) )?
2359 $
2360 (?(DEFINE)
2361 (?<osg>[-+]?) # optional sign
2362 (?<int>\d++) # integer
2363 (?<dec>\.(?&int)) # decimal fraction
2364 )/x
2365 Recursive patterns
2367 This feature (introduced in Perl 5.10) significantly extends the power
2368 of Perl's pattern matching. By referring to some other capture group
2369 anywhere in the pattern with the construct "(?group-ref)", the pattern
2370 within the referenced group is used as an independent subpattern in
2371 place of the group reference itself. Because the group reference may
2372 be contained within the group it refers to, it is now possible to apply
2373 pattern matching to tasks that hitherto required a recursive parser.
2374 To illustrate this feature, we'll design a pattern that matches if a
2376 string contains a palindrome. (This is a word or a sentence that, while
2377 ignoring spaces, interpunctuation and case, reads the same backwards as
2378 forwards. We begin by observing that the empty string or a string
2379 containing just one word character is a palindrome. Otherwise it must
2380 have a word character up front and the same at its end, with another
2381 palindrome in between.
2382 /(?: (\w) (?...Here be a palindrome...) \g{ -1 } | \w? )/x
2384 Adding "\W*" at either end to eliminate what is to be ignored, we
2386 already have the full pattern:
2387 my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2389 for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2390 print "'$s' is a palindrome\n" if $s =~ /$pp/;
2391 }
2392 In "(?...)" both absolute and relative backreferences may be used. The
2394 entire pattern can be reinserted with "(?R)" or "(?0)". If you prefer
2395 to name your groups, you can use "(?&name)" to recurse into that group.
2396 A bit of magic: executing Perl code in a regular expression
2398 Normally, regexps are a part of Perl expressions. Code evaluation
2399 expressions turn that around by allowing arbitrary Perl code to be a
2400 part of a regexp. A code evaluation expression is denoted "(?{code})",
2401 with code a string of Perl statements.
2402 Code expressions are zero-width assertions, and the value they return
2404 depends on their environment. There are two possibilities: either the
2405 code expression is used as a conditional in a conditional expression
2406 "(?(condition)...)", or it is not. If the code expression is a
2407 conditional, the code is evaluated and the result (i.e., the result of
2408 the last statement) is used to determine truth or falsehood. If the
2409 code expression is not used as a conditional, the assertion always
2410 evaluates true and the result is put into the special variable $^R.
2411 The variable $^R can then be used in code expressions later in the
2412 regexp. Here are some silly examples:
2413 $x = "abcdef";
2415 $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2416 # prints 'Hi Mom!'
2417 $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2418 # no 'Hi Mom!'
2419 Pay careful attention to the next example:
2421 $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2423 # no 'Hi Mom!'
2424 # but why not?
2425 At first glance, you'd think that it shouldn't print, because obviously
2427 the "ddd" isn't going to match the target string. But look at this
2428 example:
2429 $x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # doesn't match,
2431 # but _does_ print
2432 Hmm. What happened here? If you've been following along, you know that
2434 the above pattern should be effectively (almost) the same as the last
2435 one; enclosing the 'd' in a character class isn't going to change what
2436 it matches. So why does the first not print while the second one does?
2437 The answer lies in the optimizations the regexp engine makes. In the
2439 first case, all the engine sees are plain old characters (aside from
2440 the "?{}" construct). It's smart enough to realize that the string
2441 'ddd' doesn't occur in our target string before actually running the
2442 pattern through. But in the second case, we've tricked it into thinking
2443 that our pattern is more complicated. It takes a look, sees our
2444 character class, and decides that it will have to actually run the
2445 pattern to determine whether or not it matches, and in the process of
2446 running it hits the print statement before it discovers that we don't
2447 have a match.
2448 To take a closer look at how the engine does optimizations, see the
2450 section "Pragmas and debugging" below.
2451 More fun with "?{}":
2453 $x =~ /(?{print "Hi Mom!";})/; # matches,
2455 # prints 'Hi Mom!'
2456 $x =~ /(?{$c = 1;})(?{print "$c";})/; # matches,
2457 # prints '1'
2458 $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2459 # prints '1'
2460 The bit of magic mentioned in the section title occurs when the regexp
2462 backtracks in the process of searching for a match. If the regexp
2463 backtracks over a code expression and if the variables used within are
2464 localized using "local", the changes in the variables produced by the
2465 code expression are undone! Thus, if we wanted to count how many times
2466 a character got matched inside a group, we could use, e.g.,
2467 $x = "aaaa";
2469 $count = 0; # initialize 'a' count
2470 $c = "bob"; # test if $c gets clobbered
2471 $x =~ /(?{local $c = 0;}) # initialize count
2472 ( a # match 'a'
2473 (?{local $c = $c + 1;}) # increment count
2474 )* # do this any number of times,
2475 aa # but match 'aa' at the end
2476 (?{$count = $c;}) # copy local $c var into $count
2477 /x;
2478 print "'a' count is $count, \$c variable is '$c'\n";
2479 This prints
2481 'a' count is 2, $c variable is 'bob'
2483 If we replace the " (?{local $c = $c + 1;})" with " (?{$c = $c + 1;})",
2485 the variable changes are not undone during backtracking, and we get
2486 'a' count is 4, $c variable is 'bob'
2488 Note that only localized variable changes are undone. Other side
2490 effects of code expression execution are permanent. Thus
2491 $x = "aaaa";
2493 $x =~ /(a(?{print "Yow\n";}))*aa/;
2494 produces
2496 Yow
2498 Yow
2499 Yow
2500 Yow
2501 The result $^R is automatically localized, so that it will behave
2503 properly in the presence of backtracking.
2504 This example uses a code expression in a conditional to match a
2506 definite article, either 'the' in English or 'der|die|das' in German:
2507 $lang = 'DE'; # use German
2509 ...
2510 $text = "das";
2511 print "matched\n"
2512 if $text =~ /(?(?{
2513 $lang eq 'EN'; # is the language English?
2514 })
2515 the | # if so, then match 'the'
2516 (der|die|das) # else, match 'der|die|das'
2517 )
2518 /xi;
2519 Note that the syntax here is "(?(?{...})yes-regexp|no-regexp)", not
2521 "(?((?{...}))yes-regexp|no-regexp)". In other words, in the case of a
2522 code expression, we don't need the extra parentheses around the
2523 conditional.
2524 If you try to use code expressions where the code text is contained
2526 within an interpolated variable, rather than appearing literally in the
2527 pattern, Perl may surprise you:
2528 $bar = 5;
2530 $pat = '(?{ 1 })';
2531 /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2532 /foo(?{ 1 })$bar/; # compiles ok, $bar interpolated
2533 /foo${pat}bar/; # compile error!
2534 $pat = qr/(?{ $foo = 1 })/; # precompile code regexp
2536 /foo${pat}bar/; # compiles ok
2537 If a regexp has a variable that interpolates a code expression, Perl
2539 treats the regexp as an error. If the code expression is precompiled
2540 into a variable, however, interpolating is ok. The question is, why is
2541 this an error?
2542 The reason is that variable interpolation and code expressions together
2544 pose a security risk. The combination is dangerous because many
2545 programmers who write search engines often take user input and plug it
2546 directly into a regexp:
2547 $regexp = <>; # read user-supplied regexp
2549 $chomp $regexp; # get rid of possible newline
2550 $text =~ /$regexp/; # search $text for the $regexp
2551 If the $regexp variable contains a code expression, the user could then
2553 execute arbitrary Perl code. For instance, some joker could search for
2554 "system('rm -rf *');" to erase your files. In this sense, the
2555 combination of interpolation and code expressions taints your regexp.
2556 So by default, using both interpolation and code expressions in the
2557 same regexp is not allowed. If you're not concerned about malicious
2558 users, it is possible to bypass this security check by invoking
2559 "use re 'eval'":
2560 use re 'eval'; # throw caution out the door
2562 $bar = 5;
2563 $pat = '(?{ 1 })';
2564 /foo${pat}bar/; # compiles ok
2565 Another form of code expression is the pattern code expression. The
2567 pattern code expression is like a regular code expression, except that
2568 the result of the code evaluation is treated as a regular expression
2569 and matched immediately. A simple example is
2570 $length = 5;
2572 $char = 'a';
2573 $x = 'aaaaabb';
2574 $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2575 This final example contains both ordinary and pattern code expressions.
2577 It detects whether a binary string 1101010010001... has a Fibonacci
2578 spacing 0,1,1,2,3,5,... of the '1''s:
2579 $x = "1101010010001000001";
2581 $z0 = ''; $z1 = '0'; # initial conditions
2582 print "It is a Fibonacci sequence\n"
2583 if $x =~ /^1 # match an initial '1'
2584 (?:
2585 ((??{ $z0 })) # match some '0'
2586 1 # and then a '1'
2587 (?{ $z0 = $z1; $z1 .= $^N; })
2588 )+ # repeat as needed
2589 $ # that is all there is
2590 /x;
2591 printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2592 Remember that $^N is set to whatever was matched by the last completed
2594 capture group. This prints
2595 It is a Fibonacci sequence
2597 Largest sequence matched was 5
2598 Ha! Try that with your garden variety regexp package...
2600 Note that the variables $z0 and $z1 are not substituted when the regexp
2602 is compiled, as happens for ordinary variables outside a code
2603 expression. Rather, the whole code block is parsed as perl code at the
2604 same time as perl is compiling the code containing the literal regexp
2605 pattern.
2606 This regexp without the "/x" modifier is
2608 /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2610 which shows that spaces are still possible in the code parts.
2612 Nevertheless, when working with code and conditional expressions, the
2613 extended form of regexps is almost necessary in creating and debugging
2614 regexps.
2615 Backtracking control verbs
2617 Perl 5.10 introduced a number of control verbs intended to provide
2618 detailed control over the backtracking process, by directly influencing
2619 the regexp engine and by providing monitoring techniques. See "Special
2620 Backtracking Control Verbs" in perlre for a detailed description.
2621 Below is just one example, illustrating the control verb "(*FAIL)",
2623 which may be abbreviated as "(*F)". If this is inserted in a regexp it
2624 will cause it to fail, just as it would at some mismatch between the
2625 pattern and the string. Processing of the regexp continues as it would
2626 after any "normal" failure, so that, for instance, the next position in
2627 the string or another alternative will be tried. As failing to match
2628 doesn't preserve capture groups or produce results, it may be necessary
2629 to use this in combination with embedded code.
2630 %count = ();
2632 "supercalifragilisticexpialidocious" =~
2633 /([aeiou])(?{ $count{$1}++; })(*FAIL)/i;
2634 printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2635 The pattern begins with a class matching a subset of letters. Whenever
2637 this matches, a statement like "$count{'a'}++;" is executed,
2638 incrementing the letter's counter. Then "(*FAIL)" does what it says,
2639 and the regexp engine proceeds according to the book: as long as the
2640 end of the string hasn't been reached, the position is advanced before
2641 looking for another vowel. Thus, match or no match makes no difference,
2642 and the regexp engine proceeds until the entire string has been
2643 inspected. (It's remarkable that an alternative solution using
2644 something like
2645 $count{lc($_)}++ for split('', "supercalifragilisticexpialidocious");
2647 printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2648 is considerably slower.)
2650 Pragmas and debugging
2652 Speaking of debugging, there are several pragmas available to control
2653 and debug regexps in Perl. We have already encountered one pragma in
2654 the previous section, "use re 'eval';", that allows variable
2655 interpolation and code expressions to coexist in a regexp. The other
2656 pragmas are
2657 use re 'taint';
2659 $tainted = <>;
2660 @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2661 The "taint" pragma causes any substrings from a match with a tainted
2663 variable to be tainted as well, if your perl supports tainting (see
2664 perlsec). This is not normally the case, as regexps are often used to
2665 extract the safe bits from a tainted variable. Use "taint" when you
2666 are not extracting safe bits, but are performing some other processing.
2667 Both "taint" and "eval" pragmas are lexically scoped, which means they
2668 are in effect only until the end of the block enclosing the pragmas.
2669 use re '/m'; # or any other flags
2671 $multiline_string =~ /^foo/; # /m is implied
2672 The "re '/flags'" pragma (introduced in Perl 5.14) turns on the given
2674 regular expression flags until the end of the lexical scope. See
2675 "'/flags' mode" in re for more detail.
2676 use re 'debug';
2678 /^(.*)$/s; # output debugging info
2679 use re 'debugcolor';
2681 /^(.*)$/s; # output debugging info in living color
2682 The global "debug" and "debugcolor" pragmas allow one to get detailed
2684 debugging info about regexp compilation and execution. "debugcolor" is
2685 the same as debug, except the debugging information is displayed in
2686 color on terminals that can display termcap color sequences. Here is
2687 example output:
2688 % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2690 Compiling REx 'a*b+c'
2691 size 9 first at 1
2692 1: STAR(4)
2693 2: EXACT <a>(0)
2694 4: PLUS(7)
2695 5: EXACT <b>(0)
2696 7: EXACT <c>(9)
2697 9: END(0)
2698 floating 'bc' at 0..2147483647 (checking floating) minlen 2
2699 Guessing start of match, REx 'a*b+c' against 'abc'...
2700 Found floating substr 'bc' at offset 1...
2701 Guessed: match at offset 0
2702 Matching REx 'a*b+c' against 'abc'
2703 Setting an EVAL scope, savestack=3
2704 0 <> <abc> | 1: STAR
2705 EXACT <a> can match 1 times out of 32767...
2706 Setting an EVAL scope, savestack=3
2707 1 <a> <bc> | 4: PLUS
2708 EXACT <b> can match 1 times out of 32767...
2709 Setting an EVAL scope, savestack=3
2710 2 <ab> <c> | 7: EXACT <c>
2711 3 <abc> <> | 9: END
2712 Match successful!
2713 Freeing REx: 'a*b+c'
2714 If you have gotten this far into the tutorial, you can probably guess
2716 what the different parts of the debugging output tell you. The first
2717 part
2718 Compiling REx 'a*b+c'
2720 size 9 first at 1
2721 1: STAR(4)
2722 2: EXACT <a>(0)
2723 4: PLUS(7)
2724 5: EXACT <b>(0)
2725 7: EXACT <c>(9)
2726 9: END(0)
2727 describes the compilation stage. STAR(4) means that there is a starred
2729 object, in this case 'a', and if it matches, goto line 4, i.e.,
2730 PLUS(7). The middle lines describe some heuristics and optimizations
2731 performed before a match:
2732 floating 'bc' at 0..2147483647 (checking floating) minlen 2
2734 Guessing start of match, REx 'a*b+c' against 'abc'...
2735 Found floating substr 'bc' at offset 1...
2736 Guessed: match at offset 0
2737 Then the match is executed and the remaining lines describe the
2739 process:
2740 Matching REx 'a*b+c' against 'abc'
2742 Setting an EVAL scope, savestack=3
2743 0 <> <abc> | 1: STAR
2744 EXACT <a> can match 1 times out of 32767...
2745 Setting an EVAL scope, savestack=3
2746 1 <a> <bc> | 4: PLUS
2747 EXACT <b> can match 1 times out of 32767...
2748 Setting an EVAL scope, savestack=3
2749 2 <ab> <c> | 7: EXACT <c>
2750 3 <abc> <> | 9: END
2751 Match successful!
2752 Freeing REx: 'a*b+c'
2753 Each step is of the form "n <x> <y>", with "<x>" the part of the string
2755 matched and "<y>" the part not yet matched. The "| 1: STAR" says
2756 that Perl is at line number 1 in the compilation list above. See
2757 "Debugging Regular Expressions" in perldebguts for much more detail.
2758 An alternative method of debugging regexps is to embed "print"
2760 statements within the regexp. This provides a blow-by-blow account of
2761 the backtracking in an alternation:
2762 "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2764 t(?{print "t1\n";})
2765 h(?{print "h1\n";})
2766 i(?{print "i1\n";})
2767 s(?{print "s1\n";})
2768 |
2769 t(?{print "t2\n";})
2770 h(?{print "h2\n";})
2771 a(?{print "a2\n";})
2772 t(?{print "t2\n";})
2773 (?{print "Done at position ", pos, "\n";})
2774 @x;
2775 prints
2777 Start at position 0
2779 t1
2780 h1
2781 t2
2782 h2
2783 a2
2784 t2
2785 Done at position 4
2786
2788 This is just a tutorial. For the full story on Perl regular
2789 expressions, see the perlre regular expressions reference page.
2790 For more information on the matching "m//" and substitution "s///"
2792 operators, see "Regexp Quote-Like Operators" in perlop. For
2793 information on the "split" operation, see "split" in perlfunc.
2794 For an excellent all-around resource on the care and feeding of regular
2796 expressions, see the book Mastering Regular Expressions by Jeffrey
2797 Friedl (published by O'Reilly, ISBN 1556592-257-3).
2798
2800 Copyright (c) 2000 Mark Kvale. All rights reserved. Now maintained by
2801 Perl porters.
2802 This document may be distributed under the same terms as Perl itself.
2804 Acknowledgments
2806 The inspiration for the stop codon DNA example came from the ZIP code
2807 example in chapter 7 of Mastering Regular Expressions.
2808 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2810 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2811 comments.
2812perl v5.36.0 2022-08-30 PERLRETUT(1)