1XS(3) User Contributed Perl Documentation XS(3)
2
6 Cpanel::JSON::XS - cPanel fork of JSON::XS, fast and correct
7 serializing
8
10 use Cpanel::JSON::XS;
11 # exported functions, they croak on error
13 # and expect/generate UTF-8
14 $utf8_encoded_json_text = encode_json $perl_hash_or_arrayref;
16 $perl_hash_or_arrayref = decode_json $utf8_encoded_json_text;
17 # OO-interface
19 $coder = Cpanel::JSON::XS->new->ascii->pretty->allow_nonref;
21 $pretty_printed_unencoded = $coder->encode ($perl_scalar);
22 $perl_scalar = $coder->decode ($unicode_json_text);
23 # Note that 5.6 misses most smart utf8 and encoding functionalities
25 # of newer releases.
26 # Note that L<JSON::MaybeXS> will automatically use Cpanel::JSON::XS
28 # if available, at virtually no speed overhead either, so you should
29 # be able to just:
30 use JSON::MaybeXS;
32 # and do the same things, except that you have a pure-perl fallback now.
34
36 This module converts Perl data structures to JSON and vice versa. Its
37 primary goal is to be correct and its secondary goal is to be fast. To
38 reach the latter goal it was written in C.
39 As this is the n-th-something JSON module on CPAN, what was the reason
41 to write yet another JSON module? While it seems there are many JSON
42 modules, none of them correctly handle all corner cases, and in most
43 cases their maintainers are unresponsive, gone missing, or not
44 listening to bug reports for other reasons.
45 See below for the cPanel fork.
47 See MAPPING, below, on how Cpanel::JSON::XS maps perl values to JSON
49 values and vice versa.
50 FEATURES
52 · correct Unicode handling
53 This module knows how to handle Unicode with Perl version higher
55 than 5.8.5, documents how and when it does so, and even documents
56 what "correct" means.
57 · round-trip integrity
59 When you serialize a perl data structure using only data types
61 supported by JSON and Perl, the deserialized data structure is
62 identical on the Perl level. (e.g. the string "2.0" doesn't
63 suddenly become "2" just because it looks like a number). There are
64 minor exceptions to this, read the MAPPING section below to learn
65 about those.
66 · strict checking of JSON correctness
68 There is no guessing, no generating of illegal JSON texts by
70 default, and only JSON is accepted as input by default. the latter
71 is a security feature.
72 · fast
74 Compared to other JSON modules and other serializers such as
76 Storable, this module usually compares favourably in terms of
77 speed, too.
78 · simple to use
80 This module has both a simple functional interface as well as an
82 object oriented interface.
83 · reasonably versatile output formats
85 You can choose between the most compact guaranteed-single-line
87 format possible (nice for simple line-based protocols), a pure-
88 ASCII format (for when your transport is not 8-bit clean, still
89 supports the whole Unicode range), or a pretty-printed format (for
90 when you want to read that stuff). Or you can combine those
91 features in whatever way you like.
92 cPanel fork
94 Since the original author MLEHMANN has no public bugtracker, this
95 cPanel fork sits now on github.
96 src repo: <https://github.com/rurban/Cpanel-JSON-XS> original:
98 <http://cvs.schmorp.de/JSON-XS/>
99 RT: <https://github.com/rurban/Cpanel-JSON-XS/issues> or
101 <https://rt.cpan.org/Public/Dist/Display.html?Queue=Cpanel-JSON-XS>
102 Changes to JSON::XS
104 - stricter decode_json() as documented. non-refs are disallowed.
106 added a 2nd optional argument. decode() honors now allow_nonref.
107 - fixed encode of numbers for dual-vars. Different string
109 representations are preserved, but numbers with temporary strings
110 which represent the same number are here treated as numbers, not
111 strings. Cpanel::JSON::XS is a bit slower, but preserves numeric
112 types better.
113 - numbers ending with .0 stay numbers, are not converted to
115 integers. [#63] dual-vars which are represented as number not
116 integer (42+"bar" != 5.8.9) are now encoded as number (=> 42.0)
117 because internally it's now a NOK type. However !!1 which is
118 wrongly encoded in 5.8 as "1"/1.0 is still represented as integer.
119 - different handling of inf/nan. Default now to null, optionally with
121 stringify_infnan() to "inf"/"nan". [#28, #32]
122 - added "binary" extension, non-JSON and non JSON parsable, allows
124 "\xNN" and "\NNN" sequences.
125 - 5.6.2 support; sacrificing some utf8 features (assuming bytes
127 all-over), no multi-byte unicode characters with 5.6.
128 - interop for true/false overloading. JSON::XS, JSON::PP and Mojo::JSON
130 representations for booleans are accepted and JSON::XS accepts
131 Cpanel::JSON::XS booleans [#13, #37]
132 Fixed overloading of booleans. Cpanel::JSON::XS::true stringifies
133 again
134 to "1", not "true", analog to all other JSON modules.
135 - native boolean mapping of yes and no to true and false, as in
137 YAML::XS.
138 In perl "!0" is yes, "!1" is no.
139 The JSON value true maps to 1, false maps to 0. [#39]
140 - support arbitrary stringification with encode, with convert_blessed
142 and allow_blessed.
143 - ithread support. Cpanel::JSON::XS is thread-safe, JSON::XS not
145 - is_bool can be called as method, JSON::XS::is_bool not.
147 - performance optimizations for threaded Perls
149 - relaxed mode, allowing many popular extensions
151 - additional fixes for:
153 - [cpan #88061] AIX atof without USE_LONG_DOUBLE
155 - #10 unshare_hek crash
157 - #7, #29 avoid re-blessing where possible. It fails in JSON::XS for
159 READONLY values, i.e. restricted hashes.
160 - #41 overloading of booleans, use the object not the reference.
162 - #62 -Dusequadmath conversion and no SEGV.
164 - #72 parsing of values followed \0, like 1\0 does fail.
166 - #72 parsing of illegal unicode or non-unicode characters.
168 - #96 locale-insensitive numeric conversion
170 - public maintenance and bugtracker
172 - use ppport.h, sanify XS.xs comment styles, harness C coding style
174 - common::sense is optional. When available it is not used in the
176 published production module, just during development and testing.
177 - extended testsuite, passes all http://seriot.ch/parsing_json.html
179 tests. In fact it is the only know JSON decoder which does so,
180 while also being the fastest.
181 - support many more options and methods from JSON::PP:
183 stringify_infnan, allow_unknown, allow_stringify, allow_barekey,
184 encode_stringify, allow_bignum, allow_singlequote, sort_by
185 (partially), escape_slash, convert_blessed, ... optional
186 decode_json(, allow_nonref) arg.
187 relaxed implements allow_dupkeys.
188 - support all 5 unicode BOM's: UTF-8, UTF-16LE, UTF-16BE, UTF-32LE,
190 UTF-32BE, encoding internally to UTF-8.
191
193 The following convenience methods are provided by this module. They are
194 exported by default:
195 $json_text = encode_json $perl_scalar, [json_type]
197 Converts the given Perl data structure to a UTF-8 encoded, binary
198 string (that is, the string contains octets only). Croaks on error.
199 This function call is functionally identical to:
201 $json_text = Cpanel::JSON::XS->new->utf8->encode ($perl_scalar)
203 Except being faster.
205 For the type argument see Cpanel::JSON::XS::Type.
207 $perl_scalar = decode_json $json_text [, $allow_nonref ]
209 The opposite of "encode_json": expects an UTF-8 (binary) string of
210 an json reference and tries to parse that as an UTF-8 encoded JSON
211 text, returning the resulting reference. Croaks on error.
212 This function call is functionally identical to:
214 $perl_scalar = Cpanel::JSON::XS->new->utf8->decode ($json_text)
216 except being faster.
218 Note that older decode_json versions in Cpanel::JSON::XS older than
220 3.0116 and JSON::XS did not set allow_nonref but allowed them due
221 to a bug in the decoder.
222 If the new optional $allow_nonref argument is set and not false,
224 the allow_nonref option will be set and the function will act is
225 described as in the relaxed RFC 7159 allowing all values such as
226 objects, arrays, strings, numbers, "null", "true", and "false".
227 $is_boolean = Cpanel::JSON::XS::is_bool $scalar
229 Returns true if the passed scalar represents either
230 "JSON::XS::true" or "JSON::XS::false", two constants that act like
231 1 and 0, respectively and are used to represent JSON "true" and
232 "false" values in Perl.
233 See MAPPING, below, for more information on how JSON values are
235 mapped to Perl.
236
238 from_json
239 from_json has been renamed to decode_json
240 to_json
242 to_json has been renamed to encode_json
243
245 Since this often leads to confusion, here are a few very clear words on
246 how Unicode works in Perl, modulo bugs.
247 1. Perl strings can store characters with ordinal values > 255.
249 This enables you to store Unicode characters as single characters
250 in a Perl string - very natural.
251 2. Perl does not associate an encoding with your strings.
253 ... until you force it to, e.g. when matching it against a regex,
254 or printing the scalar to a file, in which case Perl either
255 interprets your string as locale-encoded text, octets/binary, or as
256 Unicode, depending on various settings. In no case is an encoding
257 stored together with your data, it is use that decides encoding,
258 not any magical meta data.
259 3. The internal utf-8 flag has no meaning with regards to the encoding
261 of your string.
262 4. A "Unicode String" is simply a string where each character can be
263 validly interpreted as a Unicode code point.
264 If you have UTF-8 encoded data, it is no longer a Unicode string,
265 but a Unicode string encoded in UTF-8, giving you a binary string.
266 5. A string containing "high" (> 255) character values is not a UTF-8
268 string.
269 6. Unicode noncharacters only warn, as in core.
270 The 66 Unicode noncharacters U+FDD0..U+FDEF, and U+*FFFE, U+*FFFF
271 just warn, see <http://www.unicode.org/versions/corrigendum9.html>.
272 But illegal surrogate pairs fail to parse.
273 7. Raw non-Unicode characters above U+10FFFF are disallowed.
275 Raw non-Unicode characters outside the valid unicode range fail to
276 parse, because "A string is a sequence of zero or more Unicode
277 characters" RFC 7159 section 1 and "JSON text SHALL be encoded in
278 Unicode RFC 7159 section 8.1. We use now the UTF8_DISALLOW_SUPER
279 flag when parsing unicode.
280 I hope this helps :)
282
284 The object oriented interface lets you configure your own encoding or
285 decoding style, within the limits of supported formats.
286 $json = new Cpanel::JSON::XS
288 Creates a new JSON object that can be used to de/encode JSON
289 strings. All boolean flags described below are by default disabled.
290 The mutators for flags all return the JSON object again and thus
292 calls can be chained:
293 my $json = Cpanel::JSON::XS->new->utf8->space_after->encode ({a => [1,2]})
295 => {"a": [1, 2]}
296 $json = $json->ascii ([$enable])
298 $enabled = $json->get_ascii
299 If $enable is true (or missing), then the "encode" method will not
300 generate characters outside the code range 0..127 (which is ASCII).
301 Any Unicode characters outside that range will be escaped using
302 either a single "\uXXXX" (BMP characters) or a double
303 "\uHHHH\uLLLLL" escape sequence, as per RFC4627. The resulting
304 encoded JSON text can be treated as a native Unicode string, an
305 ascii-encoded, latin1-encoded or UTF-8 encoded string, or any other
306 superset of ASCII.
307 If $enable is false, then the "encode" method will not escape
309 Unicode characters unless required by the JSON syntax or other
310 flags. This results in a faster and more compact format.
311 See also the section ENCODING/CODESET FLAG NOTES later in this
313 document.
314 The main use for this flag is to produce JSON texts that can be
316 transmitted over a 7-bit channel, as the encoded JSON texts will
317 not contain any 8 bit characters.
318 Cpanel::JSON::XS->new->ascii (1)->encode ([chr 0x10401])
320 => ["\ud801\udc01"]
321 $json = $json->latin1 ([$enable])
323 $enabled = $json->get_latin1
324 If $enable is true (or missing), then the "encode" method will
325 encode the resulting JSON text as latin1 (or ISO-8859-1), escaping
326 any characters outside the code range 0..255. The resulting string
327 can be treated as a latin1-encoded JSON text or a native Unicode
328 string. The "decode" method will not be affected in any way by this
329 flag, as "decode" by default expects Unicode, which is a strict
330 superset of latin1.
331 If $enable is false, then the "encode" method will not escape
333 Unicode characters unless required by the JSON syntax or other
334 flags.
335 See also the section ENCODING/CODESET FLAG NOTES later in this
337 document.
338 The main use for this flag is efficiently encoding binary data as
340 JSON text, as most octets will not be escaped, resulting in a
341 smaller encoded size. The disadvantage is that the resulting JSON
342 text is encoded in latin1 (and must correctly be treated as such
343 when storing and transferring), a rare encoding for JSON. It is
344 therefore most useful when you want to store data structures known
345 to contain binary data efficiently in files or databases, not when
346 talking to other JSON encoders/decoders.
347 Cpanel::JSON::XS->new->latin1->encode (["\x{89}\x{abc}"]
349 => ["\x{89}\\u0abc"] # (perl syntax, U+abc escaped, U+89 not)
350 $json = $json->binary ([$enable])
352 $enabled = $json = $json->get_binary
353 If the $enable argument is true (or missing), then the "encode"
354 method will not try to detect an UTF-8 encoding in any JSON string,
355 it will strictly interpret it as byte sequence. The result might
356 contain new "\xNN" sequences, which is unparsable JSON. The
357 "decode" method forbids "\uNNNN" sequences and accepts "\xNN" and
358 octal "\NNN" sequences.
359 There is also a special logic for perl 5.6 and utf8. 5.6 encodes
361 any string to utf-8 automatically when seeing a codepoint >= 0x80
362 and < 0x100. With the binary flag enabled decode the perl utf8
363 encoded string to the original byte encoding and encode this with
364 "\xNN" escapes. This will result to the same encodings as with
365 newer perls. But note that binary multi-byte codepoints with 5.6
366 will result in "illegal unicode character in binary string" errors,
367 unlike with newer perls.
368 If $enable is false, then the "encode" method will smartly try to
370 detect Unicode characters unless required by the JSON syntax or
371 other flags and hex and octal sequences are forbidden.
372 See also the section ENCODING/CODESET FLAG NOTES later in this
374 document.
375 The main use for this flag is to avoid the smart unicode detection
377 and possible double encoding. The disadvantage is that the
378 resulting JSON text is encoded in new "\xNN" and in latin1
379 characters and must correctly be treated as such when storing and
380 transferring, a rare encoding for JSON. It will produce non-
381 readable JSON strings in the browser. It is therefore most useful
382 when you want to store data structures known to contain binary data
383 efficiently in files or databases, not when talking to other JSON
384 encoders/decoders. The binary decoding method can also be used
385 when an encoder produced a non-JSON conformant hex or octal
386 encoding "\xNN" or "\NNN".
387 Cpanel::JSON::XS->new->binary->encode (["\x{89}\x{abc}"])
389 5.6: Error: malformed or illegal unicode character in binary string
390 >=5.8: ['\x89\xe0\xaa\xbc']
391 Cpanel::JSON::XS->new->binary->encode (["\x{89}\x{bc}"])
393 => ["\x89\xbc"]
394 Cpanel::JSON::XS->new->binary->decode (["\x89\ua001"])
396 Error: malformed or illegal unicode character in binary string
397 Cpanel::JSON::XS->new->decode (["\x89"])
399 Error: illegal hex character in non-binary string
400 $json = $json->utf8 ([$enable])
402 $enabled = $json->get_utf8
403 If $enable is true (or missing), then the "encode" method will
404 encode the JSON result into UTF-8, as required by many protocols,
405 while the "decode" method expects to be handled an UTF-8-encoded
406 string. Please note that UTF-8-encoded strings do not contain any
407 characters outside the range 0..255, they are thus useful for
408 bytewise/binary I/O. In future versions, enabling this option might
409 enable autodetection of the UTF-16 and UTF-32 encoding families, as
410 described in RFC4627.
411 If $enable is false, then the "encode" method will return the JSON
413 string as a (non-encoded) Unicode string, while "decode" expects
414 thus a Unicode string. Any decoding or encoding (e.g. to UTF-8 or
415 UTF-16) needs to be done yourself, e.g. using the Encode module.
416 See also the section ENCODING/CODESET FLAG NOTES later in this
418 document.
419 Example, output UTF-16BE-encoded JSON:
421 use Encode;
423 $jsontext = encode "UTF-16BE", Cpanel::JSON::XS->new->encode ($object);
424 Example, decode UTF-32LE-encoded JSON:
426 use Encode;
428 $object = Cpanel::JSON::XS->new->decode (decode "UTF-32LE", $jsontext);
429 $json = $json->pretty ([$enable])
431 This enables (or disables) all of the "indent", "space_before" and
432 "space_after" (and in the future possibly more) flags in one call
433 to generate the most readable (or most compact) form possible.
434 Example, pretty-print some simple structure:
436 my $json = Cpanel::JSON::XS->new->pretty(1)->encode ({a => [1,2]})
438 =>
439 {
440 "a" : [
441 1,
442 2
443 ]
444 }
445 $json = $json->indent ([$enable])
447 $enabled = $json->get_indent
448 If $enable is true (or missing), then the "encode" method will use
449 a multiline format as output, putting every array member or
450 object/hash key-value pair into its own line, indenting them
451 properly.
452 If $enable is false, no newlines or indenting will be produced, and
454 the resulting JSON text is guaranteed not to contain any
455 "newlines".
456 This setting has no effect when decoding JSON texts.
458 $json = $json->indent_length([$number_of_spaces])
460 $length = $json->get_indent_length()
461 Set the indent length (default 3). This option is only useful when
462 you also enable indent or pretty. The acceptable range is from 0
463 (no indentation) to 15
464 $json = $json->space_before ([$enable])
466 $enabled = $json->get_space_before
467 If $enable is true (or missing), then the "encode" method will add
468 an extra optional space before the ":" separating keys from values
469 in JSON objects.
470 If $enable is false, then the "encode" method will not add any
472 extra space at those places.
473 This setting has no effect when decoding JSON texts. You will also
475 most likely combine this setting with "space_after".
476 Example, space_before enabled, space_after and indent disabled:
478 {"key" :"value"}
480 $json = $json->space_after ([$enable])
482 $enabled = $json->get_space_after
483 If $enable is true (or missing), then the "encode" method will add
484 an extra optional space after the ":" separating keys from values
485 in JSON objects and extra whitespace after the "," separating key-
486 value pairs and array members.
487 If $enable is false, then the "encode" method will not add any
489 extra space at those places.
490 This setting has no effect when decoding JSON texts.
492 Example, space_before and indent disabled, space_after enabled:
494 {"key": "value"}
496 $json = $json->relaxed ([$enable])
498 $enabled = $json->get_relaxed
499 If $enable is true (or missing), then "decode" will accept some
500 extensions to normal JSON syntax (see below). "encode" will not be
501 affected in anyway. Be aware that this option makes you accept
502 invalid JSON texts as if they were valid!. I suggest only to use
503 this option to parse application-specific files written by humans
504 (configuration files, resource files etc.)
505 If $enable is false (the default), then "decode" will only accept
507 valid JSON texts.
508 Currently accepted extensions are:
510 · list items can have an end-comma
512 JSON separates array elements and key-value pairs with commas.
514 This can be annoying if you write JSON texts manually and want
515 to be able to quickly append elements, so this extension
516 accepts comma at the end of such items not just between them:
517 [
519 1,
520 2, <- this comma not normally allowed
521 ]
522 {
523 "k1": "v1",
524 "k2": "v2", <- this comma not normally allowed
525 }
526 · shell-style '#'-comments
528 Whenever JSON allows whitespace, shell-style comments are
530 additionally allowed. They are terminated by the first
531 carriage-return or line-feed character, after which more white-
532 space and comments are allowed.
533 [
535 1, # this comment not allowed in JSON
536 # neither this one...
537 ]
538 · literal ASCII TAB characters in strings
540 Literal ASCII TAB characters are now allowed in strings (and
542 treated as "\t") in relaxed mode. Despite JSON mandates, that
543 TAB character is substituted for "\t" sequence.
544 [
546 "Hello\tWorld",
547 "Hello<TAB>World", # literal <TAB> would not normally be allowed
548 ]
549 · allow_singlequote
551 Single quotes are accepted instead of double quotes. See the
553 "allow_singlequote" option.
554 { "foo":'bar' }
556 { 'foo':"bar" }
557 { 'foo':'bar' }
558 · allow_barekey
560 Accept unquoted object keys instead of with mandatory double
562 quotes. See the "allow_barekey" option.
563 { foo:"bar" }
565 · duplicate keys
567 With relaxed decoding of duplicate keys does not error and are
569 silently accepted. See <http://seriot.ch/parsing_json.php#24>:
570 RFC 7159 section 4: "The names within an object should be
571 unique."
572 $json = $json->canonical ([$enable])
574 $enabled = $json->get_canonical
575 If $enable is true (or missing), then the "encode" method will
576 output JSON objects by sorting their keys. This is adding a
577 comparatively high overhead.
578 If $enable is false, then the "encode" method will output key-value
580 pairs in the order Perl stores them (which will likely change
581 between runs of the same script, and can change even within the
582 same run from 5.18 onwards).
583 This option is useful if you want the same data structure to be
585 encoded as the same JSON text (given the same overall settings). If
586 it is disabled, the same hash might be encoded differently even if
587 contains the same data, as key-value pairs have no inherent
588 ordering in Perl.
589 This setting has no effect when decoding JSON texts.
591 This setting has currently no effect on tied hashes.
593 $json = $json->sort_by (undef, 0, 1 or a block)
595 This currently only (un)sets the "canonical" option, and ignores
596 custom sort blocks.
597 This setting has no effect when decoding JSON texts.
599 This setting has currently no effect on tied hashes.
601 $json = $json->escape_slash ([$enable])
603 $enabled = $json->get_escape_slash
604 According to the JSON Grammar, the forward slash character (U+002F)
605 "/" need to be escaped. But by default strings are encoded without
606 escaping slashes in all perl JSON encoders.
607 If $enable is true (or missing), then "encode" will escape slashes,
609 "\/".
610 This setting has no effect when decoding JSON texts.
612 $json = $json->allow_singlequote ([$enable])
614 $enabled = $json->get_allow_singlequote
615 $json = $json->allow_singlequote([$enable])
616 If $enable is true (or missing), then "decode" will accept JSON
618 strings quoted by single quotations that are invalid JSON format.
619 $json->allow_singlequote->decode({"foo":'bar'});
621 $json->allow_singlequote->decode({'foo':"bar"});
622 $json->allow_singlequote->decode({'foo':'bar'});
623 This is also enabled with "relaxed". As same as the "relaxed"
625 option, this option may be used to parse application-specific files
626 written by humans.
627 $json = $json->allow_barekey ([$enable])
629 $enabled = $json->get_allow_barekey
630 $json = $json->allow_barekey([$enable])
631 If $enable is true (or missing), then "decode" will accept bare
633 keys of JSON object that are invalid JSON format.
634 Same as with the "relaxed" option, this option may be used to parse
636 application-specific files written by humans.
637 $json->allow_barekey->decode('{foo:"bar"}');
639 $json = $json->allow_bignum ([$enable])
641 $enabled = $json->get_allow_bignum
642 $json = $json->allow_bignum([$enable])
643 If $enable is true (or missing), then "decode" will convert the big
645 integer Perl cannot handle as integer into a Math::BigInt object
646 and convert a floating number (any) into a Math::BigFloat.
647 On the contrary, "encode" converts "Math::BigInt" objects and
649 "Math::BigFloat" objects into JSON numbers with "allow_blessed"
650 enable.
651 $json->allow_nonref->allow_blessed->allow_bignum;
653 $bigfloat = $json->decode('2.000000000000000000000000001');
654 print $json->encode($bigfloat);
655 # => 2.000000000000000000000000001
656 See "MAPPING" about the normal conversion of JSON number.
658 $json = $json->allow_bigint ([$enable])
660 This option is obsolete and replaced by allow_bignum.
661 $json = $json->allow_nonref ([$enable])
663 $enabled = $json->get_allow_nonref
664 If $enable is true (or missing), then the "encode" method can
665 convert a non-reference into its corresponding string, number or
666 null JSON value, which is an extension to RFC4627. Likewise,
667 "decode" will accept those JSON values instead of croaking.
668 If $enable is false, then the "encode" method will croak if it
670 isn't passed an arrayref or hashref, as JSON texts must either be
671 an object or array. Likewise, "decode" will croak if given
672 something that is not a JSON object or array.
673 Example, encode a Perl scalar as JSON value with enabled
675 "allow_nonref", resulting in an invalid JSON text:
676 Cpanel::JSON::XS->new->allow_nonref->encode ("Hello, World!")
678 => "Hello, World!"
679 $json = $json->allow_unknown ([$enable])
681 $enabled = $json->get_allow_unknown
682 If $enable is true (or missing), then "encode" will not throw an
683 exception when it encounters values it cannot represent in JSON
684 (for example, filehandles) but instead will encode a JSON "null"
685 value. Note that blessed objects are not included here and are
686 handled separately by c<allow_nonref>.
687 If $enable is false (the default), then "encode" will throw an
689 exception when it encounters anything it cannot encode as JSON.
690 This option does not affect "decode" in any way, and it is
692 recommended to leave it off unless you know your communications
693 partner.
694 $json = $json->allow_stringify ([$enable])
696 $enabled = $json->get_allow_stringify
697 If $enable is true (or missing), then "encode" will stringify the
698 non-object perl value or reference. Note that blessed objects are
699 not included here and are handled separately by "allow_blessed" and
700 "convert_blessed". String references are stringified to the string
701 value, other references as in perl.
702 This option does not affect "decode" in any way.
704 This option is special to this module, it is not supported by other
706 encoders. So it is not recommended to use it.
707 $json = $json->allow_blessed ([$enable])
709 $enabled = $json->get_allow_blessed
710 If $enable is true (or missing), then the "encode" method will not
711 barf when it encounters a blessed reference. Instead, the value of
712 the convert_blessed option will decide whether "null"
713 ("convert_blessed" disabled or no "TO_JSON" method found) or a
714 representation of the object ("convert_blessed" enabled and
715 "TO_JSON" method found) is being encoded. Has no effect on
716 "decode".
717 If $enable is false (the default), then "encode" will throw an
719 exception when it encounters a blessed object.
720 This setting has no effect on "decode".
722 $json = $json->convert_blessed ([$enable])
724 $enabled = $json->get_convert_blessed
725 If $enable is true (or missing), then "encode", upon encountering a
726 blessed object, will check for the availability of the "TO_JSON"
727 method on the object's class. If found, it will be called in scalar
728 context and the resulting scalar will be encoded instead of the
729 object. If no "TO_JSON" method is found, a stringification overload
730 method is tried next. If both are not found, the value of
731 "allow_blessed" will decide what to do.
732 The "TO_JSON" method may safely call die if it wants. If "TO_JSON"
734 returns other blessed objects, those will be handled in the same
735 way. "TO_JSON" must take care of not causing an endless recursion
736 cycle (== crash) in this case. The name of "TO_JSON" was chosen
737 because other methods called by the Perl core (== not by the user
738 of the object) are usually in upper case letters and to avoid
739 collisions with any "to_json" function or method.
740 If $enable is false (the default), then "encode" will not consider
742 this type of conversion.
743 This setting has no effect on "decode".
745 $json = $json->allow_tags ([$enable])
747 $enabled = $json->get_allow_tags
748 See "OBJECT SERIALIZATION" for details.
749 If $enable is true (or missing), then "encode", upon encountering a
751 blessed object, will check for the availability of the "FREEZE"
752 method on the object's class. If found, it will be used to
753 serialize the object into a nonstandard tagged JSON value (that
754 JSON decoders cannot decode).
755 It also causes "decode" to parse such tagged JSON values and
757 deserialize them via a call to the "THAW" method.
758 If $enable is false (the default), then "encode" will not consider
760 this type of conversion, and tagged JSON values will cause a parse
761 error in "decode", as if tags were not part of the grammar.
762 $json = $json->filter_json_object ([$coderef->($hashref)])
764 When $coderef is specified, it will be called from "decode" each
765 time it decodes a JSON object. The only argument is a reference to
766 the newly-created hash. If the code references returns a single
767 scalar (which need not be a reference), this value (i.e. a copy of
768 that scalar to avoid aliasing) is inserted into the deserialized
769 data structure. If it returns an empty list (NOTE: not "undef",
770 which is a valid scalar), the original deserialized hash will be
771 inserted. This setting can slow down decoding considerably.
772 When $coderef is omitted or undefined, any existing callback will
774 be removed and "decode" will not change the deserialized hash in
775 any way.
776 Example, convert all JSON objects into the integer 5:
778 my $js = Cpanel::JSON::XS->new->filter_json_object (sub { 5 });
780 # returns [5]
781 $js->decode ('[{}]')
782 # throw an exception because allow_nonref is not enabled
783 # so a lone 5 is not allowed.
784 $js->decode ('{"a":1, "b":2}');
785 $json = $json->filter_json_single_key_object ($key [=>
787 $coderef->($value)])
788 Works remotely similar to "filter_json_object", but is only called
789 for JSON objects having a single key named $key.
790 This $coderef is called before the one specified via
792 "filter_json_object", if any. It gets passed the single value in
793 the JSON object. If it returns a single value, it will be inserted
794 into the data structure. If it returns nothing (not even "undef"
795 but the empty list), the callback from "filter_json_object" will be
796 called next, as if no single-key callback were specified.
797 If $coderef is omitted or undefined, the corresponding callback
799 will be disabled. There can only ever be one callback for a given
800 key.
801 As this callback gets called less often then the
803 "filter_json_object" one, decoding speed will not usually suffer as
804 much. Therefore, single-key objects make excellent targets to
805 serialize Perl objects into, especially as single-key JSON objects
806 are as close to the type-tagged value concept as JSON gets (it's
807 basically an ID/VALUE tuple). Of course, JSON does not support this
808 in any way, so you need to make sure your data never looks like a
809 serialized Perl hash.
810 Typical names for the single object key are "__class_whatever__",
812 or "$__dollars_are_rarely_used__$" or "}ugly_brace_placement", or
813 even things like "__class_md5sum(classname)__", to reduce the risk
814 of clashing with real hashes.
815 Example, decode JSON objects of the form "{ "__widget__" => <id> }"
817 into the corresponding $WIDGET{<id>} object:
818 # return whatever is in $WIDGET{5}:
820 Cpanel::JSON::XS
821 ->new
822 ->filter_json_single_key_object (__widget__ => sub {
823 $WIDGET{ $_[0] }
824 })
825 ->decode ('{"__widget__": 5')
826 # this can be used with a TO_JSON method in some "widget" class
828 # for serialization to json:
829 sub WidgetBase::TO_JSON {
830 my ($self) = @_;
831 unless ($self->{id}) {
833 $self->{id} = ..get..some..id..;
834 $WIDGET{$self->{id}} = $self;
835 }
836 { __widget__ => $self->{id} }
838 }
839 $json = $json->shrink ([$enable])
841 $enabled = $json->get_shrink
842 Perl usually over-allocates memory a bit when allocating space for
843 strings. This flag optionally resizes strings generated by either
844 "encode" or "decode" to their minimum size possible. This can save
845 memory when your JSON texts are either very very long or you have
846 many short strings. It will also try to downgrade any strings to
847 octet-form if possible: perl stores strings internally either in an
848 encoding called UTF-X or in octet-form. The latter cannot store
849 everything but uses less space in general (and some buggy Perl or C
850 code might even rely on that internal representation being used).
851 The actual definition of what shrink does might change in future
853 versions, but it will always try to save space at the expense of
854 time.
855 If $enable is true (or missing), the string returned by "encode"
857 will be shrunk-to-fit, while all strings generated by "decode" will
858 also be shrunk-to-fit.
859 If $enable is false, then the normal perl allocation algorithms are
861 used. If you work with your data, then this is likely to be
862 faster.
863 In the future, this setting might control other things, such as
865 converting strings that look like integers or floats into integers
866 or floats internally (there is no difference on the Perl level),
867 saving space.
868 $json = $json->max_depth ([$maximum_nesting_depth])
870 $max_depth = $json->get_max_depth
871 Sets the maximum nesting level (default 512) accepted while
872 encoding or decoding. If a higher nesting level is detected in JSON
873 text or a Perl data structure, then the encoder and decoder will
874 stop and croak at that point.
875 Nesting level is defined by number of hash- or arrayrefs that the
877 encoder needs to traverse to reach a given point or the number of
878 "{" or "[" characters without their matching closing parenthesis
879 crossed to reach a given character in a string.
880 Setting the maximum depth to one disallows any nesting, so that
882 ensures that the object is only a single hash/object or array.
883 If no argument is given, the highest possible setting will be used,
885 which is rarely useful.
886 Note that nesting is implemented by recursion in C. The default
888 value has been chosen to be as large as typical operating systems
889 allow without crashing.
890 See SECURITY CONSIDERATIONS, below, for more info on why this is
892 useful.
893 $json = $json->max_size ([$maximum_string_size])
895 $max_size = $json->get_max_size
896 Set the maximum length a JSON text may have (in bytes) where
897 decoding is being attempted. The default is 0, meaning no limit.
898 When "decode" is called on a string that is longer then this many
899 bytes, it will not attempt to decode the string but throw an
900 exception. This setting has no effect on "encode" (yet).
901 If no argument is given, the limit check will be deactivated (same
903 as when 0 is specified).
904 See "SECURITY CONSIDERATIONS", below, for more info on why this is
906 useful.
907 $json->stringify_infnan ([$infnan_mode = 1])
909 $infnan_mode = $json->get_stringify_infnan
910 Get or set how Cpanel::JSON::XS encodes "inf", "-inf" or "nan" for
911 numeric values. Also qnan, snan or negative nan on some platforms.
912 "null": infnan_mode = 0. Similar to most JSON modules in other
914 languages. Always null.
915 stringified: infnan_mode = 1. As in Mojo::JSON. Platform specific
917 strings. Stringified via sprintf(%g), with double quotes.
918 inf/nan: infnan_mode = 2. As in JSON::XS, and older releases.
920 Passes through platform dependent values, invalid JSON. Stringified
921 via sprintf(%g), but without double quotes.
922 "inf/-inf/nan": infnan_mode = 3. Platform independent inf/nan/-inf
924 strings. No QNAN/SNAN/negative NAN support, unified to "nan". Much
925 easier to detect, but may conflict with valid strings.
926 $json_text = $json->encode ($perl_scalar)
928 Converts the given Perl data structure (a simple scalar or a
929 reference to a hash or array) to its JSON representation. Simple
930 scalars will be converted into JSON string or number sequences,
931 while references to arrays become JSON arrays and references to
932 hashes become JSON objects. Undefined Perl values (e.g. "undef")
933 become JSON "null" values. Neither "true" nor "false" values will
934 be generated.
935 $perl_scalar = $json->decode ($json_text)
937 The opposite of "encode": expects a JSON text and tries to parse
938 it, returning the resulting simple scalar or reference. Croaks on
939 error.
940 JSON numbers and strings become simple Perl scalars. JSON arrays
942 become Perl arrayrefs and JSON objects become Perl hashrefs. "true"
943 becomes 1, "false" becomes 0 and "null" becomes "undef".
944 ($perl_scalar, $characters) = $json->decode_prefix ($json_text)
946 This works like the "decode" method, but instead of raising an
947 exception when there is trailing garbage after the first JSON
948 object, it will silently stop parsing there and return the number
949 of characters consumed so far.
950 This is useful if your JSON texts are not delimited by an outer
952 protocol and you need to know where the JSON text ends.
953 Cpanel::JSON::XS->new->decode_prefix ("[1] the tail")
955 => ([1], 3)
956 $json->to_json ($perl_hash_or_arrayref)
958 Deprecated method for perl 5.8 and newer. Use encode_json instead.
959 $json->from_json ($utf8_encoded_json_text)
961 Deprecated method for perl 5.8 and newer. Use decode_json instead.
962
964 In some cases, there is the need for incremental parsing of JSON texts.
965 While this module always has to keep both JSON text and resulting Perl
966 data structure in memory at one time, it does allow you to parse a JSON
967 stream incrementally. It does so by accumulating text until it has a
968 full JSON object, which it then can decode. This process is similar to
969 using "decode_prefix" to see if a full JSON object is available, but is
970 much more efficient (and can be implemented with a minimum of method
971 calls).
972 Cpanel::JSON::XS will only attempt to parse the JSON text once it is
974 sure it has enough text to get a decisive result, using a very simple
975 but truly incremental parser. This means that it sometimes won't stop
976 as early as the full parser, for example, it doesn't detect mismatched
977 parentheses. The only thing it guarantees is that it starts decoding as
978 soon as a syntactically valid JSON text has been seen. This means you
979 need to set resource limits (e.g. "max_size") to ensure the parser will
980 stop parsing in the presence if syntax errors.
981 The following methods implement this incremental parser.
983 [void, scalar or list context] = $json->incr_parse ([$string])
985 This is the central parsing function. It can both append new text
986 and extract objects from the stream accumulated so far (both of
987 these functions are optional).
988 If $string is given, then this string is appended to the already
990 existing JSON fragment stored in the $json object.
991 After that, if the function is called in void context, it will
993 simply return without doing anything further. This can be used to
994 add more text in as many chunks as you want.
995 If the method is called in scalar context, then it will try to
997 extract exactly one JSON object. If that is successful, it will
998 return this object, otherwise it will return "undef". If there is a
999 parse error, this method will croak just as "decode" would do (one
1000 can then use "incr_skip" to skip the erroneous part). This is the
1001 most common way of using the method.
1002 And finally, in list context, it will try to extract as many
1004 objects from the stream as it can find and return them, or the
1005 empty list otherwise. For this to work, there must be no separators
1006 between the JSON objects or arrays, instead they must be
1007 concatenated back-to-back. If an error occurs, an exception will be
1008 raised as in the scalar context case. Note that in this case, any
1009 previously-parsed JSON texts will be lost.
1010 Example: Parse some JSON arrays/objects in a given string and
1012 return them.
1013 my @objs = Cpanel::JSON::XS->new->incr_parse ("[5][7][1,2]");
1015 $lvalue_string = $json->incr_text (>5.8 only)
1017 This method returns the currently stored JSON fragment as an
1018 lvalue, that is, you can manipulate it. This only works when a
1019 preceding call to "incr_parse" in scalar context successfully
1020 returned an object, and 2. only with Perl >= 5.8
1021 Under all other circumstances you must not call this function (I
1023 mean it. although in simple tests it might actually work, it will
1024 fail under real world conditions). As a special exception, you can
1025 also call this method before having parsed anything.
1026 This function is useful in two cases: a) finding the trailing text
1028 after a JSON object or b) parsing multiple JSON objects separated
1029 by non-JSON text (such as commas).
1030 $json->incr_skip
1032 This will reset the state of the incremental parser and will remove
1033 the parsed text from the input buffer so far. This is useful after
1034 "incr_parse" died, in which case the input buffer and incremental
1035 parser state is left unchanged, to skip the text parsed so far and
1036 to reset the parse state.
1037 The difference to "incr_reset" is that only text until the parse
1039 error occurred is removed.
1040 $json->incr_reset
1042 This completely resets the incremental parser, that is, after this
1043 call, it will be as if the parser had never parsed anything.
1044 This is useful if you want to repeatedly parse JSON objects and
1046 want to ignore any trailing data, which means you have to reset the
1047 parser after each successful decode.
1048 LIMITATIONS
1050 All options that affect decoding are supported, except "allow_nonref".
1051 The reason for this is that it cannot be made to work sensibly: JSON
1052 objects and arrays are self-delimited, i.e. you can concatenate them
1053 back to back and still decode them perfectly. This does not hold true
1054 for JSON numbers, however.
1055 For example, is the string 1 a single JSON number, or is it simply the
1057 start of 12? Or is 12 a single JSON number, or the concatenation of 1
1058 and 2? In neither case you can tell, and this is why Cpanel::JSON::XS
1059 takes the conservative route and disallows this case.
1060 EXAMPLES
1062 Some examples will make all this clearer. First, a simple example that
1063 works similarly to "decode_prefix": We want to decode the JSON object
1064 at the start of a string and identify the portion after the JSON
1065 object:
1066 my $text = "[1,2,3] hello";
1068 my $json = new Cpanel::JSON::XS;
1070 my $obj = $json->incr_parse ($text)
1072 or die "expected JSON object or array at beginning of string";
1073 my $tail = $json->incr_text;
1075 # $tail now contains " hello"
1076 Easy, isn't it?
1078 Now for a more complicated example: Imagine a hypothetical protocol
1080 where you read some requests from a TCP stream, and each request is a
1081 JSON array, without any separation between them (in fact, it is often
1082 useful to use newlines as "separators", as these get interpreted as
1083 whitespace at the start of the JSON text, which makes it possible to
1084 test said protocol with "telnet"...).
1085 Here is how you'd do it (it is trivial to write this in an event-based
1087 manner):
1088 my $json = new Cpanel::JSON::XS;
1090 # read some data from the socket
1092 while (sysread $socket, my $buf, 4096) {
1093 # split and decode as many requests as possible
1095 for my $request ($json->incr_parse ($buf)) {
1096 # act on the $request
1097 }
1098 }
1099 Another complicated example: Assume you have a string with JSON objects
1101 or arrays, all separated by (optional) comma characters (e.g. "[1],[2],
1102 [3]"). To parse them, we have to skip the commas between the JSON
1103 texts, and here is where the lvalue-ness of "incr_text" comes in
1104 useful:
1105 my $text = "[1],[2], [3]";
1107 my $json = new Cpanel::JSON::XS;
1108 # void context, so no parsing done
1110 $json->incr_parse ($text);
1111 # now extract as many objects as possible. note the
1113 # use of scalar context so incr_text can be called.
1114 while (my $obj = $json->incr_parse) {
1115 # do something with $obj
1116 # now skip the optional comma
1118 $json->incr_text =~ s/^ \s* , //x;
1119 }
1120 Now lets go for a very complex example: Assume that you have a gigantic
1122 JSON array-of-objects, many gigabytes in size, and you want to parse
1123 it, but you cannot load it into memory fully (this has actually
1124 happened in the real world :).
1125 Well, you lost, you have to implement your own JSON parser. But
1127 Cpanel::JSON::XS can still help you: You implement a (very simple)
1128 array parser and let JSON decode the array elements, which are all full
1129 JSON objects on their own (this wouldn't work if the array elements
1130 could be JSON numbers, for example):
1131 my $json = new Cpanel::JSON::XS;
1133 # open the monster
1135 open my $fh, "<bigfile.json"
1136 or die "bigfile: $!";
1137 # first parse the initial "["
1139 for (;;) {
1140 sysread $fh, my $buf, 65536
1141 or die "read error: $!";
1142 $json->incr_parse ($buf); # void context, so no parsing
1143 # Exit the loop once we found and removed(!) the initial "[".
1145 # In essence, we are (ab-)using the $json object as a simple scalar
1146 # we append data to.
1147 last if $json->incr_text =~ s/^ \s* \[ //x;
1148 }
1149 # now we have the skipped the initial "[", so continue
1151 # parsing all the elements.
1152 for (;;) {
1153 # in this loop we read data until we got a single JSON object
1154 for (;;) {
1155 if (my $obj = $json->incr_parse) {
1156 # do something with $obj
1157 last;
1158 }
1159 # add more data
1161 sysread $fh, my $buf, 65536
1162 or die "read error: $!";
1163 $json->incr_parse ($buf); # void context, so no parsing
1164 }
1165 # in this loop we read data until we either found and parsed the
1167 # separating "," between elements, or the final "]"
1168 for (;;) {
1169 # first skip whitespace
1170 $json->incr_text =~ s/^\s*//;
1171 # if we find "]", we are done
1173 if ($json->incr_text =~ s/^\]//) {
1174 print "finished.\n";
1175 exit;
1176 }
1177 # if we find ",", we can continue with the next element
1179 if ($json->incr_text =~ s/^,//) {
1180 last;
1181 }
1182 # if we find anything else, we have a parse error!
1184 if (length $json->incr_text) {
1185 die "parse error near ", $json->incr_text;
1186 }
1187 # else add more data
1189 sysread $fh, my $buf, 65536
1190 or die "read error: $!";
1191 $json->incr_parse ($buf); # void context, so no parsing
1192 }
1193 This is a complex example, but most of the complexity comes from the
1195 fact that we are trying to be correct (bear with me if I am wrong, I
1196 never ran the above example :).
1197
1199 Detect all unicode Byte Order Marks on decode. Which are UTF-8,
1200 UTF-16LE, UTF-16BE, UTF-32LE and UTF-32BE.
1201 Warning: With perls older than 5.20 you need load the Encode module
1203 before loading a multibyte BOM, i.e. >= UTF-16. Otherwise an error is
1204 thrown. This is an implementation limitation and might get fixed later.
1205 See <https://tools.ietf.org/html/rfc7159#section-8.1> "JSON text SHALL
1207 be encoded in UTF-8, UTF-16, or UTF-32."
1208 "Implementations MUST NOT add a byte order mark to the beginning of a
1210 JSON text", "implementations (...) MAY ignore the presence of a byte
1211 order mark rather than treating it as an error".
1212 See also <http://www.unicode.org/faq/utf_bom.html#BOM>.
1214 Beware that Cpanel::JSON::XS is currently the only JSON module which
1216 does accept and decode a BOM.
1217 The latest JSON spec
1219 <https://www.greenbytes.de/tech/webdav/rfc8259.html#character.encoding>
1220 forbid the usage of UTF-16 or UTF-32, the character encoding is UTF-8.
1221 Thus in subsequent updates BOM's of UTF-16 or UTF-32 will throw an
1222 error.
1223
1225 This section describes how Cpanel::JSON::XS maps Perl values to JSON
1226 values and vice versa. These mappings are designed to "do the right
1227 thing" in most circumstances automatically, preserving round-tripping
1228 characteristics (what you put in comes out as something equivalent).
1229 For the more enlightened: note that in the following descriptions,
1231 lowercase perl refers to the Perl interpreter, while uppercase Perl
1232 refers to the abstract Perl language itself.
1233 JSON -> PERL
1235 object
1236 A JSON object becomes a reference to a hash in Perl. No ordering of
1237 object keys is preserved (JSON does not preserve object key
1238 ordering itself).
1239 array
1241 A JSON array becomes a reference to an array in Perl.
1242 string
1244 A JSON string becomes a string scalar in Perl - Unicode codepoints
1245 in JSON are represented by the same codepoints in the Perl string,
1246 so no manual decoding is necessary.
1247 number
1249 A JSON number becomes either an integer, numeric (floating point)
1250 or string scalar in perl, depending on its range and any fractional
1251 parts. On the Perl level, there is no difference between those as
1252 Perl handles all the conversion details, but an integer may take
1253 slightly less memory and might represent more values exactly than
1254 floating point numbers.
1255 If the number consists of digits only, Cpanel::JSON::XS will try to
1257 represent it as an integer value. If that fails, it will try to
1258 represent it as a numeric (floating point) value if that is
1259 possible without loss of precision. Otherwise it will preserve the
1260 number as a string value (in which case you lose roundtripping
1261 ability, as the JSON number will be re-encoded to a JSON string).
1262 Numbers containing a fractional or exponential part will always be
1264 represented as numeric (floating point) values, possibly at a loss
1265 of precision (in which case you might lose perfect roundtripping
1266 ability, but the JSON number will still be re-encoded as a JSON
1267 number).
1268 Note that precision is not accuracy - binary floating point values
1270 cannot represent most decimal fractions exactly, and when
1271 converting from and to floating point, "Cpanel::JSON::XS" only
1272 guarantees precision up to but not including the least significant
1273 bit.
1274 true, false
1276 These JSON atoms become "Cpanel::JSON::XS::true" and
1277 "Cpanel::JSON::XS::false", respectively. They are
1278 "JSON::PP::Boolean" objects and are overloaded to act almost
1279 exactly like the numbers 1 and 0. You can check whether a scalar is
1280 a JSON boolean by using the "Cpanel::JSON::XS::is_bool" function.
1281 The other round, from perl to JSON, "!0" which is represented as
1283 "yes" becomes "true", and "!1" which is represented as "no" becomes
1284 "false".
1285 Via Cpanel::JSON::XS::Type you can now even force negation in
1287 "encode", without overloading of "!":
1288 my $false = Cpanel::JSON::XS::false;
1290 print($json->encode([!$false], [JSON_TYPE_BOOL]));
1291 => [true]
1292 null
1294 A JSON null atom becomes "undef" in Perl.
1295 shell-style comments ("# text")
1297 As a nonstandard extension to the JSON syntax that is enabled by
1298 the "relaxed" setting, shell-style comments are allowed. They can
1299 start anywhere outside strings and go till the end of the line.
1300 tagged values ("(tag)value").
1302 Another nonstandard extension to the JSON syntax, enabled with the
1303 "allow_tags" setting, are tagged values. In this implementation,
1304 the tag must be a perl package/class name encoded as a JSON string,
1305 and the value must be a JSON array encoding optional constructor
1306 arguments.
1307 See "OBJECT SERIALIZATION", below, for details.
1309 PERL -> JSON
1311 The mapping from Perl to JSON is slightly more difficult, as Perl is a
1312 truly typeless language, so we can only guess which JSON type is meant
1313 by a Perl value.
1314 hash references
1316 Perl hash references become JSON objects. As there is no inherent
1317 ordering in hash keys (or JSON objects), they will usually be
1318 encoded in a pseudo-random order that can change between runs of
1319 the same program but stays generally the same within a single run
1320 of a program. Cpanel::JSON::XS can optionally sort the hash keys
1321 (determined by the canonical flag), so the same datastructure will
1322 serialize to the same JSON text (given same settings and version of
1323 Cpanel::JSON::XS), but this incurs a runtime overhead and is only
1324 rarely useful, e.g. when you want to compare some JSON text against
1325 another for equality.
1326 array references
1328 Perl array references become JSON arrays.
1329 other references
1331 Other unblessed references are generally not allowed and will cause
1332 an exception to be thrown, except for references to the integers 0
1333 and 1, which get turned into "false" and "true" atoms in JSON.
1334 With the option "allow_stringify", you can ignore the exception and
1336 return the stringification of the perl value.
1337 With the option "allow_unknown", you can ignore the exception and
1339 return "null" instead.
1340 encode_json [\"x"] # => cannot encode reference to scalar 'SCALAR(0x..)'
1342 # unless the scalar is 0 or 1
1343 encode_json [\0, \1] # yields [false,true]
1344 allow_stringify->encode_json [\"x"] # yields "x" unlike JSON::PP
1346 allow_unknown->encode_json [\"x"] # yields null as in JSON::PP
1347 Cpanel::JSON::XS::true, Cpanel::JSON::XS::false
1349 These special values become JSON true and JSON false values,
1350 respectively. You can also use "\1" and "\0" or "!0" and "!1"
1351 directly if you want.
1352 encode_json [Cpanel::JSON::XS::true, Cpanel::JSON::XS::true] # yields [false,true]
1354 encode_json [!1, !0] # yields [false,true]
1355 eq/ne comparisons with true, false:
1357 false is eq to the empty string or the string 'false' or the
1359 special empty string "!!0", i.e. "SV_NO", or the numbers 0 or 0.0.
1360 true is eq to the string 'true' or to the special string "!0" (i.e.
1362 "SV_YES") or to the numbers 1 or 1.0.
1363 blessed objects
1365 Blessed objects are not directly representable in JSON, but
1366 "Cpanel::JSON::XS" allows various optional ways of handling
1367 objects. See "OBJECT SERIALIZATION", below, for details.
1368 See the "allow_blessed" and "convert_blessed" methods on various
1370 options on how to deal with this: basically, you can choose between
1371 throwing an exception, encoding the reference as if it weren't
1372 blessed, use the objects overloaded stringification method or
1373 provide your own serializer method.
1374 simple scalars
1376 Simple Perl scalars (any scalar that is not a reference) are the
1377 most difficult objects to encode: Cpanel::JSON::XS will encode
1378 undefined scalars or inf/nan as JSON "null" values, scalars that
1379 have last been used in a string context before encoding as JSON
1380 strings, and anything else as number value:
1381 # dump as number
1383 encode_json [2] # yields [2]
1384 encode_json [-3.0e17] # yields [-3e+17]
1385 my $value = 5; encode_json [$value] # yields [5]
1386 # used as string, but the two representations are for the same number
1388 print $value;
1389 encode_json [$value] # yields [5]
1390 # used as different string (non-matching dual-var)
1392 my $str = '0 but true';
1393 my $num = 1 + $str;
1394 encode_json [$num, $str] # yields [1,"0 but true"]
1395 # undef becomes null
1397 encode_json [undef] # yields [null]
1398 # inf or nan becomes null, unless you answered
1400 # "Do you want to handle inf/nan as strings" with yes
1401 encode_json [9**9**9] # yields [null]
1402 You can force the type to be a JSON string by stringifying it:
1404 my $x = 3.1; # some variable containing a number
1406 "$x"; # stringified
1407 $x .= ""; # another, more awkward way to stringify
1408 print $x; # perl does it for you, too, quite often
1409 You can force the type to be a JSON number by numifying it:
1411 my $x = "3"; # some variable containing a string
1413 $x += 0; # numify it, ensuring it will be dumped as a number
1414 $x *= 1; # same thing, the choice is yours.
1415 Note that numerical precision has the same meaning as under Perl
1417 (so binary to decimal conversion follows the same rules as in Perl,
1418 which can differ to other languages). Also, your perl interpreter
1419 might expose extensions to the floating point numbers of your
1420 platform, such as infinities or NaN's - these cannot be represented
1421 in JSON, and thus null is returned instead. Optionally you can
1422 configure it to stringify inf and nan values.
1423 OBJECT SERIALIZATION
1425 As JSON cannot directly represent Perl objects, you have to choose
1426 between a pure JSON representation (without the ability to deserialize
1427 the object automatically again), and a nonstandard extension to the
1428 JSON syntax, tagged values.
1429 SERIALIZATION
1431 What happens when "Cpanel::JSON::XS" encounters a Perl object depends
1433 on the "allow_blessed", "convert_blessed" and "allow_tags" settings,
1434 which are used in this order:
1435 1. "allow_tags" is enabled and the object has a "FREEZE" method.
1437 In this case, "Cpanel::JSON::XS" uses the Types::Serialiser object
1438 serialization protocol to create a tagged JSON value, using a
1439 nonstandard extension to the JSON syntax.
1440 This works by invoking the "FREEZE" method on the object, with the
1442 first argument being the object to serialize, and the second
1443 argument being the constant string "JSON" to distinguish it from
1444 other serializers.
1445 The "FREEZE" method can return any number of values (i.e. zero or
1447 more). These values and the paclkage/classname of the object will
1448 then be encoded as a tagged JSON value in the following format:
1449 ("classname")[FREEZE return values...]
1451 e.g.:
1453 ("URI")["http://www.google.com/"]
1455 ("MyDate")[2013,10,29]
1456 ("ImageData::JPEG")["Z3...VlCg=="]
1457 For example, the hypothetical "My::Object" "FREEZE" method might
1459 use the objects "type" and "id" members to encode the object:
1460 sub My::Object::FREEZE {
1462 my ($self, $serializer) = @_;
1463 ($self->{type}, $self->{id})
1465 }
1466 2. "convert_blessed" is enabled and the object has a "TO_JSON" method.
1468 In this case, the "TO_JSON" method of the object is invoked in
1469 scalar context. It must return a single scalar that can be directly
1470 encoded into JSON. This scalar replaces the object in the JSON
1471 text.
1472 For example, the following "TO_JSON" method will convert all URI
1474 objects to JSON strings when serialized. The fact that these values
1475 originally were URI objects is lost.
1476 sub URI::TO_JSON {
1478 my ($uri) = @_;
1479 $uri->as_string
1480 }
1481 2. "convert_blessed" is enabled and the object has a stringification
1483 overload.
1484 In this case, the overloaded "" method of the object is invoked in
1485 scalar context. It must return a single scalar that can be directly
1486 encoded into JSON. This scalar replaces the object in the JSON
1487 text.
1488 For example, the following "" method will convert all URI objects
1490 to JSON strings when serialized. The fact that these values
1491 originally were URI objects is lost.
1492 package URI;
1494 use overload '""' => sub { shift->as_string };
1495 3. "allow_blessed" is enabled.
1497 The object will be serialized as a JSON null value.
1498 4. none of the above
1500 If none of the settings are enabled or the respective methods are
1501 missing, "Cpanel::JSON::XS" throws an exception.
1502 DESERIALIZATION
1504 For deserialization there are only two cases to consider: either
1506 nonstandard tagging was used, in which case "allow_tags" decides, or
1507 objects cannot be automatically be deserialized, in which case you can
1508 use postprocessing or the "filter_json_object" or
1509 "filter_json_single_key_object" callbacks to get some real objects our
1510 of your JSON.
1511 This section only considers the tagged value case: I a tagged JSON
1513 object is encountered during decoding and "allow_tags" is disabled, a
1514 parse error will result (as if tagged values were not part of the
1515 grammar).
1516 If "allow_tags" is enabled, "Cpanel::JSON::XS" will look up the "THAW"
1518 method of the package/classname used during serialization (it will not
1519 attempt to load the package as a Perl module). If there is no such
1520 method, the decoding will fail with an error.
1521 Otherwise, the "THAW" method is invoked with the classname as first
1523 argument, the constant string "JSON" as second argument, and all the
1524 values from the JSON array (the values originally returned by the
1525 "FREEZE" method) as remaining arguments.
1526 The method must then return the object. While technically you can
1528 return any Perl scalar, you might have to enable the "enable_nonref"
1529 setting to make that work in all cases, so better return an actual
1530 blessed reference.
1531 As an example, let's implement a "THAW" function that regenerates the
1533 "My::Object" from the "FREEZE" example earlier:
1534 sub My::Object::THAW {
1536 my ($class, $serializer, $type, $id) = @_;
1537 $class->new (type => $type, id => $id)
1539 }
1540 See the "SECURITY CONSIDERATIONS" section below. Allowing external json
1542 objects being deserialized to perl objects is usually a very bad idea.
1543
1545 The interested reader might have seen a number of flags that signify
1546 encodings or codesets - "utf8", "latin1", "binary" and "ascii". There
1547 seems to be some confusion on what these do, so here is a short
1548 comparison:
1549 "utf8" controls whether the JSON text created by "encode" (and expected
1551 by "decode") is UTF-8 encoded or not, while "latin1" and "ascii" only
1552 control whether "encode" escapes character values outside their
1553 respective codeset range. Neither of these flags conflict with each
1554 other, although some combinations make less sense than others.
1555 Care has been taken to make all flags symmetrical with respect to
1557 "encode" and "decode", that is, texts encoded with any combination of
1558 these flag values will be correctly decoded when the same flags are
1559 used - in general, if you use different flag settings while encoding
1560 vs. when decoding you likely have a bug somewhere.
1561 Below comes a verbose discussion of these flags. Note that a "codeset"
1563 is simply an abstract set of character-codepoint pairs, while an
1564 encoding takes those codepoint numbers and encodes them, in our case
1565 into octets. Unicode is (among other things) a codeset, UTF-8 is an
1566 encoding, and ISO-8859-1 (= latin 1) and ASCII are both codesets and
1567 encodings at the same time, which can be confusing.
1568 "utf8" flag disabled
1570 When "utf8" is disabled (the default), then "encode"/"decode"
1571 generate and expect Unicode strings, that is, characters with high
1572 ordinal Unicode values (> 255) will be encoded as such characters,
1573 and likewise such characters are decoded as-is, no changes to them
1574 will be done, except "(re-)interpreting" them as Unicode codepoints
1575 or Unicode characters, respectively (to Perl, these are the same
1576 thing in strings unless you do funny/weird/dumb stuff).
1577 This is useful when you want to do the encoding yourself (e.g. when
1579 you want to have UTF-16 encoded JSON texts) or when some other
1580 layer does the encoding for you (for example, when printing to a
1581 terminal using a filehandle that transparently encodes to UTF-8 you
1582 certainly do NOT want to UTF-8 encode your data first and have Perl
1583 encode it another time).
1584 "utf8" flag enabled
1586 If the "utf8"-flag is enabled, "encode"/"decode" will encode all
1587 characters using the corresponding UTF-8 multi-byte sequence, and
1588 will expect your input strings to be encoded as UTF-8, that is, no
1589 "character" of the input string must have any value > 255, as UTF-8
1590 does not allow that.
1591 The "utf8" flag therefore switches between two modes: disabled
1593 means you will get a Unicode string in Perl, enabled means you get
1594 an UTF-8 encoded octet/binary string in Perl.
1595 "latin1", "binary" or "ascii" flags enabled
1597 With "latin1" (or "ascii") enabled, "encode" will escape characters
1598 with ordinal values > 255 (> 127 with "ascii") and encode the
1599 remaining characters as specified by the "utf8" flag. With
1600 "binary" enabled, ordinal values > 255 are illegal.
1601 If "utf8" is disabled, then the result is also correctly encoded in
1603 those character sets (as both are proper subsets of Unicode,
1604 meaning that a Unicode string with all character values < 256 is
1605 the same thing as a ISO-8859-1 string, and a Unicode string with
1606 all character values < 128 is the same thing as an ASCII string in
1607 Perl).
1608 If "utf8" is enabled, you still get a correct UTF-8-encoded string,
1610 regardless of these flags, just some more characters will be
1611 escaped using "\uXXXX" then before.
1612 Note that ISO-8859-1-encoded strings are not compatible with UTF-8
1614 encoding, while ASCII-encoded strings are. That is because the
1615 ISO-8859-1 encoding is NOT a subset of UTF-8 (despite the
1616 ISO-8859-1 codeset being a subset of Unicode), while ASCII is.
1617 Surprisingly, "decode" will ignore these flags and so treat all
1619 input values as governed by the "utf8" flag. If it is disabled,
1620 this allows you to decode ISO-8859-1- and ASCII-encoded strings, as
1621 both strict subsets of Unicode. If it is enabled, you can correctly
1622 decode UTF-8 encoded strings.
1623 So neither "latin1", "binary" nor "ascii" are incompatible with the
1625 "utf8" flag - they only govern when the JSON output engine escapes
1626 a character or not.
1627 The main use for "latin1" or "binary" is to relatively efficiently
1629 store binary data as JSON, at the expense of breaking compatibility
1630 with most JSON decoders.
1631 The main use for "ascii" is to force the output to not contain
1633 characters with values > 127, which means you can interpret the
1634 resulting string as UTF-8, ISO-8859-1, ASCII, KOI8-R or most about
1635 any character set and 8-bit-encoding, and still get the same data
1636 structure back. This is useful when your channel for JSON transfer
1637 is not 8-bit clean or the encoding might be mangled in between
1638 (e.g. in mail), and works because ASCII is a proper subset of most
1639 8-bit and multibyte encodings in use in the world.
1640 JSON and ECMAscript
1642 JSON syntax is based on how literals are represented in javascript (the
1643 not-standardized predecessor of ECMAscript) which is presumably why it
1644 is called "JavaScript Object Notation".
1645 However, JSON is not a subset (and also not a superset of course) of
1647 ECMAscript (the standard) or javascript (whatever browsers actually
1648 implement).
1649 If you want to use javascript's "eval" function to "parse" JSON, you
1651 might run into parse errors for valid JSON texts, or the resulting data
1652 structure might not be queryable:
1653 One of the problems is that U+2028 and U+2029 are valid characters
1655 inside JSON strings, but are not allowed in ECMAscript string literals,
1656 so the following Perl fragment will not output something that can be
1657 guaranteed to be parsable by javascript's "eval":
1658 use Cpanel::JSON::XS;
1660 print encode_json [chr 0x2028];
1662 The right fix for this is to use a proper JSON parser in your
1664 javascript programs, and not rely on "eval" (see for example Douglas
1665 Crockford's json2.js parser).
1666 If this is not an option, you can, as a stop-gap measure, simply encode
1668 to ASCII-only JSON:
1669 use Cpanel::JSON::XS;
1671 print Cpanel::JSON::XS->new->ascii->encode ([chr 0x2028]);
1673 Note that this will enlarge the resulting JSON text quite a bit if you
1675 have many non-ASCII characters. You might be tempted to run some
1676 regexes to only escape U+2028 and U+2029, e.g.:
1677 # DO NOT USE THIS!
1679 my $json = Cpanel::JSON::XS->new->utf8->encode ([chr 0x2028]);
1680 $json =~ s/\xe2\x80\xa8/\\u2028/g; # escape U+2028
1681 $json =~ s/\xe2\x80\xa9/\\u2029/g; # escape U+2029
1682 print $json;
1683 Note that this is a bad idea: the above only works for U+2028 and
1685 U+2029 and thus only for fully ECMAscript-compliant parsers. Many
1686 existing javascript implementations, however, have issues with other
1687 characters as well - using "eval" naively simply will cause problems.
1688 Another problem is that some javascript implementations reserve some
1690 property names for their own purposes (which probably makes them non-
1691 ECMAscript-compliant). For example, Iceweasel reserves the "__proto__"
1692 property name for its own purposes.
1693 If that is a problem, you could parse try to filter the resulting JSON
1695 output for these property strings, e.g.:
1696 $json =~ s/"__proto__"\s*:/"__proto__renamed":/g;
1698 This works because "__proto__" is not valid outside of strings, so
1700 every occurrence of ""__proto__"\s*:" must be a string used as property
1701 name.
1702 Unicode non-characters between U+FFFD and U+10FFFF are decoded either
1704 to the recommended U+FFFD REPLACEMENT CHARACTER (see Unicode PR #121:
1705 Recommended Practice for Replacement Characters), or in the binary or
1706 relaxed mode left as is, keeping the illegal non-characters as before.
1707 Raw non-Unicode characters outside the valid unicode range fail now to
1709 parse, because "A string is a sequence of zero or more Unicode
1710 characters" RFC 7159 section 1 and "JSON text SHALL be encoded in
1711 Unicode RFC 7159 section 8.1. We use now the UTF8_DISALLOW_SUPER flag
1712 when parsing unicode.
1713 If you know of other incompatibilities, please let me know.
1715 JSON and YAML
1717 You often hear that JSON is a subset of YAML. in general, there is no
1718 way to configure JSON::XS to output a data structure as valid YAML that
1719 works in all cases. If you really must use Cpanel::JSON::XS to
1720 generate YAML, you should use this algorithm (subject to change in
1721 future versions):
1722 my $to_yaml = Cpanel::JSON::XS->new->utf8->space_after (1);
1724 my $yaml = $to_yaml->encode ($ref) . "\n";
1725 This will usually generate JSON texts that also parse as valid YAML.
1727 SPEED
1729 It seems that JSON::XS is surprisingly fast, as shown in the following
1730 tables. They have been generated with the help of the "eg/bench"
1731 program in the JSON::XS distribution, to make it easy to compare on
1732 your own system.
1733 JSON::XS is with Data::MessagePack and Sereal one of the fastest
1735 serializers, because JSON and JSON::XS do not support backrefs (no
1736 graph structures), only trees. Storable supports backrefs, i.e. graphs.
1737 Data::MessagePack encodes its data binary (as Storable) and supports
1738 only very simple subset of JSON.
1739 First comes a comparison between various modules using a very short
1741 single-line JSON string (also available at
1742 <http://dist.schmorp.de/misc/json/short.json>).
1743 {"method": "handleMessage", "params": ["user1",
1745 "we were just talking"], "id": null, "array":[1,11,234,-5,1e5,1e7,
1746 1, 0]}
1747 It shows the number of encodes/decodes per second (JSON::XS uses the
1749 functional interface, while Cpanel::JSON::XS/2 uses the OO interface
1750 with pretty-printing and hash key sorting enabled, Cpanel::JSON::XS/3
1751 enables shrink. JSON::DWIW/DS uses the deserialize function, while
1752 JSON::DWIW::FJ uses the from_json method). Higher is better:
1753 module | encode | decode |
1755 --------------|------------|------------|
1756 JSON::DWIW/DS | 86302.551 | 102300.098 |
1757 JSON::DWIW/FJ | 86302.551 | 75983.768 |
1758 JSON::PP | 15827.562 | 6638.658 |
1759 JSON::Syck | 63358.066 | 47662.545 |
1760 JSON::XS | 511500.488 | 511500.488 |
1761 JSON::XS/2 | 291271.111 | 388361.481 |
1762 JSON::XS/3 | 361577.931 | 361577.931 |
1763 Storable | 66788.280 | 265462.278 |
1764 --------------+------------+------------+
1765 That is, JSON::XS is almost six times faster than JSON::DWIW on
1767 encoding, about five times faster on decoding, and over thirty to
1768 seventy times faster than JSON's pure perl implementation. It also
1769 compares favourably to Storable for small amounts of data.
1770 Using a longer test string (roughly 18KB, generated from Yahoo! Locals
1772 search API (<http://dist.schmorp.de/misc/json/long.json>).
1773 module | encode | decode |
1775 --------------|------------|------------|
1776 JSON::DWIW/DS | 1647.927 | 2673.916 |
1777 JSON::DWIW/FJ | 1630.249 | 2596.128 |
1778 JSON::PP | 400.640 | 62.311 |
1779 JSON::Syck | 1481.040 | 1524.869 |
1780 JSON::XS | 20661.596 | 9541.183 |
1781 JSON::XS/2 | 10683.403 | 9416.938 |
1782 JSON::XS/3 | 20661.596 | 9400.054 |
1783 Storable | 19765.806 | 10000.725 |
1784 --------------+------------+------------+
1785 Again, JSON::XS leads by far (except for Storable which non-
1787 surprisingly decodes a bit faster).
1788 On large strings containing lots of high Unicode characters, some
1790 modules (such as JSON::PC) seem to decode faster than JSON::XS, but the
1791 result will be broken due to missing (or wrong) Unicode handling.
1792 Others refuse to decode or encode properly, so it was impossible to
1793 prepare a fair comparison table for that case.
1794 For updated graphs see
1796 <https://github.com/Sereal/Sereal/wiki/Sereal-Comparison-Graphs>
1797
1799 As long as you only serialize data that can be directly expressed in
1800 JSON, "Cpanel::JSON::XS" is incapable of generating invalid JSON output
1801 (modulo bugs, but "JSON::XS" has found more bugs in the official JSON
1802 testsuite (1) than the official JSON testsuite has found in "JSON::XS"
1803 (0)). "Cpanel::JSON::XS" is currently the only known JSON decoder
1804 which passes all <http://seriot.ch/parsing_json.html> tests, while
1805 being the fastest also.
1806 When you have trouble decoding JSON generated by this module using
1808 other decoders, then it is very likely that you have an encoding
1809 mismatch or the other decoder is broken.
1810 When decoding, "JSON::XS" is strict by default and will likely catch
1812 all errors. There are currently two settings that change this:
1813 "relaxed" makes "JSON::XS" accept (but not generate) some non-standard
1814 extensions, and "allow_tags" or "allow_blessed" will allow you to
1815 encode and decode Perl objects, at the cost of being totally insecure
1816 and not outputting valid JSON anymore.
1817 JSON-XS-3.01 broke interoperability with JSON-2.90 with booleans. See
1819 JSON.
1820 Cpanel::JSON::XS needs to know the JSON and JSON::XS versions to be
1822 able work with those objects, especially when encoding a booleans like
1823 "{"is_true":true}". So you need to load these modules before.
1824 true/false overloading and boolean representations are supported.
1826 JSON::XS and JSON::PP representations are accepted and older JSON::XS
1828 accepts Cpanel::JSON::XS booleans. All JSON modules JSON, JSON, PP,
1829 JSON::XS, Cpanel::JSON::XS produce JSON::PP::Boolean objects, just Mojo
1830 and JSON::YAJL not. Mojo produces Mojo::JSON::_Bool and
1831 JSON::YAJL::Parser just an unblessed IV.
1832 Cpanel::JSON::XS accepts JSON::PP::Boolean and Mojo::JSON::_Bool
1834 objects as booleans.
1835 I cannot think of any reason to still use JSON::XS anymore.
1837 TAGGED VALUE SYNTAX AND STANDARD JSON EN/DECODERS
1839 When you use "allow_tags" to use the extended (and also nonstandard and
1840 invalid) JSON syntax for serialized objects, and you still want to
1841 decode the generated serialize objects, you can run a regex to replace
1842 the tagged syntax by standard JSON arrays (it only works for "normal"
1843 package names without comma, newlines or single colons). First, the
1844 readable Perl version:
1845 # if your FREEZE methods return no values, you need this replace first:
1847 $json =~ s/\( \s* (" (?: [^\\":,]+|\\.|::)* ") \s* \) \s* \[\s*\]/[$1]/gx;
1848 # this works for non-empty constructor arg lists:
1850 $json =~ s/\( \s* (" (?: [^\\":,]+|\\.|::)* ") \s* \) \s* \[/[$1,/gx;
1851 And here is a less readable version that is easy to adapt to other
1853 languages:
1854 $json =~ s/\(\s*("([^\\":,]+|\\.|::)*")\s*\)\s*\[/[$1,/g;
1856 Here is an ECMAScript version (same regex):
1858 json = json.replace (/\(\s*("([^\\":,]+|\\.|::)*")\s*\)\s*\[/g, "[$1,");
1860 Since this syntax converts to standard JSON arrays, it might be hard to
1862 distinguish serialized objects from normal arrays. You can prepend a
1863 "magic number" as first array element to reduce chances of a collision:
1864 $json =~ s/\(\s*("([^\\":,]+|\\.|::)*")\s*\)\s*\[/["XU1peReLzT4ggEllLanBYq4G9VzliwKF",$1,/g;
1866 And after decoding the JSON text, you could walk the data structure
1868 looking for arrays with a first element of
1869 "XU1peReLzT4ggEllLanBYq4G9VzliwKF".
1870 The same approach can be used to create the tagged format with another
1872 encoder. First, you create an array with the magic string as first
1873 member, the classname as second, and constructor arguments last, encode
1874 it as part of your JSON structure, and then:
1875 $json =~ s/\[\s*"XU1peReLzT4ggEllLanBYq4G9VzliwKF"\s*,\s*("([^\\":,]+|\\.|::)*")\s*,/($1)[/g;
1877 Again, this has some limitations - the magic string must not be encoded
1879 with character escapes, and the constructor arguments must be non-
1880 empty.
1881
1883 Since this module was written, Google has written a new JSON RFC, RFC
1884 7159 (and RFC7158). Unfortunately, this RFC breaks compatibility with
1885 both the original JSON specification on www.json.org and RFC4627.
1886 As far as I can see, you can get partial compatibility when parsing by
1888 using "->allow_nonref". However, consider the security implications of
1889 doing so.
1890 I haven't decided yet when to break compatibility with RFC4627 by
1892 default (and potentially leave applications insecure) and change the
1893 default to follow RFC7159, but application authors are well advised to
1894 call "->allow_nonref(0)" even if this is the current default, if they
1895 cannot handle non-reference values, in preparation for the day when the
1896 default will change.
1897
1899 JSON::XS and Cpanel::JSON::XS are not only fast. JSON is generally the
1900 most secure serializing format, because it is the only one besides
1901 Data::MessagePack, which does not deserialize objects per default. For
1902 all languages, not just perl. The binary variant BSON (MongoDB) does
1903 more but is unsafe.
1904 It is trivial for any attacker to create such serialized objects in
1906 JSON and trick perl into expanding them, thereby triggering certain
1907 methods. Watch <https://www.youtube.com/watch?v=Gzx6KlqiIZE> for an
1908 exploit demo for "CVE-2015-1592 SixApart MovableType Storable Perl Code
1909 Execution" for a deserializer which expands objects. Deserializing
1910 even coderefs (methods, functions) or external data would be considered
1911 the most dangerous.
1912 Security relevant overview of serializers regarding deserializing
1914 objects by default:
1915 Objects Coderefs External Data
1917 Data::Dumper YES YES YES
1919 Storable YES NO (def) NO
1920 Sereal YES NO NO
1921 YAML YES NO NO
1922 B::C YES YES YES
1923 B::Bytecode YES YES YES
1924 BSON YES YES NO
1925 JSON::SL YES NO YES
1926 JSON NO (def) NO NO
1927 Data::MessagePack NO NO NO
1928 XML NO NO YES
1929 Pickle YES YES YES
1931 PHP Deserialize YES NO NO
1932 When you are using JSON in a protocol, talking to untrusted potentially
1934 hostile creatures requires relatively few measures.
1935 First of all, your JSON decoder should be secure, that is, should not
1937 have any buffer overflows. Obviously, this module should ensure that.
1938 Second, you need to avoid resource-starving attacks. That means you
1940 should limit the size of JSON texts you accept, or make sure then when
1941 your resources run out, that's just fine (e.g. by using a separate
1942 process that can crash safely). The size of a JSON text in octets or
1943 characters is usually a good indication of the size of the resources
1944 required to decode it into a Perl structure. While JSON::XS can check
1945 the size of the JSON text, it might be too late when you already have
1946 it in memory, so you might want to check the size before you accept the
1947 string.
1948 Third, Cpanel::JSON::XS recurses using the C stack when decoding
1950 objects and arrays. The C stack is a limited resource: for instance, on
1951 my amd64 machine with 8MB of stack size I can decode around 180k nested
1952 arrays but only 14k nested JSON objects (due to perl itself recursing
1953 deeply on croak to free the temporary). If that is exceeded, the
1954 program crashes. To be conservative, the default nesting limit is set
1955 to 512. If your process has a smaller stack, you should adjust this
1956 setting accordingly with the "max_depth" method.
1957 Also keep in mind that Cpanel::JSON::XS might leak contents of your
1959 Perl data structures in its error messages, so when you serialize
1960 sensitive information you might want to make sure that exceptions
1961 thrown by JSON::XS will not end up in front of untrusted eyes.
1962 If you are using Cpanel::JSON::XS to return packets to consumption by
1964 JavaScript scripts in a browser you should have a look at
1965 <http://blog.archive.jpsykes.com/47/practical-csrf-and-json-security/>
1966 to see whether you are vulnerable to some common attack vectors (which
1967 really are browser design bugs, but it is still you who will have to
1968 deal with it, as major browser developers care only for features, not
1969 about getting security right). You might also want to also look at
1970 Mojo::JSON special escape rules to prevent from XSS attacks.
1971
1973 TL;DR: Due to security concerns, Cpanel::JSON::XS will not allow scalar
1974 data in JSON texts by default - you need to create your own
1975 Cpanel::JSON::XS object and enable "allow_nonref":
1976 my $json = JSON::XS->new->allow_nonref;
1978 $text = $json->encode ($data);
1980 $data = $json->decode ($text);
1981 The long version: JSON being an important and supposedly stable format,
1983 the IETF standardized it as RFC 4627 in 2006. Unfortunately the
1984 inventor of JSON Douglas Crockford unilaterally changed the definition
1985 of JSON in javascript. Rather than create a fork, the IETF decided to
1986 standardize the new syntax (apparently, so I as told, without finding
1987 it very amusing).
1988 The biggest difference between the original JSON and the new JSON is
1990 that the new JSON supports scalars (anything other than arrays and
1991 objects) at the top-level of a JSON text. While this is strictly
1992 backwards compatible to older versions, it breaks a number of protocols
1993 that relied on sending JSON back-to-back, and is a minor security
1994 concern.
1995 For example, imagine you have two banks communicating, and on one side,
1997 the JSON coder gets upgraded. Two messages, such as 10 and 1000 might
1998 then be confused to mean 101000, something that couldn't happen in the
1999 original JSON, because neither of these messages would be valid JSON.
2000 If one side accepts these messages, then an upgrade in the coder on
2002 either side could result in this becoming exploitable.
2003 This module has always allowed these messages as an optional extension,
2005 by default disabled. The security concerns are the reason why the
2006 default is still disabled, but future versions might/will likely
2007 upgrade to the newer RFC as default format, so you are advised to check
2008 your implementation and/or override the default with "->allow_nonref
2009 (0)" to ensure that future versions are safe.
2010
2012 Cpanel::JSON::XS has proper ithreads support, unlike JSON::XS. If you
2013 encounter any bugs with thread support please report them.
2014
2016 While the goal of the Cpanel::JSON::XS module is to be correct, that
2017 unfortunately does not mean it's bug-free, only that the author thinks
2018 its design is bug-free. If you keep reporting bugs and tests they will
2019 be fixed swiftly, though.
2020 Since the JSON::XS author refuses to use a public bugtracker and
2022 prefers private emails, we've setup a tracker at RT, so you might want
2023 to report any issues twice. Once in private to MLEHMANN to be fixed in
2024 JSON::XS and one to our the public tracker. Issues fixed by JSON::XS
2025 with a new release will also be backported to Cpanel::JSON::XS and
2026 5.6.2, as long as cPanel relies on 5.6.2 and Cpanel::JSON::XS as our
2027 serializer of choice.
2028 <https://rt.cpan.org/Public/Dist/Display.html?Queue=Cpanel-JSON-XS>
2030
2032 This module is available under the same licences as perl, the Artistic
2033 license and the GPL.
2034
2036 The cpanel_json_xs command line utility for quick experiments.
2037 JSON, JSON::XS, JSON::MaybeXS, Mojo::JSON, Mojo::JSON::MaybeXS,
2039 JSON::SL, JSON::DWIW, JSON::YAJL, JSON::Any, Test::JSON,
2040 Locale::Wolowitz, <https://metacpan.org/search?q=JSON>
2041 <https://tools.ietf.org/html/rfc7159>
2043 <https://tools.ietf.org/html/rfc4627>
2045
2047 Reini Urban <rurban@cpan.org>
2048 Marc Lehmann <schmorp@schmorp.de>, http://home.schmorp.de/
2050
2052 Reini Urban <rurban@cpan.org>
2053perl v5.28.0 2018-08-23 XS(3)