1Moo(3) User Contributed Perl Documentation Moo(3)
2
6 Moo - Minimalist Object Orientation (with Moose compatibility)
7
9 package Cat::Food;
10 use Moo;
12 use strictures 2;
13 use namespace::clean;
14 sub feed_lion {
16 my $self = shift;
17 my $amount = shift || 1;
18 $self->pounds( $self->pounds - $amount );
20 }
21 has taste => (
23 is => 'ro',
24 );
25 has brand => (
27 is => 'ro',
28 isa => sub {
29 die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
30 },
31 );
32 has pounds => (
34 is => 'rw',
35 isa => sub { die "$_[0] is too much cat food!" unless $_[0] < 15 },
36 );
37 1;
39 And elsewhere:
41 my $full = Cat::Food->new(
43 taste => 'DELICIOUS.',
44 brand => 'SWEET-TREATZ',
45 pounds => 10,
46 );
47 $full->feed_lion;
49 say $full->pounds;
51
53 "Moo" is an extremely light-weight Object Orientation system. It allows
54 one to concisely define objects and roles with a convenient syntax that
55 avoids the details of Perl's object system. "Moo" contains a subset of
56 Moose and is optimised for rapid startup.
57 "Moo" avoids depending on any XS modules to allow for simple
59 deployments. The name "Moo" is based on the idea that it provides
60 almost -- but not quite -- two thirds of Moose. As such, the
61 Moose::Manual can serve as an effective guide to "Moo" aside from the
62 MOP and Types sections.
63 Unlike Mouse this module does not aim at full compatibility with
65 Moose's surface syntax, preferring instead to provide full
66 interoperability via the metaclass inflation capabilities described in
67 "MOO AND MOOSE".
68 For a full list of the minor differences between Moose and Moo's
70 surface syntax, see "INCOMPATIBILITIES WITH MOOSE".
71
73 If you want a full object system with a rich Metaprotocol, Moose is
74 already wonderful.
75 But if you don't want to use Moose, you may not want "less
77 metaprotocol" like Mouse offers, but you probably want "no
78 metaprotocol", which is what Moo provides. "Moo" is ideal for some
79 situations where deployment or startup time precludes using Moose and
80 Mouse:
81 • A command line or CGI script where fast startup is essential
83 • code designed to be deployed as a single file via App::FatPacker
85 • A CPAN module that may be used by others in the above situations
87 "Moo" maintains transparent compatibility with Moose so if you install
89 and load Moose you can use Moo classes and roles in Moose code without
90 modification.
91 Moo -- Minimal Object Orientation -- aims to make it smooth to upgrade
93 to Moose when you need more than the minimal features offered by Moo.
94
96 If Moo detects Moose being loaded, it will automatically register
97 metaclasses for your Moo and Moo::Role packages, so you should be able
98 to use them in Moose code without modification.
99 Moo will also create Moose type constraints for Moo classes and roles,
101 so that in Moose classes "isa => 'MyMooClass'" and "isa => 'MyMooRole'"
102 work the same as for Moose classes and roles.
103 Extending a Moose class or consuming a Moose::Role will also work.
105 Extending a Mouse class or consuming a Mouse::Role will also work. But
107 note that we don't provide Mouse metaclasses or metaroles so the other
108 way around doesn't work. This feature exists for Any::Moose users
109 porting to Moo; enabling Mouse users to use Moo classes is not a
110 priority for us.
111 This means that there is no need for anything like Any::Moose for Moo
113 code - Moo and Moose code should simply interoperate without problem.
114 To handle Mouse code, you'll likely need an empty Moo role or class
115 consuming or extending the Mouse stuff since it doesn't register true
116 Moose metaclasses like Moo does.
117 If you need to disable the metaclass creation, add:
119 no Moo::sification;
121 to your code before Moose is loaded, but bear in mind that this switch
123 is global and turns the mechanism off entirely so don't put this in
124 library code.
125
127 If a new enough version of Class::XSAccessor is available, it will be
128 used to generate simple accessors, readers, and writers for better
129 performance. Simple accessors are those without lazy defaults, type
130 checks/coercions, or triggers. Simple readers are those without lazy
131 defaults. Readers and writers generated by Class::XSAccessor will
132 behave slightly differently: they will reject attempts to call them
133 with the incorrect number of parameters.
134
136 Any::Moose will load Mouse normally, and Moose in a program using Moose
137 - which theoretically allows you to get the startup time of Mouse
138 without disadvantaging Moose users.
139 Sadly, this doesn't entirely work, since the selection is load order
141 dependent - Moo's metaclass inflation system explained above in "MOO
142 AND MOOSE" is significantly more reliable.
143 So if you want to write a CPAN module that loads fast or has only pure
145 perl dependencies but is also fully usable by Moose users, you should
146 be using Moo.
147 For a full explanation, see the article
149 <https://shadow.cat/blog/matt-s-trout/moo-versus-any-moose> which
150 explains the differing strategies in more detail and provides a direct
151 example of where Moo succeeds and Any::Moose fails.
152
154 Moo provides several methods to any class using it.
155 new
157 Foo::Bar->new( attr1 => 3 );
158 or
160 Foo::Bar->new({ attr1 => 3 });
162 The constructor for the class. By default it will accept attributes
164 either as a hashref, or a list of key value pairs. This can be
165 customized with the "BUILDARGS" method.
166 does
168 if ($foo->does('Some::Role1')) {
169 ...
170 }
171 Returns true if the object composes in the passed role.
173 DOES
175 if ($foo->DOES('Some::Role1') || $foo->DOES('Some::Class1')) {
176 ...
177 }
178 Similar to "does", but will also return true for both composed roles
180 and superclasses.
181 meta
183 my $meta = Foo::Bar->meta;
184 my @methods = $meta->get_method_list;
185 Returns an object that will behave as if it is a Moose metaclass object
187 for the class. If you call anything other than "make_immutable" on it,
188 the object will be transparently upgraded to a genuine
189 Moose::Meta::Class instance, loading Moose in the process if required.
190 "make_immutable" itself is a no-op, since we generate metaclasses that
191 are already immutable, and users converting from Moose had an
192 unfortunate tendency to accidentally load Moose by calling it.
193
195 There are several methods that you can define in your class to control
196 construction and destruction of objects. They should be used rather
197 than trying to modify "new" or "DESTROY" yourself.
198 BUILDARGS
200 around BUILDARGS => sub {
201 my ( $orig, $class, @args ) = @_;
202 return { attr1 => $args[0] }
204 if @args == 1 && !ref $args[0];
205 return $class->$orig(@args);
207 };
208 Foo::Bar->new( 3 );
210 This class method is used to transform the arguments to "new" into a
212 hash reference of attribute values.
213 The default implementation accepts a hash or hash reference of named
215 parameters. If it receives a single argument that isn't a hash
216 reference it will throw an error.
217 You can override this method in your class to handle other types of
219 options passed to the constructor.
220 This method should always return a hash reference of named options.
222 FOREIGNBUILDARGS
224 sub FOREIGNBUILDARGS {
225 my ( $class, $options ) = @_;
226 return $options->{foo};
227 }
228 If you are inheriting from a non-Moo class, the arguments passed to the
230 parent class constructor can be manipulated by defining a
231 "FOREIGNBUILDARGS" method. It will receive the same arguments as
232 "BUILDARGS", and should return a list of arguments to pass to the
233 parent class constructor.
234 BUILD
236 sub BUILD {
237 my ($self, $args) = @_;
238 die "foo and bar cannot be used at the same time"
239 if exists $args->{foo} && exists $args->{bar};
240 }
241 On object creation, any "BUILD" methods in the class's inheritance
243 hierarchy will be called on the object and given the results of
244 "BUILDARGS". They each will be called in order from the parent classes
245 down to the child, and thus should not themselves call the parent's
246 method. Typically this is used for object validation or possibly
247 logging.
248 DEMOLISH
250 sub DEMOLISH {
251 my ($self, $in_global_destruction) = @_;
252 ...
253 }
254 When an object is destroyed, any "DEMOLISH" methods in the inheritance
256 hierarchy will be called on the object. They are given boolean to
257 inform them if global destruction is in progress, and are called from
258 the child class upwards to the parent. This is similar to "BUILD"
259 methods but in the opposite order.
260 Note that this is implemented by a "DESTROY" method, which is only
262 created on on the first construction of an object of your class. This
263 saves on overhead for classes that are never instantiated or those
264 without "DEMOLISH" methods. If you try to define your own "DESTROY",
265 this will cause undefined results.
266
268 extends
269 extends 'Parent::Class';
270 Declares a base class. Multiple superclasses can be passed for multiple
272 inheritance but please consider using roles instead. The class will be
273 loaded but no errors will be triggered if the class can't be found and
274 there are already subs in the class.
275 Calling extends more than once will REPLACE your superclasses, not add
277 to them like 'use base' would.
278 with
280 with 'Some::Role1';
281 or
283 with 'Some::Role1', 'Some::Role2';
285 Composes one or more Moo::Role (or Role::Tiny) roles into the current
287 class. An error will be raised if these roles cannot be composed
288 because they have conflicting method definitions. The roles will be
289 loaded using the same mechanism as "extends" uses.
290 has
292 has attr => (
293 is => 'ro',
294 );
295 Declares an attribute for the class.
297 package Foo;
299 use Moo;
300 has 'attr' => (
301 is => 'ro'
302 );
303 package Bar;
305 use Moo;
306 extends 'Foo';
307 has '+attr' => (
308 default => sub { "blah" },
309 );
310 Using the "+" notation, it's possible to override an attribute.
312 has [qw(attr1 attr2 attr3)] => (
314 is => 'ro',
315 );
316 Using an arrayref with multiple attribute names, it's possible to
318 declare multiple attributes with the same options.
319 The options for "has" are as follows:
321 "is"
323 required, may be "ro", "lazy", "rwp" or "rw".
324 "ro" stands for "read-only" and generates an accessor that dies if
326 you attempt to write to it - i.e. a getter only - by defaulting
327 "reader" to the name of the attribute.
328 "lazy" generates a reader like "ro", but also sets "lazy" to 1 and
330 "builder" to "_build_${attribute_name}" to allow on-demand generated
331 attributes. This feature was my attempt to fix my incompetence when
332 originally designing "lazy_build", and is also implemented by
333 MooseX::AttributeShortcuts. There is, however, nothing to stop you
334 using "lazy" and "builder" yourself with "rwp" or "rw" - it's just
335 that this isn't generally a good idea so we don't provide a shortcut
336 for it.
337 "rwp" stands for "read-write protected" and generates a reader like
339 "ro", but also sets "writer" to "_set_${attribute_name}" for
340 attributes that are designed to be written from inside of the class,
341 but read-only from outside. This feature comes from
342 MooseX::AttributeShortcuts.
343 "rw" stands for "read-write" and generates a normal getter/setter by
345 defaulting the "accessor" to the name of the attribute specified.
346 "isa"
348 Takes a coderef which is used to validate the attribute. Unlike
349 Moose, Moo does not include a basic type system, so instead of doing
350 "isa => 'Num'", one should do
351 use Scalar::Util qw(looks_like_number);
353 ...
354 isa => sub {
355 die "$_[0] is not a number!" unless looks_like_number $_[0]
356 },
357 Note that the return value for "isa" is discarded. Only if the sub
359 dies does type validation fail.
360 Sub::Quote aware
362 Since Moo does not run the "isa" check before "coerce" if a coercion
364 subroutine has been supplied, "isa" checks are not structural to your
365 code and can, if desired, be omitted on non-debug builds (although if
366 this results in an uncaught bug causing your program to break, the
367 Moo authors guarantee nothing except that you get to keep both
368 halves).
369 If you want Moose compatible or MooseX::Types style named types, look
371 at Type::Tiny.
372 To cause your "isa" entries to be automatically mapped to named
374 Moose::Meta::TypeConstraint objects (rather than the default
375 behaviour of creating an anonymous type), set:
376 $Moo::HandleMoose::TYPE_MAP{$isa_coderef} = sub {
378 require MooseX::Types::Something;
379 return MooseX::Types::Something::TypeName();
380 };
381 Note that this example is purely illustrative; anything that returns
383 a Moose::Meta::TypeConstraint object or something similar enough to
384 it to make Moose happy is fine.
385 "coerce"
387 Takes a coderef which is meant to coerce the attribute. The basic
388 idea is to do something like the following:
389 coerce => sub {
391 $_[0] % 2 ? $_[0] : $_[0] + 1
392 },
393 Note that Moo will always execute your coercion: this is to permit
395 "isa" entries to be used purely for bug trapping, whereas coercions
396 are always structural to your code. We do, however, apply any
397 supplied "isa" check after the coercion has run to ensure that it
398 returned a valid value.
399 Sub::Quote aware
401 If the "isa" option is a blessed object providing a "coerce" or
403 "coercion" method, then the "coerce" option may be set to just 1.
404 "handles"
406 Takes a string
407 handles => 'RobotRole'
409 Where "RobotRole" is a role that defines an interface which becomes
411 the list of methods to handle.
412 Takes a list of methods
414 handles => [ qw( one two ) ]
416 Takes a hashref
418 handles => {
420 un => 'one',
421 }
422 "trigger"
424 Takes a coderef which will get called any time the attribute is set.
425 This includes the constructor, but not default or built values. The
426 coderef will be invoked against the object with the new value as an
427 argument.
428 If you set this to just 1, it generates a trigger which calls the
430 "_trigger_${attr_name}" method on $self. This feature comes from
431 MooseX::AttributeShortcuts.
432 Note that Moose also passes the old value, if any; this feature is
434 not yet supported.
435 Sub::Quote aware
437 "default"
439 Takes a coderef which will get called with $self as its only argument
440 to populate an attribute if no value for that attribute was supplied
441 to the constructor. Alternatively, if the attribute is lazy,
442 "default" executes when the attribute is first retrieved if no value
443 has yet been provided.
444 If a simple scalar is provided, it will be inlined as a string. Any
446 non-code reference (hash, array) will result in an error - for that
447 case instead use a code reference that returns the desired value.
448 Note that if your default is fired during new() there is no guarantee
450 that other attributes have been populated yet so you should not rely
451 on their existence.
452 Sub::Quote aware
454 "predicate"
456 Takes a method name which will return true if an attribute has a
457 value.
458 If you set this to just 1, the predicate is automatically named
460 "has_${attr_name}" if your attribute's name does not start with an
461 underscore, or "_has_${attr_name_without_the_underscore}" if it does.
462 This feature comes from MooseX::AttributeShortcuts.
463 "builder"
465 Takes a method name which will be called to create the attribute -
466 functions exactly like default except that instead of calling
467 $default->($self);
469 Moo will call
471 $self->$builder;
473 The following features come from MooseX::AttributeShortcuts:
475 If you set this to just 1, the builder is automatically named
477 "_build_${attr_name}".
478 If you set this to a coderef or code-convertible object, that
480 variable will be installed under "$class::_build_${attr_name}" and
481 the builder set to the same name.
482 "clearer"
484 Takes a method name which will clear the attribute.
485 If you set this to just 1, the clearer is automatically named
487 "clear_${attr_name}" if your attribute's name does not start with an
488 underscore, or "_clear_${attr_name_without_the_underscore}" if it
489 does. This feature comes from MooseX::AttributeShortcuts.
490 NOTE: If the attribute is "lazy", it will be regenerated from
492 "default" or "builder" the next time it is accessed. If it is not
493 lazy, it will be "undef".
494 "lazy"
496 Boolean. Set this if you want values for the attribute to be grabbed
497 lazily. This is usually a good idea if you have a "builder" which
498 requires another attribute to be set.
499 "required"
501 Boolean. Set this if the attribute must be passed on object
502 instantiation.
503 "reader"
505 The name of the method that returns the value of the attribute. If
506 you like Java style methods, you might set this to "get_foo"
507 "writer"
509 The value of this attribute will be the name of the method to set the
510 value of the attribute. If you like Java style methods, you might
511 set this to "set_foo".
512 "weak_ref"
514 Boolean. Set this if you want the reference that the attribute
515 contains to be weakened. Use this when circular references, which
516 cause memory leaks, are possible.
517 "init_arg"
519 Takes the name of the key to look for at instantiation time of the
520 object. A common use of this is to make an underscored attribute
521 have a non-underscored initialization name. "undef" means that
522 passing the value in on instantiation is ignored.
523 "moosify"
525 Takes either a coderef or array of coderefs which is meant to
526 transform the given attributes specifications if necessary when
527 upgrading to a Moose role or class. You shouldn't need this by
528 default, but is provided as a means of possible extensibility.
529 before
531 before foo => sub { ... };
532 See "before method(s) => sub { ... };" in Class::Method::Modifiers for
534 full documentation.
535 around
537 around foo => sub { ... };
538 See "around method(s) => sub { ... };" in Class::Method::Modifiers for
540 full documentation.
541 after
543 after foo => sub { ... };
544 See "after method(s) => sub { ... };" in Class::Method::Modifiers for
546 full documentation.
547
549 "quote_sub" in Sub::Quote allows us to create coderefs that are
550 "inlineable," giving us a handy, XS-free speed boost. Any option that
551 is Sub::Quote aware can take advantage of this.
552 To do this, you can write
554 use Sub::Quote;
556 use Moo;
558 use namespace::clean;
559 has foo => (
561 is => 'ro',
562 isa => quote_sub(q{ die "Not <3" unless $_[0] < 3 })
563 );
564 which will be inlined as
566 do {
568 local @_ = ($_[0]->{foo});
569 die "Not <3" unless $_[0] < 3;
570 }
571 or to avoid localizing @_,
573 has foo => (
575 is => 'ro',
576 isa => quote_sub(q{ my ($val) = @_; die "Not <3" unless $val < 3 })
577 );
578 which will be inlined as
580 do {
582 my ($val) = ($_[0]->{foo});
583 die "Not <3" unless $val < 3;
584 }
585 See Sub::Quote for more information, including how to pass lexical
587 captures that will also be compiled into the subroutine.
588
590 Moo will not clean up imported subroutines for you; you will have to do
591 that manually. The recommended way to do this is to declare your
592 imports first, then "use Moo", then "use namespace::clean". Anything
593 imported before namespace::clean will be scrubbed. Anything imported
594 or declared after will be still be available.
595 package Record;
597 use Digest::MD5 qw(md5_hex);
599 use Moo;
601 use namespace::clean;
602 has name => (is => 'ro', required => 1);
604 has id => (is => 'lazy');
605 sub _build_id {
606 my ($self) = @_;
607 return md5_hex($self->name);
608 }
609 1;
611 For example if you were to import these subroutines after
613 namespace::clean like this
614 use namespace::clean;
616 use Digest::MD5 qw(md5_hex);
618 use Moo;
619 then any "Record" $r would have methods such as "$r->md5_hex()",
621 "$r->has()" and "$r->around()" - almost certainly not what you intend!
622 Moo::Roles behave slightly differently. Since their methods are
624 composed into the consuming class, they can do a little more for you
625 automatically. As long as you declare your imports before calling "use
626 Moo::Role", those imports and the ones Moo::Role itself provides will
627 not be composed into consuming classes so there's usually no need to
628 use namespace::clean.
629 On namespace::autoclean: Older versions of namespace::autoclean would
631 inflate Moo classes to full Moose classes, losing the benefits of Moo.
632 If you want to use namespace::autoclean with a Moo class, make sure you
633 are using version 0.16 or newer.
634
636 TYPES
637 There is no built-in type system. "isa" is verified with a coderef; if
638 you need complex types, Type::Tiny can provide types, type libraries,
639 and will work seamlessly with both Moo and Moose. Type::Tiny can be
640 considered the successor to MooseX::Types and provides a similar API,
641 so that you can write
642 use Types::Standard qw(Int);
644 has days_to_live => (is => 'ro', isa => Int);
645 API INCOMPATIBILITIES
647 "initializer" is not supported in core since the author considers it to
648 be a bad idea and Moose best practices recommend avoiding it. Meanwhile
649 "trigger" or "coerce" are more likely to be able to fulfill your needs.
650 No support for "super", "override", "inner", or "augment" - the author
652 considers augment to be a bad idea, and override can be translated:
653 override foo => sub {
655 ...
656 super();
657 ...
658 };
659 around foo => sub {
661 my ($orig, $self) = (shift, shift);
662 ...
663 $self->$orig(@_);
664 ...
665 };
666 The "dump" method is not provided by default. The author suggests
668 loading Devel::Dwarn into "main::" (via "perl -MDevel::Dwarn ..." for
669 example) and using "$obj->$::Dwarn()" instead.
670 "default" only supports coderefs and plain scalars, because passing a
672 hash or array reference as a default is almost always incorrect since
673 the value is then shared between all objects using that default.
674 "lazy_build" is not supported; you are instead encouraged to use the
676 "is => 'lazy'" option supported by Moo and MooseX::AttributeShortcuts.
677 "auto_deref" is not supported since the author considers it a bad idea
679 and it has been considered best practice to avoid it for some time.
680 "documentation" will show up in a Moose metaclass created from your
682 class but is otherwise ignored. Then again, Moose ignores it as well,
683 so this is arguably not an incompatibility.
684 Since "coerce" does not require "isa" to be defined but Moose does
686 require it, the metaclass inflation for coerce alone is a trifle insane
687 and if you attempt to subtype the result will almost certainly break.
688 Handling of warnings: when you "use Moo" we enable strict and warnings,
690 in a similar way to Moose. The authors recommend the use of
691 "strictures", which enables FATAL warnings, and several extra pragmas
692 when used in development: indirect, multidimensional, and
693 bareword::filehandles.
694 Additionally, Moo supports a set of attribute option shortcuts intended
696 to reduce common boilerplate. The set of shortcuts is the same as in
697 the Moose module MooseX::AttributeShortcuts as of its version 0.009+.
698 So if you:
699 package MyClass;
701 use Moo;
702 use strictures 2;
703 The nearest Moose invocation would be:
705 package MyClass;
707 use Moose;
709 use warnings FATAL => "all";
710 use MooseX::AttributeShortcuts;
711 or, if you're inheriting from a non-Moose class,
713 package MyClass;
715 use Moose;
717 use MooseX::NonMoose;
718 use warnings FATAL => "all";
719 use MooseX::AttributeShortcuts;
720 META OBJECT
722 There is no meta object. If you need this level of complexity you need
723 Moose - Moo is small because it explicitly does not provide a
724 metaprotocol. However, if you load Moose, then
725 Class::MOP::class_of($moo_class_or_role)
727 will return an appropriate metaclass pre-populated by Moo.
729 IMMUTABILITY
731 Finally, Moose requires you to call
732 __PACKAGE__->meta->make_immutable;
734 at the end of your class to get an inlined (i.e. not horribly slow)
736 constructor. Moo does it automatically the first time ->new is called
737 on your class. ("make_immutable" is a no-op in Moo to ease migration.)
738 An extension MooX::late exists to ease translating Moose packages to
740 Moo by providing a more Moose-like interface.
741
743 Moo is compatible with perl versions back to 5.6. When running on
744 older versions, additional prerequisites will be required. If you are
745 packaging a script with its dependencies, such as with App::FatPacker,
746 you will need to be certain that the extra prerequisites are included.
747 MRO::Compat
749 Required on perl versions prior to 5.10.0.
750 Devel::GlobalDestruction
752 Required on perl versions prior to 5.14.0.
753
755 IRC: #moose on irc.perl.org
756 Bugtracker: <https://rt.cpan.org/Public/Dist/Display.html?Name=Moo>
758 Git repository: <git://github.com/moose/Moo.git>
760 Git browser: <https://github.com/moose/Moo>
762
764 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
765
767 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
768 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
770 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
772 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
774 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
776 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
778 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
780 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
782 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
784 Mithaldu - Christian Walde (cpan:MITHALDU)
786 <walde.christian@googlemail.com>
787 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
789 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
791 haarg - Graham Knop (cpan:HAARG) <haarg@cpan.org>
793 mattp - Matt Phillips (cpan:MATTP) <mattp@cpan.org>
795 bluefeet - Aran Deltac (cpan:BLUEFEET) <bluefeet@gmail.com>
797 bubaflub - Bob Kuo (cpan:BUBAFLUB) <bubaflub@cpan.org>
799 ether = Karen Etheridge (cpan:ETHER) <ether@cpan.org>
801
803 Copyright (c) 2010-2015 the Moo "AUTHOR" and "CONTRIBUTORS" as listed
804 above.
805
807 This library is free software and may be distributed under the same
808 terms as perl itself. See <https://dev.perl.org/licenses/>.
809perl v5.38.0 2023-07-20 Moo(3)