1PERLRE(1) Perl Programmers Reference Guide PERLRE(1)
2
3
4
6 perlre - Perl regular expressions
7
9 This page describes the syntax of regular expressions in Perl.
10
11 If you haven't used regular expressions before, a tutorial introduction
12 is available in perlretut. If you know just a little about them, a
13 quick-start introduction is available in perlrequick.
14
15 Except for "The Basics" section, this page assumes you are familiar
16 with regular expression basics, like what is a "pattern", what does it
17 look like, and how it is basically used. For a reference on how they
18 are used, plus various examples of the same, see discussions of "m//",
19 "s///", "qr//" and "??" in "Regexp Quote-Like Operators" in perlop.
20
21 New in v5.22, "use re 'strict'" applies stricter rules than otherwise
22 when compiling regular expression patterns. It can find things that,
23 while legal, may not be what you intended.
24
25 The Basics
26 Regular expressions are strings with the very particular syntax and
27 meaning described in this document and auxiliary documents referred to
28 by this one. The strings are called "patterns". Patterns are used to
29 determine if some other string, called the "target", has (or doesn't
30 have) the characteristics specified by the pattern. We call this
31 "matching" the target string against the pattern. Usually the match is
32 done by having the target be the first operand, and the pattern be the
33 second operand, of one of the two binary operators "=~" and "!~",
34 listed in "Binding Operators" in perlop; and the pattern will have been
35 converted from an ordinary string by one of the operators in "Regexp
36 Quote-Like Operators" in perlop, like so:
37
38 $foo =~ m/abc/
39
40 This evaluates to true if and only if the string in the variable $foo
41 contains somewhere in it, the sequence of characters "a", "b", then
42 "c". (The "=~ m", or match operator, is described in
43 "m/PATTERN/msixpodualngc" in perlop.)
44
45 Patterns that aren't already stored in some variable must be delimited,
46 at both ends, by delimiter characters. These are often, as in the
47 example above, forward slashes, and the typical way a pattern is
48 written in documentation is with those slashes. In most cases, the
49 delimiter is the same character, fore and aft, but there are a few
50 cases where a character looks like it has a mirror-image mate, where
51 the opening version is the beginning delimiter, and the closing one is
52 the ending delimiter, like
53
54 $foo =~ m<abc>
55
56 Most times, the pattern is evaluated in double-quotish context, but it
57 is possible to choose delimiters to force single-quotish, like
58
59 $foo =~ m'abc'
60
61 If the pattern contains its delimiter within it, that delimiter must be
62 escaped. Prefixing it with a backslash (e.g., "/foo\/bar/") serves
63 this purpose.
64
65 Any single character in a pattern matches that same character in the
66 target string, unless the character is a metacharacter with a special
67 meaning described in this document. A sequence of non-metacharacters
68 matches the same sequence in the target string, as we saw above with
69 "m/abc/".
70
71 Only a few characters (all of them being ASCII punctuation characters)
72 are metacharacters. The most commonly used one is a dot ".", which
73 normally matches almost any character (including a dot itself).
74
75 You can cause characters that normally function as metacharacters to be
76 interpreted literally by prefixing them with a "\", just like the
77 pattern's delimiter must be escaped if it also occurs within the
78 pattern. Thus, "\." matches just a literal dot, "." instead of its
79 normal meaning. This means that the backslash is also a metacharacter,
80 so "\\" matches a single "\". And a sequence that contains an escaped
81 metacharacter matches the same sequence (but without the escape) in the
82 target string. So, the pattern "/blur\\fl/" would match any target
83 string that contains the sequence "blur\fl".
84
85 The metacharacter "|" is used to match one thing or another. Thus
86
87 $foo =~ m/this|that/
88
89 is TRUE if and only if $foo contains either the sequence "this" or the
90 sequence "that". Like all metacharacters, prefixing the "|" with a
91 backslash makes it match the plain punctuation character; in its case,
92 the VERTICAL LINE.
93
94 $foo =~ m/this\|that/
95
96 is TRUE if and only if $foo contains the sequence "this|that".
97
98 You aren't limited to just a single "|".
99
100 $foo =~ m/fee|fie|foe|fum/
101
102 is TRUE if and only if $foo contains any of those 4 sequences from the
103 children's story "Jack and the Beanstalk".
104
105 As you can see, the "|" binds less tightly than a sequence of ordinary
106 characters. We can override this by using the grouping metacharacters,
107 the parentheses "(" and ")".
108
109 $foo =~ m/th(is|at) thing/
110
111 is TRUE if and only if $foo contains either the sequence "this thing"
112 or the sequence "that thing". The portions of the string that match
113 the portions of the pattern enclosed in parentheses are normally made
114 available separately for use later in the pattern, substitution, or
115 program. This is called "capturing", and it can get complicated. See
116 "Capture groups".
117
118 The first alternative includes everything from the last pattern
119 delimiter ("(", "(?:" (described later), etc. or the beginning of the
120 pattern) up to the first "|", and the last alternative contains
121 everything from the last "|" to the next closing pattern delimiter.
122 That's why it's common practice to include alternatives in parentheses:
123 to minimize confusion about where they start and end.
124
125 Alternatives are tried from left to right, so the first alternative
126 found for which the entire expression matches, is the one that is
127 chosen. This means that alternatives are not necessarily greedy. For
128 example: when matching "foo|foot" against "barefoot", only the "foo"
129 part will match, as that is the first alternative tried, and it
130 successfully matches the target string. (This might not seem important,
131 but it is important when you are capturing matched text using
132 parentheses.)
133
134 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning. These are called
137 "escape sequences", and all such are described in perlrebackslash. A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141
142 One such sequence is "\b", which matches a boundary of some sort.
143 "\b{wb}" and a few others give specialized types of boundaries. (They
144 are all described in detail starting at "\b{}, \b, \B{}, \B" in
145 perlrebackslash.) Note that these don't match characters, but the
146 zero-width spaces between characters. They are an example of a zero-
147 width assertion. Consider again,
148
149 $foo =~ m/fee|fie|foe|fum/
150
151 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in $foo. By
153 judicious use of "\b" (or better (because it is designed to handle
154 natural language) "\b{wb}"), we can make sure that only the Giant's
155 words are matched:
156
157 $foo =~ m/\b(fee|fie|foe|fum)\b/
158 $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159
160 The final example shows that the characters "{" and "}" are
161 metacharacters.
162
163 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally. These are described
165 in detail in "Character Escapes" in perlrebackslash, but the next three
166 paragraphs briefly describe some of them.
167
168 Various control characters can be written in C language style: "\n"
169 matches a newline, "\t" a tab, "\r" a carriage return, "\f" a form
170 feed, etc.
171
172 More generally, "\nnn", where nnn is a string of three octal digits,
173 matches the character whose native code point is nnn. You can easily
174 run into trouble if you don't have exactly three digits. So always use
175 three, or since Perl 5.14, you can use "\o{...}" to specify any number
176 of octal digits.
177
178 Similarly, "\xnn", where nn are hexadecimal digits, matches the
179 character whose native ordinal is nn. Again, not using exactly two
180 digits is a recipe for disaster, but you can use "\x{...}" to specify
181 any number of hex digits.
182
183 Besides being a metacharacter, the "." is an example of a "character
184 class", something that can match any single character of a given set of
185 them. In its case, the set is just about all possible characters.
186 Perl predefines several character classes besides the "."; there is a
187 separate reference page about just these, perlrecharclass.
188
189 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set. You do this by enclosing the list within "[]" bracket
192 characters. These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped. (Dropping it
194 usually doesn't cause confusion.) This means that the "[" character is
195 another metacharacter. It doesn't match anything just by itself; it is
196 used only to tell Perl that what follows it is a bracketed character
197 class. If you want to match a literal left square bracket, you must
198 escape it, like "\[". The matching "]" is also a metacharacter; again
199 it doesn't match anything by itself, but just marks the end of your
200 custom class to Perl. It is an example of a "sometimes metacharacter".
201 It isn't a metacharacter if there is no corresponding "[", and matches
202 its literal self:
203
204 print "]" =~ /]/; # prints 1
205
206 The list of characters within the character class gives the set of
207 characters matched by the class. "[abc]" matches a single "a" or "b"
208 or "c". But if the first character after the "[" is "^", the class
209 instead matches any character not in the list. Within a list, the "-"
210 character specifies a range of characters, so that "a-z" represents all
211 characters between "a" and "z", inclusive. If you want either "-" or
212 "]" itself to be a member of a class, put it at the start of the list
213 (possibly after a "^"), or escape it with a backslash. "-" is also
214 taken literally when it is at the end of the list, just before the
215 closing "]". (The following all specify the same class of three
216 characters: "[-az]", "[az-]", and "[a\-z]". All are different from
217 "[a-z]", which specifies a class containing twenty-six characters, even
218 on EBCDIC-based character sets.)
219
220 There is lots more to bracketed character classes; full details are in
221 "Bracketed Character Classes" in perlrecharclass.
222
223 Metacharacters
224
225 "The Basics" introduced some of the metacharacters. This section gives
226 them all. Most of them have the same meaning as in the egrep command.
227
228 Only the "\" is always a metacharacter. The others are metacharacters
229 just sometimes. The following tables lists all of them, summarizes
230 their use, and gives the contexts where they are metacharacters.
231 Outside those contexts or if prefixed by a "\", they match their
232 corresponding punctuation character. In some cases, their meaning
233 varies depending on various pattern modifiers that alter the default
234 behaviors. See "Modifiers".
235
236 PURPOSE WHERE
237 \ Escape the next character Always, except when
238 escaped by another \
239 ^ Match the beginning of the string Not in []
240 (or line, if /m is used)
241 ^ Complement the [] class At the beginning of []
242 . Match any single character except newline Not in []
243 (under /s, includes newline)
244 $ Match the end of the string Not in [], but can
245 (or before newline at the end of the mean interpolate a
246 string; or before any newline if /m is scalar
247 used)
248 | Alternation Not in []
249 () Grouping Not in []
250 [ Start Bracketed Character class Not in []
251 ] End Bracketed Character class Only in [], and
252 not first
253 * Matches the preceding element 0 or more Not in []
254 times
255 + Matches the preceding element 1 or more Not in []
256 times
257 ? Matches the preceding element 0 or 1 Not in []
258 times
259 { Starts a sequence that gives number(s) Not in []
260 of times the preceding element can be
261 matched
262 { when following certain escape sequences
263 starts a modifier to the meaning of the
264 sequence
265 } End sequence started by {
266 - Indicates a range Only in [] interior
267 # Beginning of comment, extends to line end Only with /x modifier
268
269 Notice that most of the metacharacters lose their special meaning when
270 they occur in a bracketed character class, except "^" has a different
271 meaning when it is at the beginning of such a class. And "-" and "]"
272 are metacharacters only at restricted positions within bracketed
273 character classes; while "}" is a metacharacter only when closing a
274 special construct started by "{".
275
276 In double-quotish context, as is usually the case, you need to be
277 careful about "$" and the non-metacharacter "@". Those could
278 interpolate variables, which may or may not be what you intended.
279
280 These rules were designed for compactness of expression, rather than
281 legibility and maintainability. The "/x and /xx" pattern modifiers
282 allow you to insert white space to improve readability. And use of
283 "re 'strict'" adds extra checking to catch some typos that might
284 silently compile into something unintended.
285
286 By default, the "^" character is guaranteed to match only the beginning
287 of the string, the "$" character only the end (or before the newline at
288 the end), and Perl does certain optimizations with the assumption that
289 the string contains only one line. Embedded newlines will not be
290 matched by "^" or "$". You may, however, wish to treat a string as a
291 multi-line buffer, such that the "^" will match after any newline
292 within the string (except if the newline is the last character in the
293 string), and "$" will match before any newline. At the cost of a
294 little more overhead, you can do this by using the "/m" modifier on the
295 pattern match operator. (Older programs did this by setting $*, but
296 this option was removed in perl 5.10.)
297
298 To simplify multi-line substitutions, the "." character never matches a
299 newline unless you use the "/s" modifier, which in effect tells Perl to
300 pretend the string is a single line--even if it isn't.
301
302 Modifiers
303 Overview
304
305 The default behavior for matching can be changed, using various
306 modifiers. Modifiers that relate to the interpretation of the pattern
307 are listed just below. Modifiers that alter the way a pattern is used
308 by Perl are detailed in "Regexp Quote-Like Operators" in perlop and
309 "Gory details of parsing quoted constructs" in perlop. Modifiers can
310 be added dynamically; see "Extended Patterns" below.
311
312 "m" Treat the string being matched against as multiple lines. That is,
313 change "^" and "$" from matching the start of the string's first
314 line and the end of its last line to matching the start and end of
315 each line within the string.
316
317 "s" Treat the string as single line. That is, change "." to match any
318 character whatsoever, even a newline, which normally it would not
319 match.
320
321 Used together, as "/ms", they let the "." match any character
322 whatsoever, while still allowing "^" and "$" to match,
323 respectively, just after and just before newlines within the
324 string.
325
326 "i" Do case-insensitive pattern matching. For example, "A" will match
327 "a" under "/i".
328
329 If locale matching rules are in effect, the case map is taken from
330 the current locale for code points less than 255, and from Unicode
331 rules for larger code points. However, matches that would cross
332 the Unicode rules/non-Unicode rules boundary (ords 255/256) will
333 not succeed, unless the locale is a UTF-8 one. See perllocale.
334
335 There are a number of Unicode characters that match a sequence of
336 multiple characters under "/i". For example, "LATIN SMALL LIGATURE
337 FI" should match the sequence "fi". Perl is not currently able to
338 do this when the multiple characters are in the pattern and are
339 split between groupings, or when one or more are quantified. Thus
340
341 "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i; # Matches
342 "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i; # Doesn't match!
343 "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i; # Doesn't match!
344
345 # The below doesn't match, and it isn't clear what $1 and $2 would
346 # be even if it did!!
347 "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i; # Doesn't match!
348
349 Perl doesn't match multiple characters in a bracketed character
350 class unless the character that maps to them is explicitly
351 mentioned, and it doesn't match them at all if the character class
352 is inverted, which otherwise could be highly confusing. See
353 "Bracketed Character Classes" in perlrecharclass, and "Negation" in
354 perlrecharclass.
355
356 "x" and "xx"
357 Extend your pattern's legibility by permitting whitespace and
358 comments. Details in "/x and /xx"
359
360 "p" Preserve the string matched such that "${^PREMATCH}", "${^MATCH}",
361 and "${^POSTMATCH}" are available for use after matching.
362
363 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
364 mechanism, "${^PREMATCH}", "${^MATCH}", and "${^POSTMATCH}" will be
365 available after the match regardless of the modifier.
366
367 "a", "d", "l", and "u"
368 These modifiers, all new in 5.14, affect which character-set rules
369 (Unicode, etc.) are used, as described below in "Character set
370 modifiers".
371
372 "n" Prevent the grouping metacharacters "()" from capturing. This
373 modifier, new in 5.22, will stop $1, $2, etc... from being filled
374 in.
375
376 "hello" =~ /(hi|hello)/; # $1 is "hello"
377 "hello" =~ /(hi|hello)/n; # $1 is undef
378
379 This is equivalent to putting "?:" at the beginning of every
380 capturing group:
381
382 "hello" =~ /(?:hi|hello)/; # $1 is undef
383
384 "/n" can be negated on a per-group basis. Alternatively, named
385 captures may still be used.
386
387 "hello" =~ /(?-n:(hi|hello))/n; # $1 is "hello"
388 "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
389 # "hello"
390
391 Other Modifiers
392 There are a number of flags that can be found at the end of regular
393 expression constructs that are not generic regular expression
394 flags, but apply to the operation being performed, like matching or
395 substitution ("m//" or "s///" respectively).
396
397 Flags described further in "Using regular expressions in Perl" in
398 perlretut are:
399
400 c - keep the current position during repeated matching
401 g - globally match the pattern repeatedly in the string
402
403 Substitution-specific modifiers described in
404 "s/PATTERN/REPLACEMENT/msixpodualngcer" in perlop are:
405
406 e - evaluate the right-hand side as an expression
407 ee - evaluate the right side as a string then eval the result
408 o - pretend to optimize your code, but actually introduce bugs
409 r - perform non-destructive substitution and return the new value
410
411 Regular expression modifiers are usually written in documentation as
412 e.g., "the "/x" modifier", even though the delimiter in question might
413 not really be a slash. The modifiers "/imnsxadlup" may also be
414 embedded within the regular expression itself using the "(?...)"
415 construct, see "Extended Patterns" below.
416
417 Details on some modifiers
418
419 Some of the modifiers require more explanation than given in the
420 "Overview" above.
421
422 "/x" and "/xx"
423
424 A single "/x" tells the regular expression parser to ignore most
425 whitespace that is neither backslashed nor within a bracketed character
426 class, nor within the characters of a multi-character metapattern like
427 "(?i: ... )". You can use this to break up your regular expression
428 into more readable parts. Also, the "#" character is treated as a
429 metacharacter introducing a comment that runs up to the pattern's
430 closing delimiter, or to the end of the current line if the pattern
431 extends onto the next line. Hence, this is very much like an ordinary
432 Perl code comment. (You can include the closing delimiter within the
433 comment only if you precede it with a backslash, so be careful!)
434
435 Use of "/x" means that if you want real whitespace or "#" characters in
436 the pattern (outside a bracketed character class, which is unaffected
437 by "/x"), then you'll either have to escape them (using backslashes or
438 "\Q...\E") or encode them using octal, hex, or "\N{}" or "\p{name=...}"
439 escapes. It is ineffective to try to continue a comment onto the next
440 line by escaping the "\n" with a backslash or "\Q".
441
442 You can use "(?#text)" to create a comment that ends earlier than the
443 end of the current line, but "text" also can't contain the closing
444 delimiter unless escaped with a backslash.
445
446 A common pitfall is to forget that "#" characters (outside a bracketed
447 character class) begin a comment under "/x" and are not matched
448 literally. Just keep that in mind when trying to puzzle out why a
449 particular "/x" pattern isn't working as expected. Inside a bracketed
450 character class, "#" retains its non-special, literal meaning.
451
452 Starting in Perl v5.26, if the modifier has a second "x" within it, the
453 effect of a single "/x" is increased. The only difference is that
454 inside bracketed character classes, non-escaped (by a backslash) SPACE
455 and TAB characters are not added to the class, and hence can be
456 inserted to make the classes more readable:
457
458 / [d-e g-i 3-7]/xx
459 /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
460
461 may be easier to grasp than the squashed equivalents
462
463 /[d-eg-i3-7]/
464 /[!@"#$%^&*()=?<>']/
465
466 Note that this unfortunately doesn't mean that your bracketed classes
467 can contain comments or extend over multiple lines. A "#" inside a
468 character class is still just a literal "#", and doesn't introduce a
469 comment. And, unless the closing bracket is on the same line as the
470 opening one, the newline character (and everything on the next line(s)
471 until terminated by a "]" will be part of the class, just as if you'd
472 written "\n".
473
474 Taken together, these features go a long way towards making Perl's
475 regular expressions more readable. Here's an example:
476
477 # Delete (most) C comments.
478 $program =~ s {
479 /\* # Match the opening delimiter.
480 .*? # Match a minimal number of characters.
481 \*/ # Match the closing delimiter.
482 } []gsx;
483
484 Note that anything inside a "\Q...\E" stays unaffected by "/x". And
485 note that "/x" doesn't affect space interpretation within a single
486 multi-character construct. For example "(?:...)" can't have a space
487 between the "(", "?", and ":". Within any delimiters for such a
488 construct, allowed spaces are not affected by "/x", and depend on the
489 construct. For example, all constructs using curly braces as
490 delimiters, such as "\x{...}" can have blanks within but adjacent to
491 the braces, but not elsewhere, and no non-blank space characters. An
492 exception are Unicode properties which follow Unicode rules, for which
493 see "Properties accessible through \p{} and \P{}" in perluniprops.
494
495 The set of characters that are deemed whitespace are those that Unicode
496 calls "Pattern White Space", namely:
497
498 U+0009 CHARACTER TABULATION
499 U+000A LINE FEED
500 U+000B LINE TABULATION
501 U+000C FORM FEED
502 U+000D CARRIAGE RETURN
503 U+0020 SPACE
504 U+0085 NEXT LINE
505 U+200E LEFT-TO-RIGHT MARK
506 U+200F RIGHT-TO-LEFT MARK
507 U+2028 LINE SEPARATOR
508 U+2029 PARAGRAPH SEPARATOR
509
510 Character set modifiers
511
512 "/d", "/u", "/a", and "/l", available starting in 5.14, are called the
513 character set modifiers; they affect the character set rules used for
514 the regular expression.
515
516 The "/d", "/u", and "/l" modifiers are not likely to be of much use to
517 you, and so you need not worry about them very much. They exist for
518 Perl's internal use, so that complex regular expression data structures
519 can be automatically serialized and later exactly reconstituted,
520 including all their nuances. But, since Perl can't keep a secret, and
521 there may be rare instances where they are useful, they are documented
522 here.
523
524 The "/a" modifier, on the other hand, may be useful. Its purpose is to
525 allow code that is to work mostly on ASCII data to not have to concern
526 itself with Unicode.
527
528 Briefly, "/l" sets the character set to that of whatever Locale is in
529 effect at the time of the execution of the pattern match.
530
531 "/u" sets the character set to Unicode.
532
533 "/a" also sets the character set to Unicode, BUT adds several
534 restrictions for ASCII-safe matching.
535
536 "/d" is the old, problematic, pre-5.14 Default character set behavior.
537 Its only use is to force that old behavior.
538
539 At any given time, exactly one of these modifiers is in effect. Their
540 existence allows Perl to keep the originally compiled behavior of a
541 regular expression, regardless of what rules are in effect when it is
542 actually executed. And if it is interpolated into a larger regex, the
543 original's rules continue to apply to it, and don't affect the other
544 parts.
545
546 The "/l" and "/u" modifiers are automatically selected for regular
547 expressions compiled within the scope of various pragmas, and we
548 recommend that in general, you use those pragmas instead of specifying
549 these modifiers explicitly. For one thing, the modifiers affect only
550 pattern matching, and do not extend to even any replacement done,
551 whereas using the pragmas gives consistent results for all appropriate
552 operations within their scopes. For example,
553
554 s/foo/\Ubar/il
555
556 will match "foo" using the locale's rules for case-insensitive
557 matching, but the "/l" does not affect how the "\U" operates. Most
558 likely you want both of them to use locale rules. To do this, instead
559 compile the regular expression within the scope of "use locale". This
560 both implicitly adds the "/l", and applies locale rules to the "\U".
561 The lesson is to "use locale", and not "/l" explicitly.
562
563 Similarly, it would be better to use "use feature 'unicode_strings'"
564 instead of,
565
566 s/foo/\Lbar/iu
567
568 to get Unicode rules, as the "\L" in the former (but not necessarily
569 the latter) would also use Unicode rules.
570
571 More detail on each of the modifiers follows. Most likely you don't
572 need to know this detail for "/l", "/u", and "/d", and can skip ahead
573 to /a.
574
575 /l
576
577 means to use the current locale's rules (see perllocale) when pattern
578 matching. For example, "\w" will match the "word" characters of that
579 locale, and "/i" case-insensitive matching will match according to the
580 locale's case folding rules. The locale used will be the one in effect
581 at the time of execution of the pattern match. This may not be the
582 same as the compilation-time locale, and can differ from one match to
583 another if there is an intervening call of the setlocale() function.
584
585 Prior to v5.20, Perl did not support multi-byte locales. Starting
586 then, UTF-8 locales are supported. No other multi byte locales are
587 ever likely to be supported. However, in all locales, one can have
588 code points above 255 and these will always be treated as Unicode no
589 matter what locale is in effect.
590
591 Under Unicode rules, there are a few case-insensitive matches that
592 cross the 255/256 boundary. Except for UTF-8 locales in Perls v5.20
593 and later, these are disallowed under "/l". For example, 0xFF (on
594 ASCII platforms) does not caselessly match the character at 0x178,
595 "LATIN CAPITAL LETTER Y WITH DIAERESIS", because 0xFF may not be "LATIN
596 SMALL LETTER Y WITH DIAERESIS" in the current locale, and Perl has no
597 way of knowing if that character even exists in the locale, much less
598 what code point it is.
599
600 In a UTF-8 locale in v5.20 and later, the only visible difference
601 between locale and non-locale in regular expressions should be
602 tainting, if your perl supports taint checking (see perlsec).
603
604 This modifier may be specified to be the default by "use locale", but
605 see "Which character set modifier is in effect?".
606
607 /u
608
609 means to use Unicode rules when pattern matching. On ASCII platforms,
610 this means that the code points between 128 and 255 take on their
611 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
612 (Otherwise Perl considers their meanings to be undefined.) Thus, under
613 this modifier, the ASCII platform effectively becomes a Unicode
614 platform; and hence, for example, "\w" will match any of the more than
615 100_000 word characters in Unicode.
616
617 Unlike most locales, which are specific to a language and country pair,
618 Unicode classifies all the characters that are letters somewhere in the
619 world as "\w". For example, your locale might not think that "LATIN
620 SMALL LETTER ETH" is a letter (unless you happen to speak Icelandic),
621 but Unicode does. Similarly, all the characters that are decimal
622 digits somewhere in the world will match "\d"; this is hundreds, not
623 10, possible matches. And some of those digits look like some of the
624 10 ASCII digits, but mean a different number, so a human could easily
625 think a number is a different quantity than it really is. For example,
626 "BENGALI DIGIT FOUR" (U+09EA) looks very much like an "ASCII DIGIT
627 EIGHT" (U+0038), and "LEPCHA DIGIT SIX" (U+1C46) looks very much like
628 an "ASCII DIGIT FIVE" (U+0035). And, "\d+", may match strings of
629 digits that are a mixture from different writing systems, creating a
630 security issue. A fraudulent website, for example, could display the
631 price of something using U+1C46, and it would appear to the user that
632 something cost 500 units, but it really costs 600. A browser that
633 enforced script runs ("Script Runs") would prevent that fraudulent
634 display. "num()" in Unicode::UCD can also be used to sort this out.
635 Or the "/a" modifier can be used to force "\d" to match just the ASCII
636 0 through 9.
637
638 Also, under this modifier, case-insensitive matching works on the full
639 set of Unicode characters. The "KELVIN SIGN", for example matches the
640 letters "k" and "K"; and "LATIN SMALL LIGATURE FF" matches the sequence
641 "ff", which, if you're not prepared, might make it look like a
642 hexadecimal constant, presenting another potential security issue. See
643 <https://unicode.org/reports/tr36> for a detailed discussion of Unicode
644 security issues.
645
646 This modifier may be specified to be the default by "use feature
647 'unicode_strings", "use locale ':not_characters'", or "use v5.12" (or
648 higher), but see "Which character set modifier is in effect?".
649
650 /d
651
652 IMPORTANT: Because of the unpredictable behaviors this modifier causes,
653 only use it to maintain weird backward compatibilities. Use the
654 "unicode_strings" feature in new code to avoid inadvertently enabling
655 this modifier by default.
656
657 What does this modifier do? It "Depends"!
658
659 This modifier means to use platform-native matching rules except when
660 there is cause to use Unicode rules instead, as follows:
661
662 1. the target string's UTF8 flag (see below) is set; or
663
664 2. the pattern's UTF8 flag (see below) is set; or
665
666 3. the pattern explicitly mentions a code point that is above 255 (say
667 by "\x{100}"); or
668
669 4. the pattern uses a Unicode name ("\N{...}"); or
670
671 5. the pattern uses a Unicode property ("\p{...}" or "\P{...}"); or
672
673 6. the pattern uses a Unicode break ("\b{...}" or "\B{...}"); or
674
675 7. the pattern uses "(?[ ])"
676
677 8. the pattern uses "(*script_run: ...)"
678
679 Regarding the "UTF8 flag" references above: normally Perl applications
680 shouldn't think about that flag. It's part of Perl's internals, so it
681 can change whenever Perl wants. "/d" may thus cause unpredictable
682 results. See "The "Unicode Bug"" in perlunicode. This bug has become
683 rather infamous, leading to yet other (without swearing) names for this
684 modifier like "Dicey" and "Dodgy".
685
686 Here are some examples of how that works on an ASCII platform:
687
688 $str = "\xDF"; #
689 utf8::downgrade($str); # $str is not UTF8-flagged.
690 $str =~ /^\w/; # No match, since no UTF8 flag.
691
692 $str .= "\x{0e0b}"; # Now $str is UTF8-flagged.
693 $str =~ /^\w/; # Match! $str is now UTF8-flagged.
694 chop $str;
695 $str =~ /^\w/; # Still a match! $str retains its UTF8 flag.
696
697 Under Perl's default configuration this modifier is automatically
698 selected by default when none of the others are, so yet another name
699 for it (unfortunately) is "Default".
700
701 Whenever you can, use the "unicode_strings" to cause to be the default
702 instead.
703
704 /a (and /aa)
705
706 This modifier stands for ASCII-restrict (or ASCII-safe). This modifier
707 may be doubled-up to increase its effect.
708
709 When it appears singly, it causes the sequences "\d", "\s", "\w", and
710 the Posix character classes to match only in the ASCII range. They
711 thus revert to their pre-5.6, pre-Unicode meanings. Under "/a", "\d"
712 always means precisely the digits "0" to "9"; "\s" means the five
713 characters "[ \f\n\r\t]", and starting in Perl v5.18, the vertical tab;
714 "\w" means the 63 characters "[A-Za-z0-9_]"; and likewise, all the
715 Posix classes such as "[[:print:]]" match only the appropriate ASCII-
716 range characters.
717
718 This modifier is useful for people who only incidentally use Unicode,
719 and who do not wish to be burdened with its complexities and security
720 concerns.
721
722 With "/a", one can write "\d" with confidence that it will only match
723 ASCII characters, and should the need arise to match beyond ASCII, you
724 can instead use "\p{Digit}" (or "\p{Word}" for "\w"). There are
725 similar "\p{...}" constructs that can match beyond ASCII both white
726 space (see "Whitespace" in perlrecharclass), and Posix classes (see
727 "POSIX Character Classes" in perlrecharclass). Thus, this modifier
728 doesn't mean you can't use Unicode, it means that to get Unicode
729 matching you must explicitly use a construct ("\p{}", "\P{}") that
730 signals Unicode.
731
732 As you would expect, this modifier causes, for example, "\D" to mean
733 the same thing as "[^0-9]"; in fact, all non-ASCII characters match
734 "\D", "\S", and "\W". "\b" still means to match at the boundary
735 between "\w" and "\W", using the "/a" definitions of them (similarly
736 for "\B").
737
738 Otherwise, "/a" behaves like the "/u" modifier, in that case-
739 insensitive matching uses Unicode rules; for example, "k" will match
740 the Unicode "\N{KELVIN SIGN}" under "/i" matching, and code points in
741 the Latin1 range, above ASCII will have Unicode rules when it comes to
742 case-insensitive matching.
743
744 To forbid ASCII/non-ASCII matches (like "k" with "\N{KELVIN SIGN}"),
745 specify the "a" twice, for example "/aai" or "/aia". (The first
746 occurrence of "a" restricts the "\d", etc., and the second occurrence
747 adds the "/i" restrictions.) But, note that code points outside the
748 ASCII range will use Unicode rules for "/i" matching, so the modifier
749 doesn't really restrict things to just ASCII; it just forbids the
750 intermixing of ASCII and non-ASCII.
751
752 To summarize, this modifier provides protection for applications that
753 don't wish to be exposed to all of Unicode. Specifying it twice gives
754 added protection.
755
756 This modifier may be specified to be the default by "use re '/a'" or
757 "use re '/aa'". If you do so, you may actually have occasion to use
758 the "/u" modifier explicitly if there are a few regular expressions
759 where you do want full Unicode rules (but even here, it's best if
760 everything were under feature "unicode_strings", along with the "use re
761 '/aa'"). Also see "Which character set modifier is in effect?".
762
763 Which character set modifier is in effect?
764
765 Which of these modifiers is in effect at any given point in a regular
766 expression depends on a fairly complex set of interactions. These have
767 been designed so that in general you don't have to worry about it, but
768 this section gives the gory details. As explained below in "Extended
769 Patterns" it is possible to explicitly specify modifiers that apply
770 only to portions of a regular expression. The innermost always has
771 priority over any outer ones, and one applying to the whole expression
772 has priority over any of the default settings that are described in the
773 remainder of this section.
774
775 The "use re '/foo'" pragma can be used to set default modifiers
776 (including these) for regular expressions compiled within its scope.
777 This pragma has precedence over the other pragmas listed below that
778 also change the defaults.
779
780 Otherwise, "use locale" sets the default modifier to "/l"; and "use
781 feature 'unicode_strings", or "use v5.12" (or higher) set the default
782 to "/u" when not in the same scope as either "use locale" or "use
783 bytes". ("use locale ':not_characters'" also sets the default to "/u",
784 overriding any plain "use locale".) Unlike the mechanisms mentioned
785 above, these affect operations besides regular expressions pattern
786 matching, and so give more consistent results with other operators,
787 including using "\U", "\l", etc. in substitution replacements.
788
789 If none of the above apply, for backwards compatibility reasons, the
790 "/d" modifier is the one in effect by default. As this can lead to
791 unexpected results, it is best to specify which other rule set should
792 be used.
793
794 Character set modifier behavior prior to Perl 5.14
795
796 Prior to 5.14, there were no explicit modifiers, but "/l" was implied
797 for regexes compiled within the scope of "use locale", and "/d" was
798 implied otherwise. However, interpolating a regex into a larger regex
799 would ignore the original compilation in favor of whatever was in
800 effect at the time of the second compilation. There were a number of
801 inconsistencies (bugs) with the "/d" modifier, where Unicode rules
802 would be used when inappropriate, and vice versa. "\p{}" did not imply
803 Unicode rules, and neither did all occurrences of "\N{}", until 5.12.
804
805 Regular Expressions
806 Quantifiers
807
808 Quantifiers are used when a particular portion of a pattern needs to
809 match a certain number (or numbers) of times. If there isn't a
810 quantifier the number of times to match is exactly one. The following
811 standard quantifiers are recognized:
812
813 * Match 0 or more times
814 + Match 1 or more times
815 ? Match 1 or 0 times
816 {n} Match exactly n times
817 {n,} Match at least n times
818 {,n} Match at most n times
819 {n,m} Match at least n but not more than m times
820
821 (If a non-escaped curly bracket occurs in a context other than one of
822 the quantifiers listed above, where it does not form part of a
823 backslashed sequence like "\x{...}", it is either a fatal syntax error,
824 or treated as a regular character, generally with a deprecation warning
825 raised. To escape it, you can precede it with a backslash ("\{") or
826 enclose it within square brackets ("[{]"). This change will allow for
827 future syntax extensions (like making the lower bound of a quantifier
828 optional), and better error checking of quantifiers).
829
830 The "*" quantifier is equivalent to "{0,}", the "+" quantifier to
831 "{1,}", and the "?" quantifier to "{0,1}". n and m are limited to non-
832 negative integral values less than a preset limit defined when perl is
833 built. This is usually 65534 on the most common platforms. The actual
834 limit can be seen in the error message generated by code such as this:
835
836 $_ **= $_ , / {$_} / for 2 .. 42;
837
838 By default, a quantified subpattern is "greedy", that is, it will match
839 as many times as possible (given a particular starting location) while
840 still allowing the rest of the pattern to match. If you want it to
841 match the minimum number of times possible, follow the quantifier with
842 a "?". Note that the meanings don't change, just the "greediness":
843
844 *? Match 0 or more times, not greedily
845 +? Match 1 or more times, not greedily
846 ?? Match 0 or 1 time, not greedily
847 {n}? Match exactly n times, not greedily (redundant)
848 {n,}? Match at least n times, not greedily
849 {,n}? Match at most n times, not greedily
850 {n,m}? Match at least n but not more than m times, not greedily
851
852 Normally when a quantified subpattern does not allow the rest of the
853 overall pattern to match, Perl will backtrack. However, this behaviour
854 is sometimes undesirable. Thus Perl provides the "possessive"
855 quantifier form as well.
856
857 *+ Match 0 or more times and give nothing back
858 ++ Match 1 or more times and give nothing back
859 ?+ Match 0 or 1 time and give nothing back
860 {n}+ Match exactly n times and give nothing back (redundant)
861 {n,}+ Match at least n times and give nothing back
862 {,n}+ Match at most n times and give nothing back
863 {n,m}+ Match at least n but not more than m times and give nothing back
864
865 For instance,
866
867 'aaaa' =~ /a++a/
868
869 will never match, as the "a++" will gobble up all the "a"'s in the
870 string and won't leave any for the remaining part of the pattern. This
871 feature can be extremely useful to give perl hints about where it
872 shouldn't backtrack. For instance, the typical "match a double-quoted
873 string" problem can be most efficiently performed when written as:
874
875 /"(?:[^"\\]++|\\.)*+"/
876
877 as we know that if the final quote does not match, backtracking will
878 not help. See the independent subexpression "(?>pattern)" for more
879 details; possessive quantifiers are just syntactic sugar for that
880 construct. For instance the above example could also be written as
881 follows:
882
883 /"(?>(?:(?>[^"\\]+)|\\.)*)"/
884
885 Note that the possessive quantifier modifier can not be combined with
886 the non-greedy modifier. This is because it would make no sense.
887 Consider the follow equivalency table:
888
889 Illegal Legal
890 ------------ ------
891 X??+ X{0}
892 X+?+ X{1}
893 X{min,max}?+ X{min}
894
895 Escape sequences
896
897 Because patterns are processed as double-quoted strings, the following
898 also work:
899
900 \t tab (HT, TAB)
901 \n newline (LF, NL)
902 \r return (CR)
903 \f form feed (FF)
904 \a alarm (bell) (BEL)
905 \e escape (think troff) (ESC)
906 \cK control char (example: VT)
907 \x{}, \x00 character whose ordinal is the given hexadecimal number
908 \N{name} named Unicode character or character sequence
909 \N{U+263D} Unicode character (example: FIRST QUARTER MOON)
910 \o{}, \000 character whose ordinal is the given octal number
911 \l lowercase next char (think vi)
912 \u uppercase next char (think vi)
913 \L lowercase until \E (think vi)
914 \U uppercase until \E (think vi)
915 \Q quote (disable) pattern metacharacters until \E
916 \E end either case modification or quoted section, think vi
917
918 Details are in "Quote and Quote-like Operators" in perlop.
919
920 Character Classes and other Special Escapes
921
922 In addition, Perl defines the following:
923
924 Sequence Note Description
925 [...] [1] Match a character according to the rules of the
926 bracketed character class defined by the "...".
927 Example: [a-z] matches "a" or "b" or "c" ... or "z"
928 [[:...:]] [2] Match a character according to the rules of the POSIX
929 character class "..." within the outer bracketed
930 character class. Example: [[:upper:]] matches any
931 uppercase character.
932 (?[...]) [8] Extended bracketed character class
933 \w [3] Match a "word" character (alphanumeric plus "_", plus
934 other connector punctuation chars plus Unicode
935 marks)
936 \W [3] Match a non-"word" character
937 \s [3] Match a whitespace character
938 \S [3] Match a non-whitespace character
939 \d [3] Match a decimal digit character
940 \D [3] Match a non-digit character
941 \pP [3] Match P, named property. Use \p{Prop} for longer names
942 \PP [3] Match non-P
943 \X [4] Match Unicode "eXtended grapheme cluster"
944 \1 [5] Backreference to a specific capture group or buffer.
945 '1' may actually be any positive integer.
946 \g1 [5] Backreference to a specific or previous group,
947 \g{-1} [5] The number may be negative indicating a relative
948 previous group and may optionally be wrapped in
949 curly brackets for safer parsing.
950 \g{name} [5] Named backreference
951 \k<name> [5] Named backreference
952 \k'name' [5] Named backreference
953 \k{name} [5] Named backreference
954 \K [6] Keep the stuff left of the \K, don't include it in $&
955 \N [7] Any character but \n. Not affected by /s modifier
956 \v [3] Vertical whitespace
957 \V [3] Not vertical whitespace
958 \h [3] Horizontal whitespace
959 \H [3] Not horizontal whitespace
960 \R [4] Linebreak
961
962 [1] See "Bracketed Character Classes" in perlrecharclass for details.
963
964 [2] See "POSIX Character Classes" in perlrecharclass for details.
965
966 [3] See "Unicode Character Properties" in perlunicode for details
967
968 [4] See "Misc" in perlrebackslash for details.
969
970 [5] See "Capture groups" below for details.
971
972 [6] See "Extended Patterns" below for details.
973
974 [7] Note that "\N" has two meanings. When of the form "\N{NAME}", it
975 matches the character or character sequence whose name is NAME; and
976 similarly when of the form "\N{U+hex}", it matches the character
977 whose Unicode code point is hex. Otherwise it matches any
978 character but "\n".
979
980 [8] See "Extended Bracketed Character Classes" in perlrecharclass for
981 details.
982
983 Assertions
984
985 Besides "^" and "$", Perl defines the following zero-width assertions:
986
987 \b{} Match at Unicode boundary of specified type
988 \B{} Match where corresponding \b{} doesn't match
989 \b Match a \w\W or \W\w boundary
990 \B Match except at a \w\W or \W\w boundary
991 \A Match only at beginning of string
992 \Z Match only at end of string, or before newline at the end
993 \z Match only at end of string
994 \G Match only at pos() (e.g. at the end-of-match position
995 of prior m//g)
996
997 A Unicode boundary ("\b{}"), available starting in v5.22, is a spot
998 between two characters, or before the first character in the string, or
999 after the final character in the string where certain criteria defined
1000 by Unicode are met. See "\b{}, \b, \B{}, \B" in perlrebackslash for
1001 details.
1002
1003 A word boundary ("\b") is a spot between two characters that has a "\w"
1004 on one side of it and a "\W" on the other side of it (in either order),
1005 counting the imaginary characters off the beginning and end of the
1006 string as matching a "\W". (Within character classes "\b" represents
1007 backspace rather than a word boundary, just as it normally does in any
1008 double-quoted string.) The "\A" and "\Z" are just like "^" and "$",
1009 except that they won't match multiple times when the "/m" modifier is
1010 used, while "^" and "$" will match at every internal line boundary. To
1011 match the actual end of the string and not ignore an optional trailing
1012 newline, use "\z".
1013
1014 The "\G" assertion can be used to chain global matches (using "m//g"),
1015 as described in "Regexp Quote-Like Operators" in perlop. It is also
1016 useful when writing "lex"-like scanners, when you have several patterns
1017 that you want to match against consequent substrings of your string;
1018 see the previous reference. The actual location where "\G" will match
1019 can also be influenced by using pos() as an lvalue: see "pos" in
1020 perlfunc. Note that the rule for zero-length matches (see "Repeated
1021 Patterns Matching a Zero-length Substring") is modified somewhat, in
1022 that contents to the left of "\G" are not counted when determining the
1023 length of the match. Thus the following will not match forever:
1024
1025 my $string = 'ABC';
1026 pos($string) = 1;
1027 while ($string =~ /(.\G)/g) {
1028 print $1;
1029 }
1030
1031 It will print 'A' and then terminate, as it considers the match to be
1032 zero-width, and thus will not match at the same position twice in a
1033 row.
1034
1035 It is worth noting that "\G" improperly used can result in an infinite
1036 loop. Take care when using patterns that include "\G" in an
1037 alternation.
1038
1039 Note also that "s///" will refuse to overwrite part of a substitution
1040 that has already been replaced; so for example this will stop after the
1041 first iteration, rather than iterating its way backwards through the
1042 string:
1043
1044 $_ = "123456789";
1045 pos = 6;
1046 s/.(?=.\G)/X/g;
1047 print; # prints 1234X6789, not XXXXX6789
1048
1049 Capture groups
1050
1051 The grouping construct "( ... )" creates capture groups (also referred
1052 to as capture buffers). To refer to the current contents of a group
1053 later on, within the same pattern, use "\g1" (or "\g{1}") for the
1054 first, "\g2" (or "\g{2}") for the second, and so on. This is called a
1055 backreference.
1056
1057
1058
1059
1060
1061
1062
1063
1064 There is no limit to the number of captured substrings that you may
1065 use. Groups are numbered with the leftmost open parenthesis being
1066 number 1, etc. If a group did not match, the associated backreference
1067 won't match either. (This can happen if the group is optional, or in a
1068 different branch of an alternation.) You can omit the "g", and write
1069 "\1", etc, but there are some issues with this form, described below.
1070
1071 You can also refer to capture groups relatively, by using a negative
1072 number, so that "\g-1" and "\g{-1}" both refer to the immediately
1073 preceding capture group, and "\g-2" and "\g{-2}" both refer to the
1074 group before it. For example:
1075
1076 /
1077 (Y) # group 1
1078 ( # group 2
1079 (X) # group 3
1080 \g{-1} # backref to group 3
1081 \g{-3} # backref to group 1
1082 )
1083 /x
1084
1085 would match the same as "/(Y) ( (X) \g3 \g1 )/x". This allows you to
1086 interpolate regexes into larger regexes and not have to worry about the
1087 capture groups being renumbered.
1088
1089 You can dispense with numbers altogether and create named capture
1090 groups. The notation is "(?<name>...)" to declare and "\g{name}" to
1091 reference. (To be compatible with .Net regular expressions, "\g{name}"
1092 may also be written as "\k{name}", "\k<name>" or "\k'name'".) name
1093 must not begin with a number, nor contain hyphens. When different
1094 groups within the same pattern have the same name, any reference to
1095 that name assumes the leftmost defined group. Named groups count in
1096 absolute and relative numbering, and so can also be referred to by
1097 those numbers. (It's possible to do things with named capture groups
1098 that would otherwise require "(??{})".)
1099
1100 Capture group contents are dynamically scoped and available to you
1101 outside the pattern until the end of the enclosing block or until the
1102 next successful match in the same scope, whichever comes first. See
1103 "Compound Statements" in perlsyn and "Scoping Rules of Regex Variables"
1104 in perlvar for more details.
1105
1106 You can access the contents of a capture group by absolute number
1107 (using "$1" instead of "\g1", etc); or by name via the "%+" hash, using
1108 "$+{name}".
1109
1110 Braces are required in referring to named capture groups, but are
1111 optional for absolute or relative numbered ones. Braces are safer when
1112 creating a regex by concatenating smaller strings. For example if you
1113 have "qr/$a$b/", and $a contained "\g1", and $b contained "37", you
1114 would get "/\g137/" which is probably not what you intended.
1115
1116 If you use braces, you may also optionally add any number of blank
1117 (space or tab) characters within but adjacent to the braces, like
1118 "\g{ -1 }", or "\k{ name }".
1119
1120 The "\g" and "\k" notations were introduced in Perl 5.10.0. Prior to
1121 that there were no named nor relative numbered capture groups.
1122 Absolute numbered groups were referred to using "\1", "\2", etc., and
1123 this notation is still accepted (and likely always will be). But it
1124 leads to some ambiguities if there are more than 9 capture groups, as
1125 "\10" could mean either the tenth capture group, or the character whose
1126 ordinal in octal is 010 (a backspace in ASCII). Perl resolves this
1127 ambiguity by interpreting "\10" as a backreference only if at least 10
1128 left parentheses have opened before it. Likewise "\11" is a
1129 backreference only if at least 11 left parentheses have opened before
1130 it. And so on. "\1" through "\9" are always interpreted as
1131 backreferences. There are several examples below that illustrate these
1132 perils. You can avoid the ambiguity by always using "\g{}" or "\g" if
1133 you mean capturing groups; and for octal constants always using "\o{}",
1134 or for "\077" and below, using 3 digits padded with leading zeros,
1135 since a leading zero implies an octal constant.
1136
1137 The "\digit" notation also works in certain circumstances outside the
1138 pattern. See "Warning on \1 Instead of $1" below for details.
1139
1140 Examples:
1141
1142 s/^([^ ]*) *([^ ]*)/$2 $1/; # swap first two words
1143
1144 /(.)\g1/ # find first doubled char
1145 and print "'$1' is the first doubled character\n";
1146
1147 /(?<char>.)\k<char>/ # ... a different way
1148 and print "'$+{char}' is the first doubled character\n";
1149
1150 /(?'char'.)\g1/ # ... mix and match
1151 and print "'$1' is the first doubled character\n";
1152
1153 if (/Time: (..):(..):(..)/) { # parse out values
1154 $hours = $1;
1155 $minutes = $2;
1156 $seconds = $3;
1157 }
1158
1159 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/ # \g10 is a backreference
1160 /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/ # \10 is octal
1161 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/ # \10 is a backreference
1162 /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1163
1164 $a = '(.)\1'; # Creates problems when concatenated.
1165 $b = '(.)\g{1}'; # Avoids the problems.
1166 "aa" =~ /${a}/; # True
1167 "aa" =~ /${b}/; # True
1168 "aa0" =~ /${a}0/; # False!
1169 "aa0" =~ /${b}0/; # True
1170 "aa\x08" =~ /${a}0/; # True!
1171 "aa\x08" =~ /${b}0/; # False
1172
1173 Several special variables also refer back to portions of the previous
1174 match. $+ returns whatever the last bracket match matched. $& returns
1175 the entire matched string. (At one point $0 did also, but now it
1176 returns the name of the program.) "$`" returns everything before the
1177 matched string. "$'" returns everything after the matched string. And
1178 $^N contains whatever was matched by the most-recently closed group
1179 (submatch). $^N can be used in extended patterns (see below), for
1180 example to assign a submatch to a variable.
1181
1182 These special variables, like the "%+" hash and the numbered match
1183 variables ($1, $2, $3, etc.) are dynamically scoped until the end of
1184 the enclosing block or until the next successful match, whichever comes
1185 first. (See "Compound Statements" in perlsyn.)
1186
1187 The "@{^CAPTURE}" array may be used to access ALL of the capture
1188 buffers as an array without needing to know how many there are. For
1189 instance
1190
1191 $string=~/$pattern/ and @captured = @{^CAPTURE};
1192
1193 will place a copy of each capture variable, $1, $2 etc, into the
1194 @captured array.
1195
1196 Be aware that when interpolating a subscript of the "@{^CAPTURE}" array
1197 you must use demarcated curly brace notation:
1198
1199 print "@{^CAPTURE[0]}";
1200
1201 See "Demarcated variable names using braces" in perldata for more on
1202 this notation.
1203
1204 NOTE: Failed matches in Perl do not reset the match variables, which
1205 makes it easier to write code that tests for a series of more specific
1206 cases and remembers the best match.
1207
1208 WARNING: If your code is to run on Perl 5.16 or earlier, beware that
1209 once Perl sees that you need one of $&, "$`", or "$'" anywhere in the
1210 program, it has to provide them for every pattern match. This may
1211 substantially slow your program.
1212
1213 Perl uses the same mechanism to produce $1, $2, etc, so you also pay a
1214 price for each pattern that contains capturing parentheses. (To avoid
1215 this cost while retaining the grouping behaviour, use the extended
1216 regular expression "(?: ... )" instead.) But if you never use $&, "$`"
1217 or "$'", then patterns without capturing parentheses will not be
1218 penalized. So avoid $&, "$'", and "$`" if you can, but if you can't
1219 (and some algorithms really appreciate them), once you've used them
1220 once, use them at will, because you've already paid the price.
1221
1222 Perl 5.16 introduced a slightly more efficient mechanism that notes
1223 separately whether each of "$`", $&, and "$'" have been seen, and thus
1224 may only need to copy part of the string. Perl 5.20 introduced a much
1225 more efficient copy-on-write mechanism which eliminates any slowdown.
1226
1227 As another workaround for this problem, Perl 5.10.0 introduced
1228 "${^PREMATCH}", "${^MATCH}" and "${^POSTMATCH}", which are equivalent
1229 to "$`", $& and "$'", except that they are only guaranteed to be
1230 defined after a successful match that was executed with the "/p"
1231 (preserve) modifier. The use of these variables incurs no global
1232 performance penalty, unlike their punctuation character equivalents,
1233 however at the trade-off that you have to tell perl when you want to
1234 use them. As of Perl 5.20, these three variables are equivalent to
1235 "$`", $& and "$'", and "/p" is ignored.
1236
1237 Quoting metacharacters
1238 Backslashed metacharacters in Perl are alphanumeric, such as "\b",
1239 "\w", "\n". Unlike some other regular expression languages, there are
1240 no backslashed symbols that aren't alphanumeric. So anything that
1241 looks like "\\", "\(", "\)", "\[", "\]", "\{", or "\}" is always
1242 interpreted as a literal character, not a metacharacter. This was once
1243 used in a common idiom to disable or quote the special meanings of
1244 regular expression metacharacters in a string that you want to use for
1245 a pattern. Simply quote all non-"word" characters:
1246
1247 $pattern =~ s/(\W)/\\$1/g;
1248
1249 (If "use locale" is set, then this depends on the current locale.)
1250 Today it is more common to use the quotemeta() function or the "\Q"
1251 metaquoting escape sequence to disable all metacharacters' special
1252 meanings like this:
1253
1254 /$unquoted\Q$quoted\E$unquoted/
1255
1256 Beware that if you put literal backslashes (those not inside
1257 interpolated variables) between "\Q" and "\E", double-quotish backslash
1258 interpolation may lead to confusing results. If you need to use
1259 literal backslashes within "\Q...\E", consult "Gory details of parsing
1260 quoted constructs" in perlop.
1261
1262 quotemeta() and "\Q" are fully described in "quotemeta" in perlfunc.
1263
1264 Extended Patterns
1265 Perl also defines a consistent extension syntax for features not found
1266 in standard tools like awk and lex. The syntax for most of these is a
1267 pair of parentheses with a question mark as the first thing within the
1268 parentheses. The character after the question mark indicates the
1269 extension.
1270
1271 A question mark was chosen for this and for the minimal-matching
1272 construct because 1) question marks are rare in older regular
1273 expressions, and 2) whenever you see one, you should stop and
1274 "question" exactly what is going on. That's psychology....
1275
1276 "(?#text)"
1277 A comment. The text is ignored. Note that Perl closes the comment
1278 as soon as it sees a ")", so there is no way to put a literal ")"
1279 in the comment. The pattern's closing delimiter must be escaped by
1280 a backslash if it appears in the comment.
1281
1282 See "/x" for another way to have comments in patterns.
1283
1284 Note that a comment can go just about anywhere, except in the
1285 middle of an escape sequence. Examples:
1286
1287 qr/foo(?#comment)bar/' # Matches 'foobar'
1288
1289 # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1290 qr/abc(?#comment between literal and its quantifier){1,3}d/
1291
1292 # The pattern below generates a syntax error, because the '\p' must
1293 # be followed immediately by a '{'.
1294 qr/\p(?#comment between \p and its property name){Any}/
1295
1296 # The pattern below generates a syntax error, because the initial
1297 # '\(' is a literal opening parenthesis, and so there is nothing
1298 # for the closing ')' to match
1299 qr/\(?#the backslash means this isn't a comment)p{Any}/
1300
1301 # Comments can be used to fold long patterns into multiple lines
1302 qr/First part of a long regex(?#
1303 )remaining part/
1304
1305 "(?adlupimnsx-imnsx)"
1306 "(?^alupimnsx)"
1307 Zero or more embedded pattern-match modifiers, to be turned on (or
1308 turned off if preceded by "-") for the remainder of the pattern or
1309 the remainder of the enclosing pattern group (if any).
1310
1311 This is particularly useful for dynamically-generated patterns,
1312 such as those read in from a configuration file, taken from an
1313 argument, or specified in a table somewhere. Consider the case
1314 where some patterns want to be case-sensitive and some do not: The
1315 case-insensitive ones merely need to include "(?i)" at the front of
1316 the pattern. For example:
1317
1318 $pattern = "foobar";
1319 if ( /$pattern/i ) { }
1320
1321 # more flexible:
1322
1323 $pattern = "(?i)foobar";
1324 if ( /$pattern/ ) { }
1325
1326 These modifiers are restored at the end of the enclosing group. For
1327 example,
1328
1329 ( (?i) blah ) \s+ \g1
1330
1331 will match "blah" in any case, some spaces, and an exact (including
1332 the case!) repetition of the previous word, assuming the "/x"
1333 modifier, and no "/i" modifier outside this group.
1334
1335 These modifiers do not carry over into named subpatterns called in
1336 the enclosing group. In other words, a pattern such as
1337 "((?i)(?&NAME))" does not change the case-sensitivity of the NAME
1338 pattern.
1339
1340 A modifier is overridden by later occurrences of this construct in
1341 the same scope containing the same modifier, so that
1342
1343 /((?im)foo(?-m)bar)/
1344
1345 matches all of "foobar" case insensitively, but uses "/m" rules for
1346 only the "foo" portion. The "a" flag overrides "aa" as well;
1347 likewise "aa" overrides "a". The same goes for "x" and "xx".
1348 Hence, in
1349
1350 /(?-x)foo/xx
1351
1352 both "/x" and "/xx" are turned off during matching "foo". And in
1353
1354 /(?x)foo/x
1355
1356 "/x" but NOT "/xx" is turned on for matching "foo". (One might
1357 mistakenly think that since the inner "(?x)" is already in the
1358 scope of "/x", that the result would effectively be the sum of
1359 them, yielding "/xx". It doesn't work that way.) Similarly, doing
1360 something like "(?xx-x)foo" turns off all "x" behavior for matching
1361 "foo", it is not that you subtract 1 "x" from 2 to get 1 "x"
1362 remaining.
1363
1364 Any of these modifiers can be set to apply globally to all regular
1365 expressions compiled within the scope of a "use re". See "'/flags'
1366 mode" in re.
1367
1368 Starting in Perl 5.14, a "^" (caret or circumflex accent)
1369 immediately after the "?" is a shorthand equivalent to "d-imnsx".
1370 Flags (except "d") may follow the caret to override it. But a
1371 minus sign is not legal with it.
1372
1373 Note that the "a", "d", "l", "p", and "u" modifiers are special in
1374 that they can only be enabled, not disabled, and the "a", "d", "l",
1375 and "u" modifiers are mutually exclusive: specifying one de-
1376 specifies the others, and a maximum of one (or two "a"'s) may
1377 appear in the construct. Thus, for example, "(?-p)" will warn when
1378 compiled under "use warnings"; "(?-d:...)" and "(?dl:...)" are
1379 fatal errors.
1380
1381 Note also that the "p" modifier is special in that its presence
1382 anywhere in a pattern has a global effect.
1383
1384 Having zero modifiers makes this a no-op (so why did you specify
1385 it, unless it's generated code), and starting in v5.30, warns under
1386 "use re 'strict'".
1387
1388 "(?:pattern)"
1389 "(?adluimnsx-imnsx:pattern)"
1390 "(?^aluimnsx:pattern)"
1391 This is for clustering, not capturing; it groups subexpressions
1392 like "()", but doesn't make backreferences as "()" does. So
1393
1394 @fields = split(/\b(?:a|b|c)\b/)
1395
1396 matches the same field delimiters as
1397
1398 @fields = split(/\b(a|b|c)\b/)
1399
1400 but doesn't spit out the delimiters themselves as extra fields
1401 (even though that's the behaviour of "split" in perlfunc when its
1402 pattern contains capturing groups). It's also cheaper not to
1403 capture characters if you don't need to.
1404
1405 Any letters between "?" and ":" act as flags modifiers as with
1406 "(?adluimnsx-imnsx)". For example,
1407
1408 /(?s-i:more.*than).*million/i
1409
1410 is equivalent to the more verbose
1411
1412 /(?:(?s-i)more.*than).*million/i
1413
1414 Note that any "()" constructs enclosed within this one will still
1415 capture unless the "/n" modifier is in effect.
1416
1417 Like the "(?adlupimnsx-imnsx)" construct, "aa" and "a" override
1418 each other, as do "xx" and "x". They are not additive. So, doing
1419 something like "(?xx-x:foo)" turns off all "x" behavior for
1420 matching "foo".
1421
1422 Starting in Perl 5.14, a "^" (caret or circumflex accent)
1423 immediately after the "?" is a shorthand equivalent to "d-imnsx".
1424 Any positive flags (except "d") may follow the caret, so
1425
1426 (?^x:foo)
1427
1428 is equivalent to
1429
1430 (?x-imns:foo)
1431
1432 The caret tells Perl that this cluster doesn't inherit the flags of
1433 any surrounding pattern, but uses the system defaults ("d-imnsx"),
1434 modified by any flags specified.
1435
1436 The caret allows for simpler stringification of compiled regular
1437 expressions. These look like
1438
1439 (?^:pattern)
1440
1441 with any non-default flags appearing between the caret and the
1442 colon. A test that looks at such stringification thus doesn't need
1443 to have the system default flags hard-coded in it, just the caret.
1444 If new flags are added to Perl, the meaning of the caret's
1445 expansion will change to include the default for those flags, so
1446 the test will still work, unchanged.
1447
1448 Specifying a negative flag after the caret is an error, as the flag
1449 is redundant.
1450
1451 Mnemonic for "(?^...)": A fresh beginning since the usual use of a
1452 caret is to match at the beginning.
1453
1454 "(?|pattern)"
1455 This is the "branch reset" pattern, which has the special property
1456 that the capture groups are numbered from the same starting point
1457 in each alternation branch. It is available starting from perl
1458 5.10.0.
1459
1460 Capture groups are numbered from left to right, but inside this
1461 construct the numbering is restarted for each branch.
1462
1463 The numbering within each branch will be as normal, and any groups
1464 following this construct will be numbered as though the construct
1465 contained only one branch, that being the one with the most capture
1466 groups in it.
1467
1468 This construct is useful when you want to capture one of a number
1469 of alternative matches.
1470
1471 Consider the following pattern. The numbers underneath show in
1472 which group the captured content will be stored.
1473
1474 # before ---------------branch-reset----------- after
1475 / ( a ) (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1476 # 1 2 2 3 2 3 4
1477
1478 Be careful when using the branch reset pattern in combination with
1479 named captures. Named captures are implemented as being aliases to
1480 numbered groups holding the captures, and that interferes with the
1481 implementation of the branch reset pattern. If you are using named
1482 captures in a branch reset pattern, it's best to use the same
1483 names, in the same order, in each of the alternations:
1484
1485 /(?| (?<a> x ) (?<b> y )
1486 | (?<a> z ) (?<b> w )) /x
1487
1488 Not doing so may lead to surprises:
1489
1490 "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1491 say $+{a}; # Prints '12'
1492 say $+{b}; # *Also* prints '12'.
1493
1494 The problem here is that both the group named "a" and the group
1495 named "b" are aliases for the group belonging to $1.
1496
1497 Lookaround Assertions
1498 Lookaround assertions are zero-width patterns which match a
1499 specific pattern without including it in $&. Positive assertions
1500 match when their subpattern matches, negative assertions match when
1501 their subpattern fails. Lookbehind matches text up to the current
1502 match position, lookahead matches text following the current match
1503 position.
1504
1505 "(?=pattern)"
1506 "(*pla:pattern)"
1507 "(*positive_lookahead:pattern)"
1508 A zero-width positive lookahead assertion. For example,
1509 "/\w+(?=\t)/" matches a word followed by a tab, without
1510 including the tab in $&.
1511
1512 "(?!pattern)"
1513 "(*nla:pattern)"
1514 "(*negative_lookahead:pattern)"
1515 A zero-width negative lookahead assertion. For example
1516 "/foo(?!bar)/" matches any occurrence of "foo" that isn't
1517 followed by "bar". Note however that lookahead and lookbehind
1518 are NOT the same thing. You cannot use this for lookbehind.
1519
1520 If you are looking for a "bar" that isn't preceded by a "foo",
1521 "/(?!foo)bar/" will not do what you want. That's because the
1522 "(?!foo)" is just saying that the next thing cannot be
1523 "foo"--and it's not, it's a "bar", so "foobar" will match. Use
1524 lookbehind instead (see below).
1525
1526 "(?<=pattern)"
1527 "\K"
1528 "(*plb:pattern)"
1529 "(*positive_lookbehind:pattern)"
1530 A zero-width positive lookbehind assertion. For example,
1531 "/(?<=\t)\w+/" matches a word that follows a tab, without
1532 including the tab in $&.
1533
1534 Prior to Perl 5.30, it worked only for fixed-width lookbehind,
1535 but starting in that release, it can handle variable lengths
1536 from 1 to 255 characters as an experimental feature. The
1537 feature is enabled automatically if you use a variable length
1538 positive lookbehind assertion.
1539
1540 In Perl 5.35.10 the scope of the experimental nature of this
1541 construct has been reduced, and experimental warnings will only
1542 be produced when the construct contains capturing parenthesis.
1543 The warnings will be raised at pattern compilation time, unless
1544 turned off, in the "experimental::vlb" category. This is to
1545 warn you that the exact contents of capturing buffers in a
1546 variable length positive lookbehind is not well defined and is
1547 subject to change in a future release of perl.
1548
1549 Currently if you use capture buffers inside of a positive
1550 variable length lookbehind the result will be the longest and
1551 thus leftmost match possible. This means that
1552
1553 "aax" =~ /(?=x)(?<=(a|aa))/
1554 "aax" =~ /(?=x)(?<=(aa|a))/
1555 "aax" =~ /(?=x)(?<=(a{1,2}?)/
1556 "aax" =~ /(?=x)(?<=(a{1,2})/
1557
1558 will all result in $1 containing "aa". It is possible in a
1559 future release of perl we will change this behavior.
1560
1561 There is a special form of this construct, called "\K"
1562 (available since Perl 5.10.0), which causes the regex engine to
1563 "keep" everything it had matched prior to the "\K" and not
1564 include it in $&. This effectively provides non-experimental
1565 variable-length lookbehind of any length.
1566
1567 And, there is a technique that can be used to handle variable
1568 length lookbehinds on earlier releases, and longer than 255
1569 characters. It is described in
1570 <http://www.drregex.com/2019/02/variable-length-lookbehinds-actually.html>.
1571
1572 Note that under "/i", a few single characters match two or
1573 three other characters. This makes them variable length, and
1574 the 255 length applies to the maximum number of characters in
1575 the match. For example "qr/\N{LATIN SMALL LETTER SHARP S}/i"
1576 matches the sequence "ss". Your lookbehind assertion could
1577 contain 127 Sharp S characters under "/i", but adding a 128th
1578 would generate a compilation error, as that could match 256 "s"
1579 characters in a row.
1580
1581 The use of "\K" inside of another lookaround assertion is
1582 allowed, but the behaviour is currently not well defined.
1583
1584 For various reasons "\K" may be significantly more efficient
1585 than the equivalent "(?<=...)" construct, and it is especially
1586 useful in situations where you want to efficiently remove
1587 something following something else in a string. For instance
1588
1589 s/(foo)bar/$1/g;
1590
1591 can be rewritten as the much more efficient
1592
1593 s/foo\Kbar//g;
1594
1595 Use of the non-greedy modifier "?" may not give you the
1596 expected results if it is within a capturing group within the
1597 construct.
1598
1599 "(?<!pattern)"
1600 "(*nlb:pattern)"
1601 "(*negative_lookbehind:pattern)"
1602 A zero-width negative lookbehind assertion. For example
1603 "/(?<!bar)foo/" matches any occurrence of "foo" that does not
1604 follow "bar".
1605
1606 Prior to Perl 5.30, it worked only for fixed-width lookbehind,
1607 but starting in that release, it can handle variable lengths
1608 from 1 to 255 characters as an experimental feature. The
1609 feature is enabled automatically if you use a variable length
1610 negative lookbehind assertion.
1611
1612 In Perl 5.35.10 the scope of the experimental nature of this
1613 construct has been reduced, and experimental warnings will only
1614 be produced when the construct contains capturing parentheses.
1615 The warnings will be raised at pattern compilation time, unless
1616 turned off, in the "experimental::vlb" category. This is to
1617 warn you that the exact contents of capturing buffers in a
1618 variable length negative lookbehind is not well defined and is
1619 subject to change in a future release of perl.
1620
1621 Currently if you use capture buffers inside of a negative
1622 variable length lookbehind the result may not be what you
1623 expect, for instance:
1624
1625 say "axfoo"=~/(?=foo)(?<!(a|ax)(?{ say $1 }))/ ? "y" : "n";
1626
1627 will output the following:
1628
1629 a
1630 no
1631
1632 which does not make sense as this should print out "ax" as the
1633 "a" does not line up at the correct place. Another example
1634 would be:
1635
1636 say "yes: '$1-$2'" if "aayfoo"=~/(?=foo)(?<!(a|aa)(a|aa)x)/;
1637
1638 will output the following:
1639
1640 yes: 'aa-a'
1641
1642 It is possible in a future release of perl we will change this
1643 behavior so both of these examples produced more reasonable
1644 output.
1645
1646 Note that we are confident that the construct will match and
1647 reject patterns appropriately, the undefined behavior strictly
1648 relates to the value of the capture buffer during or after
1649 matching.
1650
1651 There is a technique that can be used to handle variable length
1652 lookbehind on earlier releases, and longer than 255 characters.
1653 It is described in
1654 <http://www.drregex.com/2019/02/variable-length-lookbehinds-actually.html>.
1655
1656 Note that under "/i", a few single characters match two or
1657 three other characters. This makes them variable length, and
1658 the 255 length applies to the maximum number of characters in
1659 the match. For example "qr/\N{LATIN SMALL LETTER SHARP S}/i"
1660 matches the sequence "ss". Your lookbehind assertion could
1661 contain 127 Sharp S characters under "/i", but adding a 128th
1662 would generate a compilation error, as that could match 256 "s"
1663 characters in a row.
1664
1665 Use of the non-greedy modifier "?" may not give you the
1666 expected results if it is within a capturing group within the
1667 construct.
1668
1669 "(?<NAME>pattern)"
1670 "(?'NAME'pattern)"
1671 A named capture group. Identical in every respect to normal
1672 capturing parentheses "()" but for the additional fact that the
1673 group can be referred to by name in various regular expression
1674 constructs (like "\g{NAME}") and can be accessed by name after a
1675 successful match via "%+" or "%-". See perlvar for more details on
1676 the "%+" and "%-" hashes.
1677
1678 If multiple distinct capture groups have the same name, then
1679 $+{NAME} will refer to the leftmost defined group in the match.
1680
1681 The forms "(?'NAME'pattern)" and "(?<NAME>pattern)" are equivalent.
1682
1683 NOTE: While the notation of this construct is the same as the
1684 similar function in .NET regexes, the behavior is not. In Perl the
1685 groups are numbered sequentially regardless of being named or not.
1686 Thus in the pattern
1687
1688 /(x)(?<foo>y)(z)/
1689
1690 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1691 the opposite which is what a .NET regex hacker might expect.
1692
1693 Currently NAME is restricted to simple identifiers only. In other
1694 words, it must match "/^[_A-Za-z][_A-Za-z0-9]*\z/" or its Unicode
1695 extension (see utf8), though it isn't extended by the locale (see
1696 perllocale).
1697
1698 NOTE: In order to make things easier for programmers with
1699 experience with the Python or PCRE regex engines, the pattern
1700 "(?P<NAME>pattern)" may be used instead of "(?<NAME>pattern)";
1701 however this form does not support the use of single quotes as a
1702 delimiter for the name.
1703
1704 "\k<NAME>"
1705 "\k'NAME'"
1706 "\k{NAME}"
1707 Named backreference. Similar to numeric backreferences, except that
1708 the group is designated by name and not number. If multiple groups
1709 have the same name then it refers to the leftmost defined group in
1710 the current match.
1711
1712 It is an error to refer to a name not defined by a "(?<NAME>)"
1713 earlier in the pattern.
1714
1715 All three forms are equivalent, although with "\k{ NAME }", you may
1716 optionally have blanks within but adjacent to the braces, as shown.
1717
1718 NOTE: In order to make things easier for programmers with
1719 experience with the Python or PCRE regex engines, the pattern
1720 "(?P=NAME)" may be used instead of "\k<NAME>".
1721
1722 "(?{ code })"
1723 WARNING: Using this feature safely requires that you understand its
1724 limitations. Code executed that has side effects may not perform
1725 identically from version to version due to the effect of future
1726 optimisations in the regex engine. For more information on this,
1727 see "Embedded Code Execution Frequency".
1728
1729 This zero-width assertion executes any embedded Perl code. It
1730 always succeeds, and its return value is set as $^R.
1731
1732 In literal patterns, the code is parsed at the same time as the
1733 surrounding code. While within the pattern, control is passed
1734 temporarily back to the perl parser, until the logically-balancing
1735 closing brace is encountered. This is similar to the way that an
1736 array index expression in a literal string is handled, for example
1737
1738 "abc$array[ 1 + f('[') + g()]def"
1739
1740 In particular, braces do not need to be balanced:
1741
1742 s/abc(?{ f('{'); })/def/
1743
1744 Even in a pattern that is interpolated and compiled at run-time,
1745 literal code blocks will be compiled once, at perl compile time;
1746 the following prints "ABCD":
1747
1748 print "D";
1749 my $qr = qr/(?{ BEGIN { print "A" } })/;
1750 my $foo = "foo";
1751 /$foo$qr(?{ BEGIN { print "B" } })/;
1752 BEGIN { print "C" }
1753
1754 In patterns where the text of the code is derived from run-time
1755 information rather than appearing literally in a source code
1756 /pattern/, the code is compiled at the same time that the pattern
1757 is compiled, and for reasons of security, "use re 'eval'" must be
1758 in scope. This is to stop user-supplied patterns containing code
1759 snippets from being executable.
1760
1761 In situations where you need to enable this with "use re 'eval'",
1762 you should also have taint checking enabled, if your perl supports
1763 it. Better yet, use the carefully constrained evaluation within a
1764 Safe compartment. See perlsec for details about both these
1765 mechanisms.
1766
1767 From the viewpoint of parsing, lexical variable scope and closures,
1768
1769 /AAA(?{ BBB })CCC/
1770
1771 behaves approximately like
1772
1773 /AAA/ && do { BBB } && /CCC/
1774
1775 Similarly,
1776
1777 qr/AAA(?{ BBB })CCC/
1778
1779 behaves approximately like
1780
1781 sub { /AAA/ && do { BBB } && /CCC/ }
1782
1783 In particular:
1784
1785 { my $i = 1; $r = qr/(?{ print $i })/ }
1786 my $i = 2;
1787 /$r/; # prints "1"
1788
1789 Inside a "(?{...})" block, $_ refers to the string the regular
1790 expression is matching against. You can also use pos() to know what
1791 is the current position of matching within this string.
1792
1793 The code block introduces a new scope from the perspective of
1794 lexical variable declarations, but not from the perspective of
1795 "local" and similar localizing behaviours. So later code blocks
1796 within the same pattern will still see the values which were
1797 localized in earlier blocks. These accumulated localizations are
1798 undone either at the end of a successful match, or if the assertion
1799 is backtracked (compare "Backtracking"). For example,
1800
1801 $_ = 'a' x 8;
1802 m<
1803 (?{ $cnt = 0 }) # Initialize $cnt.
1804 (
1805 a
1806 (?{
1807 local $cnt = $cnt + 1; # Update $cnt,
1808 # backtracking-safe.
1809 })
1810 )*
1811 aaaa
1812 (?{ $res = $cnt }) # On success copy to
1813 # non-localized location.
1814 >x;
1815
1816 will initially increment $cnt up to 8; then during backtracking,
1817 its value will be unwound back to 4, which is the value assigned to
1818 $res. At the end of the regex execution, $cnt will be wound back
1819 to its initial value of 0.
1820
1821 This assertion may be used as the condition in a
1822
1823 (?(condition)yes-pattern|no-pattern)
1824
1825 switch. If not used in this way, the result of evaluation of code
1826 is put into the special variable $^R. This happens immediately, so
1827 $^R can be used from other "(?{ code })" assertions inside the same
1828 regular expression.
1829
1830 The assignment to $^R above is properly localized, so the old value
1831 of $^R is restored if the assertion is backtracked; compare
1832 "Backtracking".
1833
1834 Note that the special variable $^N is particularly useful with
1835 code blocks to capture the results of submatches in variables
1836 without having to keep track of the number of nested parentheses.
1837 For example:
1838
1839 $_ = "The brown fox jumps over the lazy dog";
1840 /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1841 print "color = $color, animal = $animal\n";
1842
1843 The use of this construct disables some optimisations globally in
1844 the pattern, and the pattern may execute much slower as a
1845 consequence. Use a "*" instead of the "?" block to create an
1846 optimistic form of this construct. "(*{ ... })" should not disable
1847 any optimisations.
1848
1849 "(*{ code })"
1850 This is *exactly* the same as "(?{ code })" with the exception that
1851 it does not disable any optimisations at all in the regex engine.
1852 How often it is executed may vary from perl release to perl
1853 release. In a failing match it may not even be executed at all.
1854
1855 "(??{ code })"
1856 WARNING: Using this feature safely requires that you understand its
1857 limitations. Code executed that has side effects may not perform
1858 identically from version to version due to the effect of future
1859 optimisations in the regex engine. For more information on this,
1860 see "Embedded Code Execution Frequency".
1861
1862 This is a "postponed" regular subexpression. It behaves in exactly
1863 the same way as a "(?{ code })" code block as described above,
1864 except that its return value, rather than being assigned to $^R, is
1865 treated as a pattern, compiled if it's a string (or used as-is if
1866 its a qr// object), then matched as if it were inserted instead of
1867 this construct.
1868
1869 During the matching of this sub-pattern, it has its own set of
1870 captures which are valid during the sub-match, but are discarded
1871 once control returns to the main pattern. For example, the
1872 following matches, with the inner pattern capturing "B" and
1873 matching "BB", while the outer pattern captures "A";
1874
1875 my $inner = '(.)\1';
1876 "ABBA" =~ /^(.)(??{ $inner })\1/;
1877 print $1; # prints "A";
1878
1879 Note that this means that there is no way for the inner pattern to
1880 refer to a capture group defined outside. (The code block itself
1881 can use $1, etc., to refer to the enclosing pattern's capture
1882 groups.) Thus, although
1883
1884 ('a' x 100)=~/(??{'(.)' x 100})/
1885
1886 will match, it will not set $1 on exit.
1887
1888 The following pattern matches a parenthesized group:
1889
1890 $re = qr{
1891 \(
1892 (?:
1893 (?> [^()]+ ) # Non-parens without backtracking
1894 |
1895 (??{ $re }) # Group with matching parens
1896 )*
1897 \)
1898 }x;
1899
1900 See also "(?PARNO)" for a different, more efficient way to
1901 accomplish the same task.
1902
1903 Executing a postponed regular expression too many times without
1904 consuming any input string will also result in a fatal error. The
1905 depth at which that happens is compiled into perl, so it can be
1906 changed with a custom build.
1907
1908 The use of this construct disables some optimisations globally in
1909 the pattern, and the pattern may execute much slower as a
1910 consequence.
1911
1912 "(?PARNO)" "(?-PARNO)" "(?+PARNO)" "(?R)" "(?0)"
1913 Recursive subpattern. Treat the contents of a given capture buffer
1914 in the current pattern as an independent subpattern and attempt to
1915 match it at the current position in the string. Information about
1916 capture state from the caller for things like backreferences is
1917 available to the subpattern, but capture buffers set by the
1918 subpattern are not visible to the caller.
1919
1920 Similar to "(??{ code })" except that it does not involve executing
1921 any code or potentially compiling a returned pattern string;
1922 instead it treats the part of the current pattern contained within
1923 a specified capture group as an independent pattern that must match
1924 at the current position. Also different is the treatment of capture
1925 buffers, unlike "(??{ code })" recursive patterns have access to
1926 their caller's match state, so one can use backreferences safely.
1927
1928 PARNO is a sequence of digits (not starting with 0) whose value
1929 reflects the paren-number of the capture group to recurse to.
1930 "(?R)" recurses to the beginning of the whole pattern. "(?0)" is an
1931 alternate syntax for "(?R)". If PARNO is preceded by a plus or
1932 minus sign then it is assumed to be relative, with negative numbers
1933 indicating preceding capture groups and positive ones following.
1934 Thus "(?-1)" refers to the most recently declared group, and
1935 "(?+1)" indicates the next group to be declared. Note that the
1936 counting for relative recursion differs from that of relative
1937 backreferences, in that with recursion unclosed groups are
1938 included.
1939
1940 The following pattern matches a function foo() which may contain
1941 balanced parentheses as the argument.
1942
1943 $re = qr{ ( # paren group 1 (full function)
1944 foo
1945 ( # paren group 2 (parens)
1946 \(
1947 ( # paren group 3 (contents of parens)
1948 (?:
1949 (?> [^()]+ ) # Non-parens without backtracking
1950 |
1951 (?2) # Recurse to start of paren group 2
1952 )*
1953 )
1954 \)
1955 )
1956 )
1957 }x;
1958
1959 If the pattern was used as follows
1960
1961 'foo(bar(baz)+baz(bop))'=~/$re/
1962 and print "\$1 = $1\n",
1963 "\$2 = $2\n",
1964 "\$3 = $3\n";
1965
1966 the output produced should be the following:
1967
1968 $1 = foo(bar(baz)+baz(bop))
1969 $2 = (bar(baz)+baz(bop))
1970 $3 = bar(baz)+baz(bop)
1971
1972 If there is no corresponding capture group defined, then it is a
1973 fatal error. Recursing deeply without consuming any input string
1974 will also result in a fatal error. The depth at which that happens
1975 is compiled into perl, so it can be changed with a custom build.
1976
1977 The following shows how using negative indexing can make it easier
1978 to embed recursive patterns inside of a "qr//" construct for later
1979 use:
1980
1981 my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1982 if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1983 # do something here...
1984 }
1985
1986 Note that this pattern does not behave the same way as the
1987 equivalent PCRE or Python construct of the same form. In Perl you
1988 can backtrack into a recursed group, in PCRE and Python the
1989 recursed into group is treated as atomic. Also, modifiers are
1990 resolved at compile time, so constructs like "(?i:(?1))" or
1991 "(?:(?i)(?1))" do not affect how the sub-pattern will be processed.
1992
1993 "(?&NAME)"
1994 Recurse to a named subpattern. Identical to "(?PARNO)" except that
1995 the parenthesis to recurse to is determined by name. If multiple
1996 parentheses have the same name, then it recurses to the leftmost.
1997
1998 It is an error to refer to a name that is not declared somewhere in
1999 the pattern.
2000
2001 NOTE: In order to make things easier for programmers with
2002 experience with the Python or PCRE regex engines the pattern
2003 "(?P>NAME)" may be used instead of "(?&NAME)".
2004
2005 "(?(condition)yes-pattern|no-pattern)"
2006 "(?(condition)yes-pattern)"
2007 Conditional expression. Matches yes-pattern if condition yields a
2008 true value, matches no-pattern otherwise. A missing pattern always
2009 matches.
2010
2011 "(condition)" should be one of:
2012
2013 an integer in parentheses
2014 (which is valid if the corresponding pair of parentheses
2015 matched);
2016
2017 a lookahead/lookbehind/evaluate zero-width assertion;
2018 a name in angle brackets or single quotes
2019 (which is valid if a group with the given name matched);
2020
2021 the special symbol "(R)"
2022 (true when evaluated inside of recursion or eval).
2023 Additionally the "R" may be followed by a number, (which will
2024 be true when evaluated when recursing inside of the appropriate
2025 group), or by "&NAME", in which case it will be true only when
2026 evaluated during recursion in the named group.
2027
2028 Here's a summary of the possible predicates:
2029
2030 "(1)" "(2)" ...
2031 Checks if the numbered capturing group has matched something.
2032 Full syntax: "(?(1)then|else)"
2033
2034 "(<NAME>)" "('NAME')"
2035 Checks if a group with the given name has matched something.
2036 Full syntax: "(?(<name>)then|else)"
2037
2038 "(?=...)" "(?!...)" "(?<=...)" "(?<!...)"
2039 Checks whether the pattern matches (or does not match, for the
2040 "!" variants). Full syntax: "(?(?=lookahead)then|else)"
2041
2042 "(?{ CODE })"
2043 Treats the return value of the code block as the condition.
2044 Full syntax: "(?(?{ CODE })then|else)"
2045
2046 Note use of this construct may globally affect the performance
2047 of the pattern. Consider using "(*{ CODE })"
2048
2049 "(*{ CODE })"
2050 Treats the return value of the code block as the condition.
2051 Full syntax: "(?(*{ CODE })then|else)"
2052
2053 "(R)"
2054 Checks if the expression has been evaluated inside of
2055 recursion. Full syntax: "(?(R)then|else)"
2056
2057 "(R1)" "(R2)" ...
2058 Checks if the expression has been evaluated while executing
2059 directly inside of the n-th capture group. This check is the
2060 regex equivalent of
2061
2062 if ((caller(0))[3] eq 'subname') { ... }
2063
2064 In other words, it does not check the full recursion stack.
2065
2066 Full syntax: "(?(R1)then|else)"
2067
2068 "(R&NAME)"
2069 Similar to "(R1)", this predicate checks to see if we're
2070 executing directly inside of the leftmost group with a given
2071 name (this is the same logic used by "(?&NAME)" to
2072 disambiguate). It does not check the full stack, but only the
2073 name of the innermost active recursion. Full syntax:
2074 "(?(R&name)then|else)"
2075
2076 "(DEFINE)"
2077 In this case, the yes-pattern is never directly executed, and
2078 no no-pattern is allowed. Similar in spirit to "(?{0})" but
2079 more efficient. See below for details. Full syntax:
2080 "(?(DEFINE)definitions...)"
2081
2082 For example:
2083
2084 m{ ( \( )?
2085 [^()]+
2086 (?(1) \) )
2087 }x
2088
2089 matches a chunk of non-parentheses, possibly included in
2090 parentheses themselves.
2091
2092 A special form is the "(DEFINE)" predicate, which never executes
2093 its yes-pattern directly, and does not allow a no-pattern. This
2094 allows one to define subpatterns which will be executed only by the
2095 recursion mechanism. This way, you can define a set of regular
2096 expression rules that can be bundled into any pattern you choose.
2097
2098 It is recommended that for this usage you put the DEFINE block at
2099 the end of the pattern, and that you name any subpatterns defined
2100 within it.
2101
2102 Also, it's worth noting that patterns defined this way probably
2103 will not be as efficient, as the optimizer is not very clever about
2104 handling them.
2105
2106 An example of how this might be used is as follows:
2107
2108 /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
2109 (?(DEFINE)
2110 (?<NAME_PAT>....)
2111 (?<ADDRESS_PAT>....)
2112 )/x
2113
2114 Note that capture groups matched inside of recursion are not
2115 accessible after the recursion returns, so the extra layer of
2116 capturing groups is necessary. Thus $+{NAME_PAT} would not be
2117 defined even though $+{NAME} would be.
2118
2119 Finally, keep in mind that subpatterns created inside a DEFINE
2120 block count towards the absolute and relative number of captures,
2121 so this:
2122
2123 my @captures = "a" =~ /(.) # First capture
2124 (?(DEFINE)
2125 (?<EXAMPLE> 1 ) # Second capture
2126 )/x;
2127 say scalar @captures;
2128
2129 Will output 2, not 1. This is particularly important if you intend
2130 to compile the definitions with the "qr//" operator, and later
2131 interpolate them in another pattern.
2132
2133 "(?>pattern)"
2134 "(*atomic:pattern)"
2135 An "independent" subexpression, one which matches the substring
2136 that a standalone pattern would match if anchored at the given
2137 position, and it matches nothing other than this substring. This
2138 construct is useful for optimizations of what would otherwise be
2139 "eternal" matches, because it will not backtrack (see
2140 "Backtracking"). It may also be useful in places where the "grab
2141 all you can, and do not give anything back" semantic is desirable.
2142
2143 For example: "^(?>a*)ab" will never match, since "(?>a*)" (anchored
2144 at the beginning of string, as above) will match all characters "a"
2145 at the beginning of string, leaving no "a" for "ab" to match. In
2146 contrast, "a*ab" will match the same as "a+b", since the match of
2147 the subgroup "a*" is influenced by the following group "ab" (see
2148 "Backtracking"). In particular, "a*" inside "a*ab" will match
2149 fewer characters than a standalone "a*", since this makes the tail
2150 match.
2151
2152 "(?>pattern)" does not disable backtracking altogether once it has
2153 matched. It is still possible to backtrack past the construct, but
2154 not into it. So "((?>a*)|(?>b*))ar" will still match "bar".
2155
2156 An effect similar to "(?>pattern)" may be achieved by writing
2157 "(?=(pattern))\g{-1}". This matches the same substring as a
2158 standalone "a+", and the following "\g{-1}" eats the matched
2159 string; it therefore makes a zero-length assertion into an analogue
2160 of "(?>...)". (The difference between these two constructs is that
2161 the second one uses a capturing group, thus shifting ordinals of
2162 backreferences in the rest of a regular expression.)
2163
2164 Consider this pattern:
2165
2166 m{ \(
2167 (
2168 [^()]+ # x+
2169 |
2170 \( [^()]* \)
2171 )+
2172 \)
2173 }x
2174
2175 That will efficiently match a nonempty group with matching
2176 parentheses two levels deep or less. However, if there is no such
2177 group, it will take virtually forever on a long string. That's
2178 because there are so many different ways to split a long string
2179 into several substrings. This is what "(.+)+" is doing, and
2180 "(.+)+" is similar to a subpattern of the above pattern. Consider
2181 how the pattern above detects no-match on "((()aaaaaaaaaaaaaaaaaa"
2182 in several seconds, but that each extra letter doubles this time.
2183 This exponential performance will make it appear that your program
2184 has hung. However, a tiny change to this pattern
2185
2186 m{ \(
2187 (
2188 (?> [^()]+ ) # change x+ above to (?> x+ )
2189 |
2190 \( [^()]* \)
2191 )+
2192 \)
2193 }x
2194
2195 which uses "(?>...)" matches exactly when the one above does
2196 (verifying this yourself would be a productive exercise), but
2197 finishes in a fourth the time when used on a similar string with
2198 1000000 "a"s. Be aware, however, that, when this construct is
2199 followed by a quantifier, it currently triggers a warning message
2200 under the "use warnings" pragma or -w switch saying it "matches
2201 null string many times in regex".
2202
2203 On simple groups, such as the pattern "(?> [^()]+ )", a comparable
2204 effect may be achieved by negative lookahead, as in "[^()]+ (?!
2205 [^()] )". This was only 4 times slower on a string with 1000000
2206 "a"s.
2207
2208 The "grab all you can, and do not give anything back" semantic is
2209 desirable in many situations where on the first sight a simple
2210 "()*" looks like the correct solution. Suppose we parse text with
2211 comments being delimited by "#" followed by some optional
2212 (horizontal) whitespace. Contrary to its appearance, "#[ \t]*" is
2213 not the correct subexpression to match the comment delimiter,
2214 because it may "give up" some whitespace if the remainder of the
2215 pattern can be made to match that way. The correct answer is
2216 either one of these:
2217
2218 (?>#[ \t]*)
2219 #[ \t]*(?![ \t])
2220
2221 For example, to grab non-empty comments into $1, one should use
2222 either one of these:
2223
2224 / (?> \# [ \t]* ) ( .+ ) /x;
2225 / \# [ \t]* ( [^ \t] .* ) /x;
2226
2227 Which one you pick depends on which of these expressions better
2228 reflects the above specification of comments.
2229
2230 In some literature this construct is called "atomic matching" or
2231 "possessive matching".
2232
2233 Possessive quantifiers are equivalent to putting the item they are
2234 applied to inside of one of these constructs. The following
2235 equivalences apply:
2236
2237 Quantifier Form Bracketing Form
2238 --------------- ---------------
2239 PAT*+ (?>PAT*)
2240 PAT++ (?>PAT+)
2241 PAT?+ (?>PAT?)
2242 PAT{min,max}+ (?>PAT{min,max})
2243
2244 Nested "(?>...)" constructs are not no-ops, even if at first glance
2245 they might seem to be. This is because the nested "(?>...)" can
2246 restrict internal backtracking that otherwise might occur. For
2247 example,
2248
2249 "abc" =~ /(?>a[bc]*c)/
2250
2251 matches, but
2252
2253 "abc" =~ /(?>a(?>[bc]*)c)/
2254
2255 does not.
2256
2257 "(?[ ])"
2258 See "Extended Bracketed Character Classes" in perlrecharclass.
2259
2260 Backtracking
2261 NOTE: This section presents an abstract approximation of regular
2262 expression behavior. For a more rigorous (and complicated) view of the
2263 rules involved in selecting a match among possible alternatives, see
2264 "Combining RE Pieces".
2265
2266 A fundamental feature of regular expression matching involves the
2267 notion called backtracking, which is currently used (when needed) by
2268 all regular non-possessive expression quantifiers, namely "*", "*?",
2269 "+", "+?", "{n,m}", and "{n,m}?". Backtracking is often optimized
2270 internally, but the general principle outlined here is valid.
2271
2272 For a regular expression to match, the entire regular expression must
2273 match, not just part of it. So if the beginning of a pattern
2274 containing a quantifier succeeds in a way that causes later parts in
2275 the pattern to fail, the matching engine backs up and recalculates the
2276 beginning part--that's why it's called backtracking.
2277
2278 Here is an example of backtracking: Let's say you want to find the
2279 word following "foo" in the string "Food is on the foo table.":
2280
2281 $_ = "Food is on the foo table.";
2282 if ( /\b(foo)\s+(\w+)/i ) {
2283 print "$2 follows $1.\n";
2284 }
2285
2286 When the match runs, the first part of the regular expression
2287 ("\b(foo)") finds a possible match right at the beginning of the
2288 string, and loads up $1 with "Foo". However, as soon as the matching
2289 engine sees that there's no whitespace following the "Foo" that it had
2290 saved in $1, it realizes its mistake and starts over again one
2291 character after where it had the tentative match. This time it goes
2292 all the way until the next occurrence of "foo". The complete regular
2293 expression matches this time, and you get the expected output of "table
2294 follows foo."
2295
2296 Sometimes minimal matching can help a lot. Imagine you'd like to match
2297 everything between "foo" and "bar". Initially, you write something
2298 like this:
2299
2300 $_ = "The food is under the bar in the barn.";
2301 if ( /foo(.*)bar/ ) {
2302 print "got <$1>\n";
2303 }
2304
2305 Which perhaps unexpectedly yields:
2306
2307 got <d is under the bar in the >
2308
2309 That's because ".*" was greedy, so you get everything between the first
2310 "foo" and the last "bar". Here it's more effective to use minimal
2311 matching to make sure you get the text between a "foo" and the first
2312 "bar" thereafter.
2313
2314 if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2315 got <d is under the >
2316
2317 Here's another example. Let's say you'd like to match a number at the
2318 end of a string, and you also want to keep the preceding part of the
2319 match. So you write this:
2320
2321 $_ = "I have 2 numbers: 53147";
2322 if ( /(.*)(\d*)/ ) { # Wrong!
2323 print "Beginning is <$1>, number is <$2>.\n";
2324 }
2325
2326 That won't work at all, because ".*" was greedy and gobbled up the
2327 whole string. As "\d*" can match on an empty string the complete
2328 regular expression matched successfully.
2329
2330 Beginning is <I have 2 numbers: 53147>, number is <>.
2331
2332 Here are some variants, most of which don't work:
2333
2334 $_ = "I have 2 numbers: 53147";
2335 @pats = qw{
2336 (.*)(\d*)
2337 (.*)(\d+)
2338 (.*?)(\d*)
2339 (.*?)(\d+)
2340 (.*)(\d+)$
2341 (.*?)(\d+)$
2342 (.*)\b(\d+)$
2343 (.*\D)(\d+)$
2344 };
2345
2346 for $pat (@pats) {
2347 printf "%-12s ", $pat;
2348 if ( /$pat/ ) {
2349 print "<$1> <$2>\n";
2350 } else {
2351 print "FAIL\n";
2352 }
2353 }
2354
2355 That will print out:
2356
2357 (.*)(\d*) <I have 2 numbers: 53147> <>
2358 (.*)(\d+) <I have 2 numbers: 5314> <7>
2359 (.*?)(\d*) <> <>
2360 (.*?)(\d+) <I have > <2>
2361 (.*)(\d+)$ <I have 2 numbers: 5314> <7>
2362 (.*?)(\d+)$ <I have 2 numbers: > <53147>
2363 (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2364 (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2365
2366 As you see, this can be a bit tricky. It's important to realize that a
2367 regular expression is merely a set of assertions that gives a
2368 definition of success. There may be 0, 1, or several different ways
2369 that the definition might succeed against a particular string. And if
2370 there are multiple ways it might succeed, you need to understand
2371 backtracking to know which variety of success you will achieve.
2372
2373 When using lookahead assertions and negations, this can all get even
2374 trickier. Imagine you'd like to find a sequence of non-digits not
2375 followed by "123". You might try to write that as
2376
2377 $_ = "ABC123";
2378 if ( /^\D*(?!123)/ ) { # Wrong!
2379 print "Yup, no 123 in $_\n";
2380 }
2381
2382 But that isn't going to match; at least, not the way you're hoping. It
2383 claims that there is no 123 in the string. Here's a clearer picture of
2384 why that pattern matches, contrary to popular expectations:
2385
2386 $x = 'ABC123';
2387 $y = 'ABC445';
2388
2389 print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2390 print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2391
2392 print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2393 print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2394
2395 This prints
2396
2397 2: got ABC
2398 3: got AB
2399 4: got ABC
2400
2401 You might have expected test 3 to fail because it seems to a more
2402 general purpose version of test 1. The important difference between
2403 them is that test 3 contains a quantifier ("\D*") and so can use
2404 backtracking, whereas test 1 will not. What's happening is that you've
2405 asked "Is it true that at the start of $x, following 0 or more non-
2406 digits, you have something that's not 123?" If the pattern matcher had
2407 let "\D*" expand to "ABC", this would have caused the whole pattern to
2408 fail.
2409
2410 The search engine will initially match "\D*" with "ABC". Then it will
2411 try to match "(?!123)" with "123", which fails. But because a
2412 quantifier ("\D*") has been used in the regular expression, the search
2413 engine can backtrack and retry the match differently in the hope of
2414 matching the complete regular expression.
2415
2416 The pattern really, really wants to succeed, so it uses the standard
2417 pattern back-off-and-retry and lets "\D*" expand to just "AB" this
2418 time. Now there's indeed something following "AB" that is not "123".
2419 It's "C123", which suffices.
2420
2421 We can deal with this by using both an assertion and a negation. We'll
2422 say that the first part in $1 must be followed both by a digit and by
2423 something that's not "123". Remember that the lookaheads are zero-
2424 width expressions--they only look, but don't consume any of the string
2425 in their match. So rewriting this way produces what you'd expect; that
2426 is, case 5 will fail, but case 6 succeeds:
2427
2428 print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2429 print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2430
2431 6: got ABC
2432
2433 In other words, the two zero-width assertions next to each other work
2434 as though they're ANDed together, just as you'd use any built-in
2435 assertions: "/^$/" matches only if you're at the beginning of the line
2436 AND the end of the line simultaneously. The deeper underlying truth is
2437 that juxtaposition in regular expressions always means AND, except when
2438 you write an explicit OR using the vertical bar. "/ab/" means match
2439 "a" AND (then) match "b", although the attempted matches are made at
2440 different positions because "a" is not a zero-width assertion, but a
2441 one-width assertion.
2442
2443 WARNING: Particularly complicated regular expressions can take
2444 exponential time to solve because of the immense number of possible
2445 ways they can use backtracking to try for a match. For example,
2446 without internal optimizations done by the regular expression engine,
2447 this will take a painfully long time to run:
2448
2449 'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2450
2451 And if you used "*"'s in the internal groups instead of limiting them
2452 to 0 through 5 matches, then it would take forever--or until you ran
2453 out of stack space. Moreover, these internal optimizations are not
2454 always applicable. For example, if you put "{0,5}" instead of "*" on
2455 the external group, no current optimization is applicable, and the
2456 match takes a long time to finish.
2457
2458 A powerful tool for optimizing such beasts is what is known as an
2459 "independent group", which does not backtrack (see "(?>pattern)").
2460 Note also that zero-length lookahead/lookbehind assertions will not
2461 backtrack to make the tail match, since they are in "logical" context:
2462 only whether they match is considered relevant. For an example where
2463 side-effects of lookahead might have influenced the following match,
2464 see "(?>pattern)".
2465
2466 Script Runs
2467 A script run is basically a sequence of characters, all from the same
2468 Unicode script (see "Scripts" in perlunicode), such as Latin or Greek.
2469 In most places a single word would never be written in multiple
2470 scripts, unless it is a spoofing attack. An infamous example, is
2471
2472 paypal.com
2473
2474 Those letters could all be Latin (as in the example just above), or
2475 they could be all Cyrillic (except for the dot), or they could be a
2476 mixture of the two. In the case of an internet address the ".com"
2477 would be in Latin, And any Cyrillic ones would cause it to be a
2478 mixture, not a script run. Someone clicking on such a link would not
2479 be directed to the real Paypal website, but an attacker would craft a
2480 look-alike one to attempt to gather sensitive information from the
2481 person.
2482
2483 Starting in Perl 5.28, it is now easy to detect strings that aren't
2484 script runs. Simply enclose just about any pattern like either of
2485 these:
2486
2487 (*script_run:pattern)
2488 (*sr:pattern)
2489
2490 What happens is that after pattern succeeds in matching, it is
2491 subjected to the additional criterion that every character in it must
2492 be from the same script (see exceptions below). If this isn't true,
2493 backtracking occurs until something all in the same script is found
2494 that matches, or all possibilities are exhausted. This can cause a lot
2495 of backtracking, but generally, only malicious input will result in
2496 this, though the slow down could cause a denial of service attack. If
2497 your needs permit, it is best to make the pattern atomic to cut down on
2498 the amount of backtracking. This is so likely to be what you want,
2499 that instead of writing this:
2500
2501 (*script_run:(?>pattern))
2502
2503 you can write either of these:
2504
2505 (*atomic_script_run:pattern)
2506 (*asr:pattern)
2507
2508 (See "(?>pattern)".)
2509
2510 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2511 characters from their native scripts and base Chinese. Perl follows
2512 Unicode's UTS 39 (<https://unicode.org/reports/tr39/>) Unicode Security
2513 Mechanisms in allowing such mixtures. For example, the Japanese
2514 scripts Katakana and Hiragana are commonly mixed together in practice,
2515 along with some Chinese characters, and hence are treated as being in a
2516 single script run by Perl.
2517
2518 The rules used for matching decimal digits are slightly stricter. Many
2519 scripts have their own sets of digits equivalent to the Western 0
2520 through 9 ones. A few, such as Arabic, have more than one set. For a
2521 string to be considered a script run, all digits in it must come from
2522 the same set of ten, as determined by the first digit encountered. As
2523 an example,
2524
2525 qr/(*script_run: \d+ \b )/x
2526
2527 guarantees that the digits matched will all be from the same set of 10.
2528 You won't get a look-alike digit from a different script that has a
2529 different value than what it appears to be.
2530
2531 Unicode has three pseudo scripts that are handled specially.
2532
2533 "Unknown" is applied to code points whose meaning has yet to be
2534 determined. Perl currently will match as a script run, any single
2535 character string consisting of one of these code points. But any
2536 string longer than one code point containing one of these will not be
2537 considered a script run.
2538
2539 "Inherited" is applied to characters that modify another, such as an
2540 accent of some type. These are considered to be in the script of the
2541 master character, and so never cause a script run to not match.
2542
2543 The other one is "Common". This consists of mostly punctuation, emoji,
2544 characters used in mathematics and music, the ASCII digits 0 through 9,
2545 and full-width forms of these digits. These characters can appear
2546 intermixed in text in many of the world's scripts. These also don't
2547 cause a script run to not match. But like other scripts, all digits in
2548 a run must come from the same set of 10.
2549
2550 This construct is non-capturing. You can add parentheses to pattern to
2551 capture, if desired. You will have to do this if you plan to use
2552 "(*ACCEPT) (*ACCEPT:arg)" and not have it bypass the script run
2553 checking.
2554
2555 The "Script_Extensions" property as modified by UTS 39
2556 (<https://unicode.org/reports/tr39/>) is used as the basis for this
2557 feature.
2558
2559 To summarize,
2560
2561 • All length 0 or length 1 sequences are script runs.
2562
2563 • A longer sequence is a script run if and only if all of the
2564 following conditions are met:
2565
2566
2567
2568 1. No code point in the sequence has the "Script_Extension"
2569 property of "Unknown".
2570
2571 This currently means that all code points in the sequence have
2572 been assigned by Unicode to be characters that aren't private
2573 use nor surrogate code points.
2574
2575 2. All characters in the sequence come from the Common script
2576 and/or the Inherited script and/or a single other script.
2577
2578 The script of a character is determined by the
2579 "Script_Extensions" property as modified by UTS 39
2580 (<https://unicode.org/reports/tr39/>), as described above.
2581
2582 3. All decimal digits in the sequence come from the same block of
2583 10 consecutive digits.
2584
2585 Special Backtracking Control Verbs
2586 These special patterns are generally of the form "(*VERB:arg)". Unless
2587 otherwise stated the arg argument is optional; in some cases, it is
2588 mandatory.
2589
2590 Any pattern containing a special backtracking verb that allows an
2591 argument has the special behaviour that when executed it sets the
2592 current package's $REGERROR and $REGMARK variables. When doing so the
2593 following rules apply:
2594
2595 On failure, the $REGERROR variable will be set to the arg value of the
2596 verb pattern, if the verb was involved in the failure of the match. If
2597 the arg part of the pattern was omitted, then $REGERROR will be set to
2598 the name of the last "(*MARK:NAME)" pattern executed, or to TRUE if
2599 there was none. Also, the $REGMARK variable will be set to FALSE.
2600
2601 On a successful match, the $REGERROR variable will be set to FALSE, and
2602 the $REGMARK variable will be set to the name of the last
2603 "(*MARK:NAME)" pattern executed. See the explanation for the
2604 "(*MARK:NAME)" verb below for more details.
2605
2606 NOTE: $REGERROR and $REGMARK are not magic variables like $1 and most
2607 other regex-related variables. They are not local to a scope, nor
2608 readonly, but instead are volatile package variables similar to
2609 $AUTOLOAD. They are set in the package containing the code that
2610 executed the regex (rather than the one that compiled it, where those
2611 differ). If necessary, you can use "local" to localize changes to
2612 these variables to a specific scope before executing a regex.
2613
2614 If a pattern does not contain a special backtracking verb that allows
2615 an argument, then $REGERROR and $REGMARK are not touched at all.
2616
2617 Verbs
2618 "(*PRUNE)" "(*PRUNE:NAME)"
2619 This zero-width pattern prunes the backtracking tree at the
2620 current point when backtracked into on failure. Consider the
2621 pattern "/A (*PRUNE) B/", where A and B are complex patterns.
2622 Until the "(*PRUNE)" verb is reached, A may backtrack as
2623 necessary to match. Once it is reached, matching continues in B,
2624 which may also backtrack as necessary; however, should B not
2625 match, then no further backtracking will take place, and the
2626 pattern will fail outright at the current starting position.
2627
2628 The following example counts all the possible matching strings
2629 in a pattern (without actually matching any of them).
2630
2631 'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2632 print "Count=$count\n";
2633
2634 which produces:
2635
2636 aaab
2637 aaa
2638 aa
2639 a
2640 aab
2641 aa
2642 a
2643 ab
2644 a
2645 Count=9
2646
2647 If we add a "(*PRUNE)" before the count like the following
2648
2649 'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2650 print "Count=$count\n";
2651
2652 we prevent backtracking and find the count of the longest
2653 matching string at each matching starting point like so:
2654
2655 aaab
2656 aab
2657 ab
2658 Count=3
2659
2660 Any number of "(*PRUNE)" assertions may be used in a pattern.
2661
2662 See also "(?>pattern)" and possessive quantifiers for other ways
2663 to control backtracking. In some cases, the use of "(*PRUNE)"
2664 can be replaced with a "(?>pattern)" with no functional
2665 difference; however, "(*PRUNE)" can be used to handle cases that
2666 cannot be expressed using a "(?>pattern)" alone.
2667
2668 "(*SKIP)" "(*SKIP:NAME)"
2669 This zero-width pattern is similar to "(*PRUNE)", except that on
2670 failure it also signifies that whatever text that was matched
2671 leading up to the "(*SKIP)" pattern being executed cannot be
2672 part of any match of this pattern. This effectively means that
2673 the regex engine "skips" forward to this position on failure and
2674 tries to match again, (assuming that there is sufficient room to
2675 match).
2676
2677 The name of the "(*SKIP:NAME)" pattern has special significance.
2678 If a "(*MARK:NAME)" was encountered while matching, then it is
2679 that position which is used as the "skip point". If no "(*MARK)"
2680 of that name was encountered, then the "(*SKIP)" operator has no
2681 effect. When used without a name the "skip point" is where the
2682 match point was when executing the "(*SKIP)" pattern.
2683
2684 Compare the following to the examples in "(*PRUNE)"; note the
2685 string is twice as long:
2686
2687 'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2688 print "Count=$count\n";
2689
2690 outputs
2691
2692 aaab
2693 aaab
2694 Count=2
2695
2696 Once the 'aaab' at the start of the string has matched, and the
2697 "(*SKIP)" executed, the next starting point will be where the
2698 cursor was when the "(*SKIP)" was executed.
2699
2700 "(*MARK:NAME)" "(*:NAME)"
2701 This zero-width pattern can be used to mark the point reached in
2702 a string when a certain part of the pattern has been
2703 successfully matched. This mark may be given a name. A later
2704 "(*SKIP)" pattern will then skip forward to that point if
2705 backtracked into on failure. Any number of "(*MARK)" patterns
2706 are allowed, and the NAME portion may be duplicated.
2707
2708 In addition to interacting with the "(*SKIP)" pattern,
2709 "(*MARK:NAME)" can be used to "label" a pattern branch, so that
2710 after matching, the program can determine which branches of the
2711 pattern were involved in the match.
2712
2713 When a match is successful, the $REGMARK variable will be set to
2714 the name of the most recently executed "(*MARK:NAME)" that was
2715 involved in the match.
2716
2717 This can be used to determine which branch of a pattern was
2718 matched without using a separate capture group for each branch,
2719 which in turn can result in a performance improvement, as perl
2720 cannot optimize "/(?:(x)|(y)|(z))/" as efficiently as something
2721 like "/(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/".
2722
2723 When a match has failed, and unless another verb has been
2724 involved in failing the match and has provided its own name to
2725 use, the $REGERROR variable will be set to the name of the most
2726 recently executed "(*MARK:NAME)".
2727
2728 See "(*SKIP)" for more details.
2729
2730 As a shortcut "(*MARK:NAME)" can be written "(*:NAME)".
2731
2732 "(*THEN)" "(*THEN:NAME)"
2733 This is similar to the "cut group" operator "::" from Raku.
2734 Like "(*PRUNE)", this verb always matches, and when backtracked
2735 into on failure, it causes the regex engine to try the next
2736 alternation in the innermost enclosing group (capturing or
2737 otherwise) that has alternations. The two branches of a
2738 "(?(condition)yes-pattern|no-pattern)" do not count as an
2739 alternation, as far as "(*THEN)" is concerned.
2740
2741 Its name comes from the observation that this operation combined
2742 with the alternation operator ("|") can be used to create what
2743 is essentially a pattern-based if/then/else block:
2744
2745 ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2746
2747 Note that if this operator is used and NOT inside of an
2748 alternation then it acts exactly like the "(*PRUNE)" operator.
2749
2750 / A (*PRUNE) B /
2751
2752 is the same as
2753
2754 / A (*THEN) B /
2755
2756 but
2757
2758 / ( A (*THEN) B | C ) /
2759
2760 is not the same as
2761
2762 / ( A (*PRUNE) B | C ) /
2763
2764 as after matching the A but failing on the B the "(*THEN)" verb
2765 will backtrack and try C; but the "(*PRUNE)" verb will simply
2766 fail.
2767
2768 "(*COMMIT)" "(*COMMIT:arg)"
2769 This is the Raku "commit pattern" "<commit>" or ":::". It's a
2770 zero-width pattern similar to "(*SKIP)", except that when
2771 backtracked into on failure it causes the match to fail
2772 outright. No further attempts to find a valid match by advancing
2773 the start pointer will occur again. For example,
2774
2775 'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2776 print "Count=$count\n";
2777
2778 outputs
2779
2780 aaab
2781 Count=1
2782
2783 In other words, once the "(*COMMIT)" has been entered, and if
2784 the pattern does not match, the regex engine will not try any
2785 further matching on the rest of the string.
2786
2787 "(*FAIL)" "(*F)" "(*FAIL:arg)"
2788 This pattern matches nothing and always fails. It can be used to
2789 force the engine to backtrack. It is equivalent to "(?!)", but
2790 easier to read. In fact, "(?!)" gets optimised into "(*FAIL)"
2791 internally. You can provide an argument so that if the match
2792 fails because of this "FAIL" directive the argument can be
2793 obtained from $REGERROR.
2794
2795 It is probably useful only when combined with "(?{})" or
2796 "(??{})".
2797
2798 "(*ACCEPT)" "(*ACCEPT:arg)"
2799 This pattern matches nothing and causes the end of successful
2800 matching at the point at which the "(*ACCEPT)" pattern was
2801 encountered, regardless of whether there is actually more to
2802 match in the string. When inside of a nested pattern, such as
2803 recursion, or in a subpattern dynamically generated via
2804 "(??{})", only the innermost pattern is ended immediately.
2805
2806 If the "(*ACCEPT)" is inside of capturing groups then the groups
2807 are marked as ended at the point at which the "(*ACCEPT)" was
2808 encountered. For instance:
2809
2810 'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2811
2812 will match, and $1 will be "AB" and $2 will be "B", $3 will not
2813 be set. If another branch in the inner parentheses was matched,
2814 such as in the string 'ACDE', then the "D" and "E" would have to
2815 be matched as well.
2816
2817 You can provide an argument, which will be available in the var
2818 $REGMARK after the match completes.
2819
2820 Warning on "\1" Instead of $1
2821 Some people get too used to writing things like:
2822
2823 $pattern =~ s/(\W)/\\\1/g;
2824
2825 This is grandfathered (for \1 to \9) for the RHS of a substitute to
2826 avoid shocking the sed addicts, but it's a dirty habit to get into.
2827 That's because in PerlThink, the righthand side of an "s///" is a
2828 double-quoted string. "\1" in the usual double-quoted string means a
2829 control-A. The customary Unix meaning of "\1" is kludged in for
2830 "s///". However, if you get into the habit of doing that, you get
2831 yourself into trouble if you then add an "/e" modifier.
2832
2833 s/(\d+)/ \1 + 1 /eg; # causes warning under -w
2834
2835 Or if you try to do
2836
2837 s/(\d+)/\1000/;
2838
2839 You can't disambiguate that by saying "\{1}000", whereas you can fix it
2840 with "${1}000". The operation of interpolation should not be confused
2841 with the operation of matching a backreference. Certainly they mean
2842 two different things on the left side of the "s///".
2843
2844 Repeated Patterns Matching a Zero-length Substring
2845 WARNING: Difficult material (and prose) ahead. This section needs a
2846 rewrite.
2847
2848 Regular expressions provide a terse and powerful programming language.
2849 As with most other power tools, power comes together with the ability
2850 to wreak havoc.
2851
2852 A common abuse of this power stems from the ability to make infinite
2853 loops using regular expressions, with something as innocuous as:
2854
2855 'foo' =~ m{ ( o? )* }x;
2856
2857 The "o?" matches at the beginning of ""foo"", and since the position in
2858 the string is not moved by the match, "o?" would match again and again
2859 because of the "*" quantifier. Another common way to create a similar
2860 cycle is with the looping modifier "/g":
2861
2862 @matches = ( 'foo' =~ m{ o? }xg );
2863
2864 or
2865
2866 print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2867
2868 or the loop implied by split().
2869
2870 However, long experience has shown that many programming tasks may be
2871 significantly simplified by using repeated subexpressions that may
2872 match zero-length substrings. Here's a simple example being:
2873
2874 @chars = split //, $string; # // is not magic in split
2875 ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2876
2877 Thus Perl allows such constructs, by forcefully breaking the infinite
2878 loop. The rules for this are different for lower-level loops given by
2879 the greedy quantifiers "*+{}", and for higher-level ones like the "/g"
2880 modifier or split() operator.
2881
2882 The lower-level loops are interrupted (that is, the loop is broken)
2883 when Perl detects that a repeated expression matched a zero-length
2884 substring. Thus
2885
2886 m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2887
2888 is made equivalent to
2889
2890 m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2891
2892 For example, this program
2893
2894 #!perl -l
2895 "aaaaab" =~ /
2896 (?:
2897 a # non-zero
2898 | # or
2899 (?{print "hello"}) # print hello whenever this
2900 # branch is tried
2901 (?=(b)) # zero-width assertion
2902 )* # any number of times
2903 /x;
2904 print $&;
2905 print $1;
2906
2907 prints
2908
2909 hello
2910 aaaaa
2911 b
2912
2913 Notice that "hello" is only printed once, as when Perl sees that the
2914 sixth iteration of the outermost "(?:)*" matches a zero-length string,
2915 it stops the "*".
2916
2917 The higher-level loops preserve an additional state between iterations:
2918 whether the last match was zero-length. To break the loop, the
2919 following match after a zero-length match is prohibited to have a
2920 length of zero. This prohibition interacts with backtracking (see
2921 "Backtracking"), and so the second best match is chosen if the best
2922 match is of zero length.
2923
2924 For example:
2925
2926 $_ = 'bar';
2927 s/\w??/<$&>/g;
2928
2929 results in "<><b><><a><><r><>". At each position of the string the
2930 best match given by non-greedy "??" is the zero-length match, and the
2931 second best match is what is matched by "\w". Thus zero-length matches
2932 alternate with one-character-long matches.
2933
2934 Similarly, for repeated "m/()/g" the second-best match is the match at
2935 the position one notch further in the string.
2936
2937 The additional state of being matched with zero-length is associated
2938 with the matched string, and is reset by each assignment to pos().
2939 Zero-length matches at the end of the previous match are ignored during
2940 "split".
2941
2942 Combining RE Pieces
2943 Each of the elementary pieces of regular expressions which were
2944 described before (such as "ab" or "\Z") could match at most one
2945 substring at the given position of the input string. However, in a
2946 typical regular expression these elementary pieces are combined into
2947 more complicated patterns using combining operators "ST", "S|T", "S*"
2948 etc. (in these examples "S" and "T" are regular subexpressions).
2949
2950 Such combinations can include alternatives, leading to a problem of
2951 choice: if we match a regular expression "a|ab" against "abc", will it
2952 match substring "a" or "ab"? One way to describe which substring is
2953 actually matched is the concept of backtracking (see "Backtracking").
2954 However, this description is too low-level and makes you think in terms
2955 of a particular implementation.
2956
2957 Another description starts with notions of "better"/"worse". All the
2958 substrings which may be matched by the given regular expression can be
2959 sorted from the "best" match to the "worst" match, and it is the "best"
2960 match which is chosen. This substitutes the question of "what is
2961 chosen?" by the question of "which matches are better, and which are
2962 worse?".
2963
2964 Again, for elementary pieces there is no such question, since at most
2965 one match at a given position is possible. This section describes the
2966 notion of better/worse for combining operators. In the description
2967 below "S" and "T" are regular subexpressions.
2968
2969 "ST"
2970 Consider two possible matches, "AB" and "A'B'", "A" and "A'" are
2971 substrings which can be matched by "S", "B" and "B'" are substrings
2972 which can be matched by "T".
2973
2974 If "A" is a better match for "S" than "A'", "AB" is a better match
2975 than "A'B'".
2976
2977 If "A" and "A'" coincide: "AB" is a better match than "AB'" if "B"
2978 is a better match for "T" than "B'".
2979
2980 "S|T"
2981 When "S" can match, it is a better match than when only "T" can
2982 match.
2983
2984 Ordering of two matches for "S" is the same as for "S". Similar
2985 for two matches for "T".
2986
2987 "S{REPEAT_COUNT}"
2988 Matches as "SSS...S" (repeated as many times as necessary).
2989
2990 "S{min,max}"
2991 Matches as "S{max}|S{max-1}|...|S{min+1}|S{min}".
2992
2993 "S{min,max}?"
2994 Matches as "S{min}|S{min+1}|...|S{max-1}|S{max}".
2995
2996 "S?", "S*", "S+"
2997 Same as "S{0,1}", "S{0,BIG_NUMBER}", "S{1,BIG_NUMBER}"
2998 respectively.
2999
3000 "S??", "S*?", "S+?"
3001 Same as "S{0,1}?", "S{0,BIG_NUMBER}?", "S{1,BIG_NUMBER}?"
3002 respectively.
3003
3004 "(?>S)"
3005 Matches the best match for "S" and only that.
3006
3007 "(?=S)", "(?<=S)"
3008 Only the best match for "S" is considered. (This is important only
3009 if "S" has capturing parentheses, and backreferences are used
3010 somewhere else in the whole regular expression.)
3011
3012 "(?!S)", "(?<!S)"
3013 For this grouping operator there is no need to describe the
3014 ordering, since only whether or not "S" can match is important.
3015
3016 "(??{ EXPR })", "(?PARNO)"
3017 The ordering is the same as for the regular expression which is the
3018 result of EXPR, or the pattern contained by capture group PARNO.
3019
3020 "(?(condition)yes-pattern|no-pattern)"
3021 Recall that which of yes-pattern or no-pattern actually matches is
3022 already determined. The ordering of the matches is the same as for
3023 the chosen subexpression.
3024
3025 The above recipes describe the ordering of matches at a given position.
3026 One more rule is needed to understand how a match is determined for the
3027 whole regular expression: a match at an earlier position is always
3028 better than a match at a later position.
3029
3030 Creating Custom RE Engines
3031 As of Perl 5.10.0, one can create custom regular expression engines.
3032 This is not for the faint of heart, as they have to plug in at the C
3033 level. See perlreapi for more details.
3034
3035 As an alternative, overloaded constants (see overload) provide a simple
3036 way to extend the functionality of the RE engine, by substituting one
3037 pattern for another.
3038
3039 Suppose that we want to enable a new RE escape-sequence "\Y|" which
3040 matches at a boundary between whitespace characters and non-whitespace
3041 characters. Note that "(?=\S)(?<!\S)|(?!\S)(?<=\S)" matches exactly at
3042 these positions, so we want to have each "\Y|" in the place of the more
3043 complicated version. We can create a module "customre" to do this:
3044
3045 package customre;
3046 use overload;
3047
3048 sub import {
3049 shift;
3050 die "No argument to customre::import allowed" if @_;
3051 overload::constant 'qr' => \&convert;
3052 }
3053
3054 sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
3055
3056 # We must also take care of not escaping the legitimate \\Y|
3057 # sequence, hence the presence of '\\' in the conversion rules.
3058 my %rules = ( '\\' => '\\\\',
3059 'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
3060 sub convert {
3061 my $re = shift;
3062 $re =~ s{
3063 \\ ( \\ | Y . )
3064 }
3065 { $rules{$1} or invalid($re,$1) }sgex;
3066 return $re;
3067 }
3068
3069 Now "use customre" enables the new escape in constant regular
3070 expressions, i.e., those without any runtime variable interpolations.
3071 As documented in overload, this conversion will work only over literal
3072 parts of regular expressions. For "\Y|$re\Y|" the variable part of
3073 this regular expression needs to be converted explicitly (but only if
3074 the special meaning of "\Y|" should be enabled inside $re):
3075
3076 use customre;
3077 $re = <>;
3078 chomp $re;
3079 $re = customre::convert $re;
3080 /\Y|$re\Y|/;
3081
3082 Embedded Code Execution Frequency
3083 The exact rules for how often "(?{})" and "(??{})" are executed in a
3084 pattern are unspecified, and this is even more true of "(*{})". In the
3085 case of a successful match you can assume that they DWIM and will be
3086 executed in left to right order the appropriate number of times in the
3087 accepting path of the pattern as would any other meta-pattern. How non-
3088 accepting pathways and match failures affect the number of times a
3089 pattern is executed is specifically unspecified and may vary depending
3090 on what optimizations can be applied to the pattern and is likely to
3091 change from version to version.
3092
3093 For instance in
3094
3095 "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
3096
3097 the exact number of times "a" or "b" are printed out is unspecified for
3098 failure, but you may assume they will be printed at least once during a
3099 successful match, additionally you may assume that if "b" is printed,
3100 it will be preceded by at least one "a".
3101
3102 In the case of branching constructs like the following:
3103
3104 /a(b|(?{ print "a" }))c(?{ print "c" })/;
3105
3106 you can assume that the input "ac" will output "ac", and that "abc"
3107 will output only "c".
3108
3109 When embedded code is quantified, successful matches will call the code
3110 once for each matched iteration of the quantifier. For example:
3111
3112 "good" =~ /g(?:o(?{print "o"}))*d/;
3113
3114 will output "o" twice.
3115
3116 For historical and consistency reasons the use of normal code blocks
3117 anywhere in a pattern will disable certain optimisations. As of 5.37.7
3118 you can use an "optimistic" codeblock, "(*{ ... })" as a replacement
3119 for "(?{ ... })", if you do *not* wish to disable these optimisations.
3120 This may result in the code block being called less often than it might
3121 have been had they not been optimistic.
3122
3123 PCRE/Python Support
3124 As of Perl 5.10.0, Perl supports several Python/PCRE-specific
3125 extensions to the regex syntax. While Perl programmers are encouraged
3126 to use the Perl-specific syntax, the following are also accepted:
3127
3128 "(?P<NAME>pattern)"
3129 Define a named capture group. Equivalent to "(?<NAME>pattern)".
3130
3131 "(?P=NAME)"
3132 Backreference to a named capture group. Equivalent to "\g{NAME}".
3133
3134 "(?P>NAME)"
3135 Subroutine call to a named capture group. Equivalent to "(?&NAME)".
3136
3138 There are a number of issues with regard to case-insensitive matching
3139 in Unicode rules. See "i" under "Modifiers" above.
3140
3141 This document varies from difficult to understand to completely and
3142 utterly opaque. The wandering prose riddled with jargon is hard to
3143 fathom in several places.
3144
3145 This document needs a rewrite that separates the tutorial content from
3146 the reference content.
3147
3149 The syntax of patterns used in Perl pattern matching evolved from those
3150 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
3151 routines. (The code is actually derived (distantly) from Henry
3152 Spencer's freely redistributable reimplementation of those V8
3153 routines.)
3154
3155 perlrequick.
3156
3157 perlretut.
3158
3159 "Regexp Quote-Like Operators" in perlop.
3160
3161 "Gory details of parsing quoted constructs" in perlop.
3162
3163 perlfaq6.
3164
3165 "pos" in perlfunc.
3166
3167 perllocale.
3168
3169 perlebcdic.
3170
3171 Mastering Regular Expressions by Jeffrey Friedl, published by O'Reilly
3172 and Associates.
3173
3174
3175
3176perl v5.38.2 2023-11-30 PERLRE(1)